Beiträge von powerafro2

#include <macro.h>
/*
    File: fn_saveGear.sqf
    Author: Bryan "Tonic" Boardwine
    Full Gear/Y-Menu Save by Vampire
    Edited: Itsyuka

    Description:
    Saves the players gear for syncing to the database for persistence..
*/
private["_return","_uItems","_bItems","_vItems","_pItems","_hItems","_yItems","_uMags","_vMags","_bMags","_pMag","_hMag","_uni","_ves","_bag","_handled"];
_return = [];




_return pushBack uniform player;
_return pushBack vest player;
_return pushBack backpack player;
_return pushBack goggles player;
_return pushBack headgear player;
_return pushBack assignedITems player;
if(playerSide == west || playerSide == civilian && {EQUAL(LIFE_SETTINGS(getNumber,"save_civ_weapons"),1)}) then {
    _return pushBack RIFLE;
    _return pushBack PISTOL;
} else {
    _return pushBack [];
    _return pushBack [];
};




_uItems = [];
_uMags  = [];
_bItems = [];
_bMags  = [];
_vItems = [];
_vMags  = [];
_pItems = [];
_hItems = [];
_yItems = [];
_uni = [];
_ves = [];
_bag = [];




if(!(EQUAL(uniform player,""))) then {
    {
        if (_x in (magazines player)) then {
			ADD(_uMags,[_x]);
        } else {
            ADD(_uItems,[_x]);
        };
    } forEach (uniformItems player);
};




if(!(EQUAL(backpack player,""))) then {
    {
        if (_x in (magazines player)) then {
			ADD(_bMags,[_x]);
        } else {
			ADD(_bItems,[_x]);
        };
    } forEach (backpackItems player);
};




if(!(EQUAL(vest player,""))) then {
    {
        if (_x in (magazines player)) then {
			ADD(_vMags,[_x]);
        } else {
			ADD(_vItems,[_x]);
        };
    } forEach (vestItems player);
};




if(count (primaryWeaponMagazine player) > 0 && alive player) then {
    _pMag = SEL((primaryWeaponMagazine player),0);

    if(!(EQUAL(_pMag,""))) then {
        _uni = player canAddItemToUniform _pMag;
        _ves = player canAddItemToVest _pMag;
        _bag = player canAddItemToBackpack _pMag;
        _handled = false;

        if(_ves) then {
			ADD(_vMags,[_pMag]);
            _handled = true;
        };

        if(_uni && !_handled) then {
			ADD(_uMags,[_pMag]);
            _handled = true;
        };

        if(_bag && !_handled) then {
			ADD(_bMags,[_pMag]);
            _handled = true;
        };
    };
};




if(count (handgunMagazine player) > 0 && alive player) then {
    _hMag = ((handgunMagazine player) select 0);

    if(!(EQUAL(_hMag,""))) then {
        _uni = player canAddItemToUniform _hMag;
        _ves = player canAddItemToVest _hMag;
        _bag = player canAddItemToBackpack _hMag;
        _handled = false;

        if(_ves) then {
			ADD(_vMags,[_hMag]);
            _handled = true;
        };

        if(_uni && !_handled) then {
			ADD(_uMags,[_hMag]);
            _handled = true;
        };

        if(_bag && !_handled) then {
            ADD(_uMags,[_hMag]);
            _handled = true;
        };
    };
};




if(count (RIFLE_ITEMS) > 0) then {
    {
		ADD(_pItems,[_x]);
    } forEach (primaryWeaponItems player);
};




if(count (PISTOL_ITEMS) > 0) then {
    {
		ADD(_hItems,[_x]);
    } forEach (handGunItems player);
};




{
	//if(ITEM_VALUE(configName _x) > 0) then {
    _val = ITEM_VALUE(_x);

    if (_val > 0) then {
		_yItems pushBack [_x,_val];
    };
} forEach LIFE_SETTINGS(getArray,"allowedSavedVirtualItems");







_return pushBack _uItems;
_return pushBack _uMags;
_return pushBack _bItems;
_return pushBack _bMags;
_return pushBack _vItems;
_return pushBack _vMags;
_return pushBack _pItems;
_return pushBack _hItems;
//if(EQUAL(LIFE_SETTINGS(getNumber,"save_virtualItems"),1)) then {
_return pushBack _yItems;
//} else {
//    _return pushBack []; 
//};




life_gear = _return;

#include <macro.h>
/*
	File: fn_escInterupt.sqf
	Author: Bryan "Tonic" Boardwine

	Description:
	Monitors when the ESC menu is pulled up and blocks off
	certain controls when conditions meet.
*/
private["_abortButton","_respawnButton","_fieldManual","_escSync","_canUseControls"];
disableSerialization;




_escSync = {
	private["_abortButton","_thread","_syncManager"];
	disableSerialization;

	_syncManager = {
		disableSerialization;
		private["_abortButton","_timeStamp"];
		_abortButton = CONTROL(49,104);
		_timeStamp = time + 10;

		waitUntil {
			_abortButton ctrlSetText format[localize "STR_NOTF_AbortESC",[(_timeStamp - time),"SS.MS"] call BIS_fnc_secondsToString];
			_abortButton ctrlCommit 0;
			round(_timeStamp - time) <= 0 || isNull (findDisplay 49)
		};

		_abortButton ctrlSetText localize "STR_DISP_INT_ABORT";
		_abortButton ctrlCommit 0;
	};

	_abortButton = CONTROL(49,104);
	[] call SOCK_fnc_updateRequest; 

	if(_this) then {
		_thread = [] spawn _syncManager;
		waitUntil{scriptDone _thread OR isNull (findDisplay 49)};
		_abortButton ctrlEnable true;
	};
};




_canUseControls = {
	if(playerSide == west) exitWith {true};
	if((player GVAR ["restrained",FALSE]) OR (player GVAR ["Escorting",FALSE]) OR (player GVAR ["transporting",FALSE]) OR (life_is_arrested) OR (life_istazed)) then {false} else {true};
};

while {true} do
{
	waitUntil{!isNull (findDisplay 49)};
	_abortButton = CONTROL(49,104);
	_abortButton buttonSetAction "[[player],""TON_fnc_cleanupRequest"",false,false] call life_fnc_MP";
	_respawnButton = CONTROL(49,1010);
	_fieldManual = CONTROL(49,122);

	//Block off our buttons first.
	_abortButton ctrlEnable false;
	_respawnButton ctrlEnable false;
	_fieldManual ctrlEnable false; 

	_usebleCtrl = call _canUseControls;
	_usebleCtrl spawn _escSync;
	if(_usebleCtrl) then {
		_respawnButton ctrlEnable true;
	};
	waitUntil{isNull (findDisplay 49)};
};

/*
	File: fn_huntingZone.sqf
	Author: Bryan "Tonic" Boardwine

	Description:
	Main functionality for the hunting zone.
*/
private["_bool","_total","_animals"];
_bool = [_this,0,false,[false]] call BIS_fnc_param;
if(!_bool && count life_animals_array == 0) exitWith {};




_animals = ["Goat_random_F","Hen_random_F","Sheep_random_F"]; //Array of animals to spawn
_total = 20; //Total amount to be spawned.




if(_bool) then
{
	for "_i" from 0 to (_total)-1 do
	{
		_pos = ["hunting_area"] call SHK_pos;
		_type = _animals call BIS_fnc_selectRandom;
		_animal = _type createUnit [(position player),(createGroup civilian)];
		//_animal = createAgent[_type,_pos, [], 0, "FORM"];
		hint format["%1\n%2",_type,_animal];
		life_animals_array pushBack _animal;
	};
	life_animals_spawned = true;
	systemChat str(life_animals_array);
}
	else
{
	{
		if(!isNull _x) then
		{
			deleteVehicle _x;
		};
	} foreach life_animals_array;

	life_animals_array = [];
	life_animals_spawned = false;
};