Beiträge von Kuchenplatte

/**
 * Bibliothèque de fonctions permettant la visualisation 3D d'objets
 *
 * Copyright (C) 2014 Team ~R3F~
 *
 * This program is free software under the terms of the GNU General Public License version 3.
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 */




 /*
    File: fn_vehicleShop3DPreview.sqf
    Modified By: NiiRoZz




    Description:
    Called when a new selection is made in the list box and
    displays the new vehicle selected.
*/







private ["_classView","_object","_id"];




if (isNil "life_preview_3D_vehicle_cam") then
{
    [] call life_fnc_vehicleShopInit3DPreview;
};




_classView = _this select 0;




// Ignore non instantiable objects.
if (_classView != "" && {isClass (configFile >> "CfgVehicles" >> _classView) && {getNumber (configFile >> "CfgVehicles" >> _classView >> "scope") > 0}}) then
{
    // Skip if object view is the same as previous.
    if (isNull life_preview_3D_vehicle_object || {_classView != typeOf life_preview_3D_vehicle_object}) then
    {
        if (!isNull life_preview_3D_vehicle_object) then {detach life_preview_3D_vehicle_object; deleteVehicle life_preview_3D_vehicle_object;};
        // Create and place the object in the sky
        if (!life_pos_exist) then {
            life_pos_attach = [[3727, 7373, 200]] call life_fnc_searchPosEmpty;
            life_pos_exist = true;
            life_preview_light = "#lightpoint" createVehicle life_pos_attach;
            life_preview_light setLightBrightness 0.5;
            life_preview_light setLightColor [1,1,1];
            life_preview_light setLightAmbient [1,1,1];
        };
        _object = _classView createVehicle life_pos_attach;
        _id = owner player;
        [_object] remoteExecCall ["life_fnc_hideObj",-_id];
        [life_preview_light] remoteExecCall ["life_fnc_hideObj",-_id];
        [_object] call life_fnc_clearVehicleAmmo;
        _object attachTo [life_attachment_point, life_pos_attach];
		_object hideObject false;
		life_preview_light hideObject false;
		_object allowDamage false;
		_object enableSimulation false;




        life_preview_3D_vehicle_object = _object;
    };
};

/**
 * Bibliothèque de fonctions permettant la visualisation 3D d'objets
 * 
 * Copyright (C) 2014 Team ~R3F~
 * 
 * This program is free software under the terms of the GNU General Public License version 3.
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 */




/*
    File: fn_vehicleShopInit3DPreview.sqf
    Modified By: NiiRoZz




    Description:
    Called when a player open the vehicle shop and setup cam and the while for rotate around the vehicle
*/
// Creating a camera.
life_preview_3D_vehicle_cam = "camera" camCreate ([[3727, 7373, 200]] call life_fnc_searchPosEmpty);
life_preview_3D_vehicle_cam cameraEffect ["Internal", "BACK"];
life_preview_3D_vehicle_cam camSetFocus [-1, -1];
showCinemaBorder false;
life_preview_3D_vehicle_cam camCommit 0;




life_preview_3D_vehicle_object = objNull;




// Thread execution performing a continuous rotation of the camera around the view object.
0 spawn
{
    // Until we left the visualization.
    for "_i" from 0 to 1 step 0 do {
        if (isNull life_preview_3D_vehicle_cam) exitWith {};
        private ["_object","_distanceCam","_azimuthCam"];




        // Waiting for a view object.
        waitUntil {!isNull life_preview_3D_vehicle_object};




        _object = life_preview_3D_vehicle_object;




        _distanceCam = 2.25 * (
                [boundingBoxReal _object select 0 select 0, boundingBoxReal _object select 0 select 2]
            distance
                [boundingBoxReal _object select 1 select 0, boundingBoxReal _object select 1 select 2]
        );
        _azimuthCam = 0;




        life_preview_3D_vehicle_cam camSetTarget _object;
        life_preview_3D_vehicle_cam camSetPos (_object modelToWorld [_distanceCam * sin _azimuthCam, _distanceCam * cos _azimuthCam, _distanceCam * 0.33]);
        life_preview_3D_vehicle_cam camCommit 0;




        // Rotation around the object.
        for "_i" from 0 to 1 step 0 do {
            if (!(life_preview_3D_vehicle_object isEqualTo _object)) exitWith {};
            _azimuthCam = _azimuthCam + 1.00;




            life_preview_3D_vehicle_cam camSetPos (_object modelToWorld [_distanceCam * sin _azimuthCam, _distanceCam * cos _azimuthCam, _distanceCam * 0.33]);
            life_preview_3D_vehicle_cam camCommit 0.05;




            sleep 0.05;
        };
    };
};