New ProgressBar System

br1zey

Darum ist das hier Schwierigkeit 4 das geht nicht mal eben schnell die zu ersetzen da musst du grundlegend was ändern

Mattzimann

Ich werde mal gucken ob ich das hinkriege

br1zey

wenn ich zeit habe packe ich mal eine Geänderte Datei noch dran damit man sieht wie es aussehn muss

br1zey

Der Code wurde upgedatet

Neuer Parameter zum Checken in jedem Frame z.b. das die Bar abbricht wenn man dort {!(alive player)} macht kann auch für ander Sachen genutzt werden

Noch dazu Ist der Spieler jetzt Bewegungsunfähig währen die Progressbar lauft

Beispiel im Tutorial zu finden

PS: Könnte mir jemand Rückantwort geben ob es Fehler gibt da der Original Code von und Mit ACE und CBA Arbeitet und etwas mehr Funktionen hat die Altis so nicht hergibt

KWKBlack

Sry XD aber raff es nicht ganz. Seh ich des richtig? Wenn ich des TuT befolge ist jeder Bar geändert? Spricht die vom reparieren ect?

br1zey

nein das musst du manuel machen

Nodons

habs auch mal versucht, leider bekomm ich einen fehler den ich nicht ganz verstehe, versuche den aufruf mit:

Code

[5,[] {Hint "Finished!"}, {hint "Failure!"}, "My Title"] spawn rl_fnc_progressBar;

wie in der Datei als beispiel

Version 4.4r3

serverlog und local bekomm ich

Spoiler anzeigen

12:13:22 Error in expression <[5,[] {Hint "Finished!"}, {hint "Failure!"}, ">

12:13:22 Error position: <{Hint "Finished!"}, {hint "Failure!"}, ">

12:13:22 Error Fehlende ]

12:13:22 Error in expression <[5,[] {Hint "Finished!"}, {hint "Failure!"}, ">

12:13:22 Error position: <{Hint "Finished!"}, {hint "Failure!"}, ">

12:13:22 Error Fehlende ]

jemand ne Idee? ich finde leider keine klammerfehler oder so was

br1zey

ja

[5,[], {Hint "Finished!"}, {hint "Failure!"}, "My Title"] spawn rl_fnc_progressBar;

da fehlt ein Koma

Nodons

ok, da hätte man drauf kommen können, sorry, ab und an die Sache mit dem Wald und den Bäumen

OssigamerTV

Eine Frage, ich kenne mich mit scripten nur mäßig aus. Wo kann ich diese bar denn mit der repair und beschlagnahm bar ersetzen?

br1zey

daher schwirigkeit 4 du must die enprechenden Scripte Ändern

mit nur mäßig Ahnung Rate ich davon ab

GenApophis

kurze frage, wenn ich das so in ein Skript einbaue, wartet der Rest des skriptes dann bis die Leiste fertig ist???

Ich weiß, ist ne dumme Frage, ich packe mal die Datei ein die ich damit bearbeiten würde

Ich habe die Toolbar in Zeile 244 eingefügt, die alte ist nur ausgegraut

Code: fn_craftaction.sqf

/*
    File: fn_craftAction.sqf
    Author: EdgeKiller
    Description:
    Master handling for crafting an item.
    Source: https://altisdev.com/topic/860/syst%C3%A8me-de-craft-par-edgekiller
    ------------------------
    Overhauled by B4v4r!4n_Str!k3r ([email protected])
    Licence: THE OVERHAULED LINES ARE THE MINDSET OF CATIONSTUDIO
             AND ONLY AUTHORIZED PEOPLE/SERVERS ARE ALLOWED TO USE IT.
*/
private["_duration","_tN","_f","_textureName","_flag","_colorIndex","_c","_vehicle","_spawnPoint","_exit","_pos","_dialog","_item","_itemInfo","_oldItem","_newItem","_upp","_itemName","_ui","_progress","_pgText","_cP","_allMaterial","_matsNeed","_invSize","_handledItem","_itemFilter","_backpackOldItems","_weight","_weightUsedItems","_category"];
if (isNull player || !alive player || (player getVariable ["restrained",false]) || (player getVariable ["Escorting",false]) || life_istazed || life_action_inUse) exitWith {}; //If null / dead exit menu
if ((getNumber(missionConfigFile >> "Cation_Crafting" >> "version_4_4")) isEqualTo 1) then {
    if ((player getVariable ["playerSurrender",false]) || life_isknocked) exitWith {};
};
disableSerialization;
_dialog = findDisplay 666;
_spawnPoint = _dialog getVariable ["spawn",""];
if ((lbCurSel 669) == -1) exitWith {hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "SelectItemFirst"))];};
_item = lbData[669,(lbCurSel 669)];
_allMaterial = true;
_itemFilter = lbData[673,(lbCurSel 673)];
_matsNeed = 0;
_pos = getPos player;
_exit = false;
switch (_itemfilter) do {
    case "backpack": {
        _duration = (getNumber(missionConfigFile >> "Cation_Crafting" >> "duration_backpack"));
    };
    case "vest": {
        _duration = (getNumber(missionConfigFile >> "Cation_Crafting" >> "duration_vest"));
    };
    case "uniform": {
        _duration = (getNumber(missionConfigFile >> "Cation_Crafting" >> "duration_uniform"));
    };
    case "weapon": {
        _duration = (getNumber(missionConfigFile >> "Cation_Crafting" >> "duration_weapon"));
    };
    case "mammoth": {
        _duration = (getNumber(missionConfigFile >> "Cation_Crafting" >> "duration_mammothweapon"));
    };
    case "item": {
        _duration = (getNumber(missionConfigFile >> "Cation_Crafting" >> "duration_item"));
    };
    case "uran": {
        _duration = (getNumber(missionConfigFile >> "Cation_Crafting" >> "duration_uran"));
    };
    default {
        _duration = (getNumber(missionConfigFile >> "Cation_Crafting" >> "duration"));
    };
};
if (_duration <= 0 || _duration > 10) then {
    _duration = 0.3;
};
if (player distance _pos > 10) exitWith {};
_category = (getArray(missionConfigFile >> "Cation_Crafting" >> "category"));
_config = [];
{
    if (_itemFilter isEqualTo (_x select 0)) then {
        for "_i" from 2 to (count _x) do {
            _config pushBack (_x select _i);
        };
    };
} forEach _category;

life_action_inUse = true;//Lock out other actions during processing.

{
    if (_item == _x select 0)then {
        _matsNeed = _x select 2;
        _tN = _x select 3;
        _f = _x select 4;
        _invSize = count _matsNeed;
        for [{_i=0},{_i<_invSize-1},{_i=_i+2}] do {
            _matsNum = _matsNeed select _i+1;
            if ((missionNamespace getVariable [format["life_inv_%1",(getText(missionConfigFile >> "VirtualItems" >> (_matsNeed select _i) >> "variable"))],0]) < _matsNum) then {_allMaterial = false;};           
        };
    };
} foreach (_config);
_newItem = _item;
if (!_allMaterial) exitWith {hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NoMaterial"))]; life_action_inUse = false;};
//Some checks
if ((count _matsNeed) == 0) exitWith {life_action_inUse = false;};
switch (_itemFilter) do {
    case "backpack": {
        if (!(player canAdd _newItem)) then {
            if (!(backpack player isEqualTo "")) exitWith {
                hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NotificationBackpack"))];
                _exit = true;
            };
        };
    };
    case "vest": {
        if (!(player canAdd _newItem)) then {
            if (!(vest player isEqualTo "")) exitWith {
                hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NotificationVest"))];
                _exit = true;
            };
        };
    };
    case "uniform": {
        if (!(player canAdd _newItem)) then {
            if (!(uniform player isEqualTo "")) exitWith {
                hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NotificationUnifrom"))];
                _exit = true;
            };
        };
    };
    case "weapon": {
        switch (getNumber(configFile >> "CfgWeapons" >> _newItem >> "type")) do {
            case 1: {
                if (!(primaryWeapon player isEqualTo "")) then {
                    if (!(player canAdd _newItem)) then {
                        _exit = true;
                        hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NoRoom"))];
                    };
                };
            };
            case 2: {
                if (!(handGunWeapon player isEqualTo "")) then {
                    if (!(player canAdd _newItem)) then {
                        _exit = true;
                        hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NoRoom"))];
                    };
                };
            };
            case 4: {
                if (!(secondaryWeapon player isEqualTo "")) then {
                    if (!(player canAdd _newItem)) then {
                        _exit = true;
                        hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NoRoom"))];
                    };
                };
            };
        };
    };
    case "mammoth": {
        switch (getNumber(configFile >> "CfgWeapons" >> _newItem >> "type")) do {
            case 1: {
                if (!(primaryWeapon player isEqualTo "")) then {
                    if (!(player canAdd _newItem)) then {
                        _exit = true;
                        hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NoRoom"))];
                    };
                };
            };
            case 2: {
                if (!(handGunWeapon player isEqualTo "")) then {
                    if (!(player canAdd _newItem)) then {
                        _exit = true;
                        hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NoRoom"))];
                    };
                };
            };
            case 4: {
                if (!(secondaryWeapon player isEqualTo "")) then {
                    if (!(player canAdd _newItem)) then {
                        _exit = true;
                        hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NoRoom"))];
                    };
                };
            };
        };
    };
    case "item": {
        _weight = [_item] call life_fnc_itemWeight;
        _weightUsedItems = 0;
        for [{_i=0},{_i<(count _matsNeed)-1},{_i=_i+2}] do {
            _matsNum = _matsNeed select _i+1;
            _weightUsedItems = _weightUsedItems + (([(_matsNeed select _i)] call life_fnc_itemWeight) * _matsNum);
        };
        if ((life_carryWeight - _weightUsedItems + _weight) > life_maxWeight) exitWith {
            hint localize "STR_NOTF_NoRoom";
            _exit = true;
        };
    };
    case "uran": {
        _weight = [_item] call life_fnc_itemWeight;
        _weightUsedItems = 0;
        for [{_i=0},{_i<(count _matsNeed)-1},{_i=_i+2}] do {
            _matsNum = _matsNeed select _i+1;
            _weightUsedItems = _weightUsedItems + (([(_matsNeed select _i)] call life_fnc_itemWeight) * _matsNum);
        };
        if ((life_carryWeight - _weightUsedItems + _weight) > life_maxWeight) exitWith {
            hint localize "STR_NOTF_NoRoom";
            _exit = true;
        };
    };
    default {
        if (!(player canAdd _newItem)) exitWith {
            hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NoRoom"))];
            _exit = true;
        };
    };
};
if (_exit) exitWith {
    life_action_inUse = false;
};
_oldItem = _matsNeed;
switch (_itemFilter) do {
    case "item":
    {
        _itemName = localize getText(missionConfigFile >> "VirtualItems" >> _newItem >> "displayName");
    };
    case "uran":
    {
        _itemName = localize getText(missionConfigFile >> "VirtualItems" >> _newItem >> "displayName");
    };
    default {
        _itemInfo = [_newItem] call life_fnc_fetchCfgDetails;
        _itemName = _itemInfo select 1;
    };
};
/*if (_itemFilter == "item") then {
    _itemName = localize getText(missionConfigFile >> "VirtualItems" >> _newItem >> "displayName");
} else {
    _itemInfo = [_newItem] call life_fnc_fetchCfgDetails;
    _itemName = _itemInfo select 1;
};*/

life_is_processing = true;
_upp = format["%1 %2 - %3",(getText(missionConfigFile >> "Cation_Crafting" >> "Craft")),_itemName,_tN];
closeDialog 0;
//Setup our progress bar.
/*
disableSerialization;
5 cutRsc ["life_progress","PLAIN"];
_ui = uiNameSpace getVariable "life_progress";
_progress = _ui displayCtrl 38201;
_pgText = _ui displayCtrl 38202;
_pgText ctrlSetText format["%2 (1%1)...","%",_upp];
_progress progressSetPosition 0.01;
_cP = 0.01;
*/
_removeItemSuccess = true;
_invSize = count _oldItem;
for [{_i=0},{_i<_invSize-1},{_i=_i+2}] do {
    _handledItem = (_oldItem select _i);
    if (!([false,_handledItem,_oldItem select _i+1] call life_fnc_handleInv)) exitWith {_removeItemSuccess = false;};
};
if (!_removeItemSuccess) exitWith {5 cutText ["","PLAIN"]; life_is_processing = false; life_action_inUse = false;};

[5,[true,false], , , "Bin am Basteln",{(isNull player || !alive player || (player getVariable ["restrained",false]) || (player getVariable ["Escorting",false]) || life_istazed) || (player getVariable ["playerSurrender",false]) || life_isknocked}] spawn prg_fnc_progressBar;

/*for "_i" from 0 to 1 step 0 do {
    sleep _duration;
    _cP = _cP + 0.01;
    _progress progressSetPosition _cP;
    _pgText ctrlSetText format["%3 (%1%2)...",round(_cP * 100),"%",_upp];
    if(_cP >= 1) exitWith {};
    if (isNull player || !alive player || (player getVariable ["restrained",false]) || (player getVariable ["Escorting",false]) || life_istazed) exitWith {}; //If null / dead exit menu
    if ((getNumber(missionConfigFile >> "Cation_Crafting" >> "version_4_4")) isEqualTo 1) then {
        if ((player getVariable ["playerSurrender",false]) || life_isknocked) exitWith {};
    };
    if (player distance _pos > 10) exitWith {};
};
*/
if (player distance _pos > 10) exitWith {
    hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "Process_Stay"))]; 5 cutText ["","PLAIN"]; life_is_processing = false; life_action_inUse = false;
    for [{_i=0},{_i<_invSize-1},{_i=_i+2}] do {
        _handledItem = (_oldItem select _i);
        [true,_handledItem,_oldItem select _i+1] call life_fnc_handleInv;
    };
    life_is_processing = false;  
    life_action_inUse = false;
};
if (isNull player || !alive player || (player getVariable ["restrained",false]) || (player getVariable ["Escorting",false]) || life_istazed) exitWith {
    for [{_i=0},{_i<_invSize-1},{_i=_i+2}] do {
        _handledItem = (_oldItem select _i);
        [true,_handledItem,_oldItem select _i+1] call life_fnc_handleInv;
    };
    life_is_processing = false;
    life_action_inUse = false;
}; //If null / dead exit menu
if ((getNumber(missionConfigFile >> "Cation_Crafting" >> "version_4_4")) isEqualTo 1) then {
    if ((player getVariable ["playerSurrender",false]) || life_isknocked) exitWith {
        for [{_i=0},{_i<_invSize-1},{_i=_i+2}] do {
            _handledItem = (_oldItem select _i);
            [true,_handledItem,_oldItem select _i+1] call life_fnc_handleInv;
        };
        life_is_processing = false;
        life_action_inUse = false;
    };
};
_exit = false;
switch (_itemFilter) do {
    case "backpack": {
        if (player canAdd _newItem) then {
            player addItem _newItem;
        } else {
            if (backpack player isEqualTo "") then {
                player addBackpack _newItem;
            } else {
                hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NotificationBackpack"))];
                _exit = true;
            };
        };
    };
    case "vest": {
        if (player canAdd _newItem) then {
            player addItem _newItem;
        } else {
            if (vest player isEqualTo "") then {
                player addVest _newItem;
            } else {
                hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NotificationVest"))];
                _exit = true;
            };
        };
    };
    case "uniform": {
        if (player canAdd _newItem) then {
            player addItem _newItem;
        } else {
            if (uniform player isEqualTo "") then {
                player addUniform _newItem;
            } else {
                hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NotificationUnifrom"))];
                _exit = true;
            };
        };
    };
    case "weapon": {
        switch (getNumber(configFile >> "CfgWeapons" >> _newItem >> "type")) do {
            case 1: {
               if (primaryWeapon player isEqualTo "") then {
                    player addWeapon _newItem;
                } else {
                    if (player canAdd _newItem) then {
                        player addItem _newItem;
                    } else {
                        _exit = true;
                        hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NoRoom"))];
                    };
                };
            };
            case 2: {
                if (handGunWeapon player isEqualTo "") then {
                    player addWeapon _newItem;
                } else {
                    if (player canAdd _newItem) then {
                        player addItem _newItem;
                    } else {
                        _exit = true;
                        hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NoRoom"))];
                    };
                };
            };
            case 4: {
                if (secondaryWeapon player isEqualTo "") then {
                    player addWeapon _newItem;
                } else {
                    if (player canAdd _newItem) then {
                        player addItem _newItem;
                    } else {
                        _exit = true;
                        hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NoRoom"))];
                    };
                };
            };
        };
    };
    case "mammoth": {
        switch (getNumber(configFile >> "CfgWeapons" >> _newItem >> "type")) do {
            case 1: {
               if (primaryWeapon player isEqualTo "") then {
                    player addWeapon _newItem;
                } else {
                    if (player canAdd _newItem) then {
                        player addItem _newItem;
                    } else {
                        _exit = true;
                        hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NoRoom"))];
                    };
                };
            };
            case 2: {
                if (handGunWeapon player isEqualTo "") then {
                    player addWeapon _newItem;
                } else {
                    if (player canAdd _newItem) then {
                        player addItem _newItem;
                    } else {
                        _exit = true;
                        hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NoRoom"))];
                    };
                };
            };
            case 4: {
                if (secondaryWeapon player isEqualTo "") then {
                    player addWeapon _newItem;
                } else {
                    if (player canAdd _newItem) then {
                        player addItem _newItem;
                    } else {
                        _exit = true;
                        hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NoRoom"))];
                    };
                };
            };
        };
    };
    case "item": {
        _handledItem = _newItem;
        if (!([true,_handledItem,1] call life_fnc_handleInv)) then { _exit = true; };
    };
    case "uran": {
        _handledItem = _newItem;
        if (!([true,_handledItem,1] call life_fnc_handleInv)) then { _exit = true; };
    };
    default {
        if (player canAdd _newItem) then {
            player addItem _newItem;
        } else {
            hint format[(getText(missionConfigFile >> "Cation_Crafting" >> "NoRoom"))];
            _exit = true;
        };
    };
};
if (_exit) exitWith {
    for [{_i=0},{_i<_invSize-1},{_i=_i+2}] do {
        _handledItem = (_oldItem select _i);
        [true,_handledItem,_oldItem select _i+1] call life_fnc_handleInv;
    };
    5 cutText ["","PLAIN"];
    [0] call SOCK_fnc_updatePartial;
    life_is_processing = false;
    life_action_inUse = false;
};
5 cutText ["","PLAIN"];
titleText[format["%1 %2",(getText(missionConfigFile >> "Cation_Crafting" >> "Process")),_itemName],"PLAIN"];
["crafting"] spawn mav_ttm_fnc_addExp;
[0] call SOCK_fnc_updatePartial;
life_is_processing = false;
life_action_inUse = false;

Alles anzeigen

br1zey

Nein so würde es nicht gehn

hier mal ein Beispiel mit der TruckRepair.sqf aus der AL Verison 5.0

Code

#include "..\..\script_macros.hpp"
/*
    File: fn_repairTruck.sqf
    Author: Bryan "Tonic" Boardwine
    Description:
    Main functionality for toolkits, to be revised in later version.
*/
private ["_veh","_upp","_ui","_progress","_pgText","_cP","_displayName","_test","_sideRepairArray"];
_veh = cursorObject;
life_interrupted = false;
if (isNull _veh) exitWith {};
if ((_veh isKindOf "Car") || (_veh isKindOf "Ship") || (_veh isKindOf "Air")) then {
    if (life_inv_toolkit > 0) then {
        life_action_inUse = true;
        _displayName = FETCH_CONFIG2(getText,"CfgVehicles",(typeOf _veh),"displayName");
        _upp = format [localize "STR_NOTF_Repairing",_displayName];


inner_fnc_repair = {
      params [
      ["_veh",objNull,[objNull]]
      ];
        life_action_inUse = false;

        _sideRepairArray = LIFE_SETTINGS(getArray,"vehicle_infiniteRepair");

        //Check if playerSide has infinite repair enabled
        if (playerSide isEqualTo civilian && (_sideRepairArray select 0) isEqualTo 0) then {
            [false,"toolkit",1] call life_fnc_handleInv;
        };
        if (playerSide isEqualTo west && (_sideRepairArray select 1) isEqualTo 0) then {
            [false,"toolkit",1] call life_fnc_handleInv;
        };
        if (playerSide isEqualTo independent && (_sideRepairArray select 2) isEqualTo 0) then {
            [false,"toolkit",1] call life_fnc_handleInv;
        };
        if (playerSide isEqualTo east && (_sideRepairArray select 3) isEqualTo 0) then {
            [false,"toolkit",1] call life_fnc_handleInv;
        };

        _veh setDamage 0;
        titleText[localize "STR_NOTF_RepairedVehicle","PLAIN"];
      };

        [5,[_veh], {_this call inner_fnc_repair},{hint "Abbgebrochen"},"Repariere",{true},["default",0]] spawn rl_fnc_progressBar
    }else{
      hint "Du hast keinen Werkzeugkasten"
    };
};

Alles anzeigen

Wenn die Progressbar Aufgerufen wird Lauft der Code trotzdem Weiter daher habe ich das jetzt so Gelöst

PS Code der Progressbar Upgedatet für das Beispiel Muss das Beachtet werden

GenApophis

Hi, ich bekomme leider eine Fehlermeldung wenn ich als Spieler auf den server Joine:

Code

Error in expression <edTitle", ""],  ["_condition", {true}], ]; _progress = 0; _startTime = diag_tick>
Error position: <]; _progress = 0; _startTime = diag_tick>
Error Missing [
File cation\progressbar\progressdata\fn_progressBar.sqf [prg_fnc_progressBar], line 1
Error in expression <edTitle", ""],  ["_condition", {true}], ]; _progress = 0; _startTime = diag_tick>
Error position: <]; _progress = 0; _startTime = diag_tick>
Error Missing [

Kann mir jemand helfen?

Und bevor jemand jetzt jammert das der Pfad falsch ist, das ist mir bewusst das der pfad ANDERS ist, das ist so gewolt und auch so schon abgeändert...

br1zey

kannst du mir mal deine Datei anhängen dan gucke ich ebend mal drüber

GenApophis

Hi br1zey,

hier mal die Datei:

Code

/*
    Author: br1zey/Ryu
    Special Thanks to ACE3 and Exile Team
    Draw progress bar and execute given function if succesful.
    Finish/Failure/Conditional are all passed [_args]
    
    Arguments:
    0: NUMBER - Total Time (in game "time" seconds)
    1: ARRAY - Arguments, passed to condition, fail and finish
    2: CODE or STRING - On Finish: Code called or STRING raised as event.
    3: CODE or STRING - On Failure: Code called or STRING raised as event.
    4: STRING - (Optional) Localized Title
    5: CODE - (Optional) Code to check each frame
    
    Return Value:
    Nothing
    
    Example:
    [5,[] {Hint "Finished!"}, {hint "Failure!"}, "My Title"] spawn rl_fnc_progressBar
    
    [5,[[false,"Test",false,5]], {(_this select 0) call life_fnc_hint},{hint "Abbgebrochen"},"Repariere"] spawn rl_fnc_progressBar
    
    [5,[[false,"Test",false,5]], {(_this select 0) call life_fnc_hint},{hint "Abbgebrochen"},"Repariere",(cursorTarget isKindOf "CAR")] spawn rl_fnc_progressBar 
*/
private["_progress","_startTime","_sleepTime","_display","_label","_progressBarBackground","_progressBarMaxSize","_progressBar","_totalTime","_onFinish", "_onFail","_localizedTitle","_return","_condition","_lastAnimStart"];

disableSerialization;
params [
    "_totalTime",
    ["_args",[]],
    "_onFinish",
    "_onFail",
    ["_localizedTitle", ""],
    ["_condition", {true}],
];

_progress = 0;
_startTime = diag_tickTime;
_sleepTime = _totalTime / 100;

_defaultVehicle = (vehicle player);

//close all Dialogs
closeDialog 0;
("RLActionProgressLayer" call BIS_fnc_rscLayer) cutRsc ["RscRLActionProgress", "PLAIN", 1, false];

createDialog "ProgressBar_Dialog";

_display = uiNamespace getVariable "RscRLActionProgress";
_label = _display displayCtrl 4002;
_label ctrlSetText format ["0% - %1",_localizedTitle];
_progressBarBackground = _display displayCtrl 4001;
_progressBarBackground ctrlSetBackgroundColor [0, 0, 0, 0.5];
_progressBarMaxSize = ctrlPosition _progressBarBackground;
_progressBar = _display displayCtrl 4000;
_progressBar ctrlSetPosition [_progressBarMaxSize select 0, _progressBarMaxSize select 1, 0, _progressBarMaxSize select 3-0.01];
_progressBar ctrlSetBackgroundColor [0, 0.5, 1, 1];
_progressBar ctrlCommit 0;
_progressBar ctrlSetPosition _progressBarMaxSize;
_progressBar ctrlCommit _totalTime;
try
{
    while {_progress < 1} do{
        if !(alive player) then{
            throw false;
        };
        if !(dialog) then{
            throw false;
        };
        if (!([_args,(time - _startTime),_totalTime] call _condition)) then {
            throw false;
        };
        if( (player getVariable ["ACE_isUnconscious",false]) OR life_istazed OR (player getVariable ["restrained",false]) OR (_defaultVehicle != (vehicle player))) then{
            throw false;
        };
        if(! (_anim isEqualTo "") && time >= (_lastAnimStart + _animTime))then{
            [player, _anim] call ace_common_fnc_doAnimation;
        };
        uiSleep _sleepTime;
        _progress = ((diag_tickTime - _startTime) / _totalTime) min 1;
        _label ctrlSetText format["%1%2 - %3", round (_progress * 100), "%",_localizedTitle];
    };
    throw true;
} catch {
    _progressBarColor = [];
    
    if(_exception) then {
        _args call _onFinish;
        _return = true;
        _progressBarColor = [0.7, 0.93, 0, 1];
    }else{
        _args call _onFail;
        _return = false;
        _progressBarColor = [0.91, 0, 0, 1];
    };
    
    _progressBar ctrlSetBackgroundColor _progressBarColor;
    _progressBar ctrlSetPosition _progressBarMaxSize;
    _progressBar ctrlCommit 0;
};
("RLActionProgressLayer" call BIS_fnc_rscLayer) cutFadeOut 2;
closeDialog 24025;

Alles anzeigen

br1zey

ich hate den code mal geupdatet die tage aber du must

["_condition", {true}], de das , letze , entfernen

GenApophis

Hi,

jetzt habe ich noch eine frage bevor ich mir die arbeit mache und das einbaue und alles umscripte^^:

kann ich so damit arbeiten:

Code

[
    30,
    [true,false],
    {_variable = _this select 0},
    {_variable = _this select 1},
    "Let's go to the Mall - Robin Sparkles",
    {!(alive player) || (_player distance _pos < 10)}
] spawn rl_fnc_progressBar;

br1zey

Sollte so gehn aber am Besten noch mal Elber Testen

GenApophis

K, Supi Danke XD

New ProgressBar System

Ähnliche Themen

Erneutes neues Nachrichtensystem mit Emojis

C# |.NET Fragen zum download und Verzeichnis aus wählen

Schmerzmittel mit Zeit

Altis Life Signatur Generator V2

Pfad Auswahl vor Download in C# auswählen?

Download Programm in C# Progressbar einbau funktioniert nicht

Tags