[Script Suche] GPS Tracker

Das ist zwar veraltet aber dennoch hilfreich:

https://board.nitrado.net/support-de-ger…er-f-r-vehicle/

Das ist mir schon bewusst.. ein bisschen nachdenken

erstelle ein neues item in der config_vitems es muss gpstracker heissen(erkläre ich nicht weiter sollte klar sein)

erstelle im verzeichnis core\items eine datei names fn_gpsTracker.sqf mit inhalt:

#include "..\..\script_macros.hpp"

private["_unit"];

_unit = [_this,0,ObjNull,[ObjNull]] call BIS_fnc_param;

if(isNull _unit) exitWith {};

if(!(_unit isKindOf "AllVehicles")) exitWith {hint "Du kannst den GPS Tracker hier nicht benutzen."};

if(player distance _unit > 7) exitWith {hint "Du musst dich näher an das Fahrzeug stellen!"};

if(!([false,"gpstracker",1] call life_fnc_handleInv)) exitWith {};

closeDialog 0;

life_action_inUse = true;

player playMove "AinvPknlMstpSnonWnonDnon_medic_1";

sleep 4;

player playMove "AinvPknlMstpSnonWnonDnon_medic_1";

sleep 4;

player playMove "AinvPknlMstpSnonWnonDnon_medic_1";

sleep 4;

life_action_inUse = false;

if(player distance _unit > 7) exitWith {titleText["Du bist nicht in der Nähe eines Fahrzeugs!","PLAIN"];};

titleText["Du hast einen GPS Tracker an diesem Fahrzeug angebracht.","PLAIN"];

[_unit] spawn {

_veh = _this select 0;

_markerName = format["%1_gpstracker",_veh];

_marker = createMarkerLocal [_markerName, visiblePosition _veh];

_marker setMarkerColorLocal "ColorRed";

_marker setMarkerTypeLocal "Mil_dot";

_marker setMarkerTextLocal "GPS Tracker "+getText(configFile >> "CfgVehicles" >> typeof _veh >> "displayName");

_marker setMarkerPosLocal getPos _veh;

while {true} do {

if(not alive _veh) exitWith {deleteMarkerLocal _markerName;};

_marker setMarkerPosLocal getPos _veh;

sleep 0.5;

};

};

trag die datei in der functions.hpp unter class items ein etwa so:

class Items {

file = "core\items";

class .... {};

class gpsTracker {};

class .... {};

};

und füg den gps tracker noch in der core\pmenu\fn_useItem.sqf hinzu:

case (_item isEqualTo "gpstracker"): {

[cursorObject] spawn life_fnc_gpsTracker;

closeDialog 0;

};

das wars

Generell würde ich die while Schleife in einem sleep von 10; oder so umbauen, dann erfindest einfach einen Roleplay Hintergrund oder sowas dann haste nicht so viele Abfragen wo der Osterhase sich aufhält.

Zitat

Generell würde ich die while Schleife in einem sleep von 10; oder so umbauen, dann erfindest einfach einen Roleplay Hintergrund oder sowas dann haste nicht so viele Abfragen wo der Osterhase sich aufhält.

Danach hat er nicht gefragt xD. Aber hast natürlich recht^^