Jail Time Problem [Behoben]

Askeroth

Huhu Leute!

Ich hab 2 Fehler auf die ich nicht draufkomme
und zwar einmal in der fn_jailMe, an der ich nach diesem Link gegangen bin.
Angeblich fehlt in Zeile 19 ein ; nur erkenn ich nicht wo dies sein sollte.

Spoiler anzeigen

15:24:55 Error in expression < _ret > 0) then { life_bail_amount = SEL(_ret,3); } else { life_bail_amount = 15>
15:24:55 Error position: <(_ret,3); } else { life_bail_amount = 15>
15:24:55 Error Fehlendes ;
15:24:55 File mpmissions\__CUR_MP.[lexicon]Tanoa[/lexicon]\core\civilian\fn_jailMe.sqf, line 19

Spoiler anzeigen

Code: fn_jailMe.sqf

#include "..\..\script_macros.hpp"
/*
    File: fn_jail.sqf
    Author: Bryan "Tonic" Boardwine




    Description:
    Starts the initial process of jailing.
*/
private ["_illegalItems"];
params [
    ["_unit",objNull,[objNull]],
    ["_bad",false,[false]],
	["_time",15,[0]]
];




if (isNull _unit) exitWith {}; //Dafuq?
if (_unit != player) exitWith {}; //Dafuq?
if (life_is_arrested) exitWith {}; //Dafuq i'm already arrested
_illegalItems = LIFE_SETTINGS(getArray,"jail_seize_vItems");




player setVariable ["restrained",false,true];
player setVariable ["Escorting",false,true];
player setVariable ["transporting",false,true];




titleText[localize "STR_Jail_Warn","PLAIN"];
hint localize "STR_Jail_LicenseNOTF";
player setPos (getMarkerPos "jail_marker");




if (_bad) then {
    waitUntil {alive player};
    sleep 1;
};




//Check to make sure they goto check
if (player distance (getMarkerPos "jail_marker") > 40) then {
    player setPos (getMarkerPos "jail_marker");
};




[1] call life_fnc_removeLicenses;




{
    _amount = ITEM_VALUE(_x);
    if (_amount > 0) then {
        [false,_x,_amount] call life_fnc_handleInv;
    };
} forEach _illegalItems;




life_is_arrested = true;




if (LIFE_SETTINGS(getNumber,"jail_seize_inventory") isEqualTo 1) then {
    [] spawn life_fnc_seizeClient;
} else {
    removeAllWeapons player;
    {player removeMagazine _x} forEach (magazines player);
};




if (life_HC_isActive) then {
    [player,_bad,_time] remoteExecCall ["HC_fnc_jailSys",HC_Life];
} else {
    [player,_bad,_time] remoteExecCall ["life_fnc_jailSys",RSERV];
};




[5] call SOCK_fnc_updatePartial;

Alles anzeigen

und einaml in der fn_captureHideoutm, an der ich nichts verändert habe. Nur die Map auf [lexicon]Tanoa[/lexicon] umgestellt habe.

Spoiler anzeigen

15:25:51 Error in expression <Barracks_V2_F"],25]) select 0;
_group = _hideout getVariable ["gangOwner",grpNul>
15:25:51 Error position: <_hideout getVariable ["gangOwner",grpNul>
15:25:51 Error Nicht definierte Variable in Ausdruck: _hideout
15:25:51 File mpmissions\__CUR_MP.[lexicon]Tanoa[/lexicon]\core\actions\fn_captureHideout.sqf, line 11
15:25:51 Error in expression <= _ui displayCtrl 38202;

_cP = _cP + _cpRate;
_progressBar progressSetPositio>
15:25:51 Error position: <_cpRate;
_progressBar progressSetPositio>
15:25:51 Error Nicht definierte Variable in Ausdruck: _cprate
15:25:51 File mpmissions\__CUR_MP.[lexicon]Tanoa[/lexicon]\core\actions\fn_captureHideout.sqf, line 57
15:25:51 Error in expression <eText = _ui displayCtrl 38202;

15:25:54 Error in expression <ue];};
if (life_interrupted) exitWith {_hideout setVariable ["inCapture",false,>
15:25:54 Error position: <_hideout setVariable ["inCapture",false,>
15:25:54 Error Nicht definierte Variable in Ausdruck: _hideout
15:25:54 File mpmissions\__CUR_MP.[lexicon]Tanoa[/lexicon]\core\actions\fn_captureHideout.sqf, line 64
15:25:54 Error in expression <eText = _ui displayCtrl 38202;

Spoiler anzeigen

Code: fn_captureHideout.sqf

#include "..\..\script_macros.hpp"
/*
    File: fn_captureHideout.sqf
    Author: Bryan "Tonic" Boardwine




    Description:
    Blah blah.
*/
private["_group","_hideout","_action","_cpRate","_cP","_progressBar","_title","_titleText","_ui","_flagTexture"];
_hideout = (nearestObjects[getPosATL player,["Land_u_Barracks_V2_F","Land_i_Barracks_V2_F"],25]) select 0;
_group = _hideout getVariable ["gangOwner",grpNull];




if (isNil {group player getVariable "gang_name"}) exitWith {titleText[localize "STR_GNOTF_CreateGang","PLAIN"];};
if (_group == group player) exitWith {titleText[localize "STR_GNOTF_Controlled","PLAIN"]};
if ((_hideout getVariable ["inCapture",false])) exitWith {hint localize "STR_GNOTF_onePersonAtATime";};
if (!isNull _group) then {
    _gangName = _group getVariable ["gang_name",""];
    _action = [
        format[localize "STR_GNOTF_AlreadyControlled",_gangName],
        localize "STR_GNOTF_CurrentCapture",
        localize "STR_Global_Yes",
        localize "STR_Global_No"
    ] call BIS_fnc_guiMessage;




    _cpRate = 0.0045;
} else {
    _cpRate = 0.0075;
};




if (!isNil "_action" && {!_action}) exitWith {titleText[localize "STR_GNOTF_CaptureCancel","PLAIN"];};
life_action_inUse = true;




//Setup the progress bar
disableSerialization;
_title = localize "STR_GNOTF_Capturing";
5 cutRsc ["life_progress","PLAIN"];
_ui = uiNamespace getVariable "life_progress";
_progressBar = _ui displayCtrl 38201;
_titleText = _ui displayCtrl 38202;
_titleText ctrlSetText format["%2 (1%1)...","%",_title];
_progressBar progressSetPosition 0.01;
_cP = 0.01;




for "_i" from 0 to 1 step 0 do {
    if (animationState player != "AinvPknlMstpSnonWnonDnon_medic_1") then {
        [player,"AinvPknlMstpSnonWnonDnon_medic_1",true] remoteExecCall ["life_fnc_animSync",RCLIENT];
        player switchMove "AinvPknlMstpSnonWnonDnon_medic_1";
        player playMoveNow "AinvPknlMstpSnonWnonDnon_medic_1";
    };
    sleep 0.26;
    if (isNull _ui) then {
        5 cutRsc ["life_progress","PLAIN"];
        _ui = uiNamespace getVariable "life_progress";
        _progressBar = _ui displayCtrl 38201;
        _titleText = _ui displayCtrl 38202;
    };
    _cP = _cP + _cpRate;
    _progressBar progressSetPosition _cP;
    _titleText ctrlSetText format["%3 (%1%2)...",round(_cP * 100),"%",_title];
    _hideout setVariable ["inCapture",true,true];
    if (_cP >= 1 || !alive player) exitWith {_hideout setVariable ["inCapture",false,true];};
    if (life_istazed) exitWith {_hideout setVariable ["inCapture",false,true];}; //Tazed
    if (life_isknocked) exitWith {_hideout setVariable ["inCapture",false,true];}; //Knocked
    if (life_interrupted) exitWith {_hideout setVariable ["inCapture",false,true];};
};




//Kill the UI display and check for various states
5 cutText ["","PLAIN"];
player playActionNow "stop";
if (!alive player || life_istazed || life_isknocked) exitWith {life_action_inUse = false;_hideout setVariable ["inCapture",false,true];};
if (player getVariable ["restrained",false]) exitWith {life_action_inUse = false;_hideout setVariable ["inCapture",false,true];};
if (life_interrupted) exitWith {life_interrupted = false; titleText[localize "STR_GNOTF_CaptureCancel","PLAIN"]; life_action_inUse = false;_hideout setVariable ["inCapture",false,true];};
life_action_inUse = false;




titleText[localize "STR_GNOTF_Captured","PLAIN"];
_flagTexture = [
        "\A3\Data_F\Flags\Flag_red_CO.paa",
        "\A3\Data_F\Flags\Flag_green_CO.paa",
        "\A3\Data_F\Flags\Flag_blue_CO.paa",
        "\A3\Data_F\Flags\Flag_white_CO.paa",
        "\A3\Data_F\Flags\flag_fd_red_CO.paa",
        "\A3\Data_F\Flags\flag_fd_green_CO.paa",
        "\A3\Data_F\Flags\flag_fd_blue_CO.paa",
        "\A3\Data_F\Flags\flag_fd_orange_CO.paa"
    ] call BIS_fnc_selectRandom;
_this select 0 setFlagTexture _flagTexture;
[[0,1],"STR_GNOTF_CaptureSuccess",true,[name player,(group player) getVariable "gang_name"]] remoteExecCall ["life_fnc_broadcast",RCLIENT];
_hideout setVariable ["inCapture",false,true];
_hideout setVariable ["gangOwner",group player,true];

Alles anzeigen

Die RPT logs hab ich im Anhang hinzugefügt.

Ich hoffe ihr könnt mir helfen!

PS: Den error in der Statusbar kenn ich und werd ihn fixen

PPS: Für andere fehler bin ich gerne offen

LG Askeroth

B4v4r!4n_Str!k3r

zum Hideout: ist eine Baracke mit dem Klassennamen _hideout = (nearestObjects[getPosATL player,["Land_u_Barracks_V2_F","Land_i_Barracks_V2_F"],25]) select 0;

in der Nähe (ca 25m) um die Fahne?

shenzox

Versuch mal diese Datei zu benutzen

Askeroth

Zitat von B4v4r!4n_Str!k3r

zum Hideout: ist eine Baracke mit dem Klassennamen _hideout = (nearestObjects[getPosATL player,["Land_u_Barracks_V2_F","Land_i_Barracks_V2_F"],25]) select 0;

in der Nähe (ca 25m) um die Fahne?

Danke

Ich Idiot hab die Ganggebiete an einem anderen Gebäude hingebaut. Hab mich da total verschaut

@shenzox

mit der Jailme von dir hab ich diesen Fehler:

Spoiler anzeigen

16:35:10 Error in expression < _ret > 0) then { life_bail_amount = SEL(_ret,3); } else { life_bail_amount = 15>
16:35:10 Error position: <(_ret,3); } else { life_bail_amount = 15>
16:35:10 Error Fehlendes ;
16:35:10 File mpmissions\__CUR_MP.[lexicon]Tanoa[/lexicon]\core\civilian\fn_jailMe.sqf, line 18
16:35:10 Error in expression < _ret > 0) then { life_bail_amount = SEL(_ret,3); } else { life_bail_amount = 15>
16:35:10 Error position: <(_ret,3); } else { life_bail_amount = 15>
16:35:10 Error Fehlendes ;
16:35:10 File mpmissions\__CUR_MP.[lexicon]Tanoa[/lexicon]\core\civilian\fn_jailMe.sqf, line 18

das einknasten funktioniert zwar aber die person kommt nicht raus.

shenzox

Finde da gerade kein Fehler außer bei Zeile 16 das + habe ich da ausversehen hingemacht müsstes du mal weg machen^^

Askeroth

das + hab ich vorher schon gesehen und entfernt.

Nur leider wie schon gesagt hab ich diesen fehler

16:35:10 Error in expression < _ret > 0) then { life_bail_amount = SEL(_ret,3); } else { life_bail_amount = 15>
16:35:10 Error position: <(_ret,3); } else { life_bail_amount = 15>
16:35:10 Error Fehlendes ;
16:35:10 File mpmissions\__CUR_MP.Tanoa\core\civilian\fn_jailMe.sqf, line 18

Ich kann da auch nirgends was entdecken.

shenzox

Hast du vielleicht einen TS Server damit wir darüber reden können? Geht schneller

PoweredByte

Probier mal meine fn_Jailme.sqf

Code: fn_jailMe.sqf

#include "..\..\script_macros.hpp"
/*
    File: fn_jailMe.sqf
    Author Bryan "Tonic" Boardwine




    Description:
    Once word is received by the server the rest of the jail execution is completed.
*/
private["_time","_bail","_esc","_countDown"];




params [
    ["_ret",[],[[]]],
    ["_bad",false,[false]]
];







if (_bad) then { _time = time + 1100; } else { _time = time + (15 * 60); };




if (count _ret > 0) then { life_bail_amount = (_ret select 2); } else { life_bail_amount = 1500; _time = time + (10 * 60); };
_esc = false;
_bail = false;




[_bad] spawn {
    life_canpay_bail = false;
    if (_this select 0) then {
        sleep (10 * 60);
    } else {
        sleep (5 * 60);
    };
    life_canpay_bail = nil;
};




for "_i" from 0 to 1 step 0 do {
    if ((round(_time - time)) > 0) then {
        _countDown = [(_time - time),"MM:SS.MS"] call BIS_fnc_secondsToString;
        hintSilent parseText format[(localize "STR_Jail_Time")+ "<br/> <t size='2'><t color='#FF0000'>%1</t></t><br/><br/>" +(localize "STR_Jail_Pay")+ " %3<br/>" +(localize "STR_Jail_Price")+ " $%2",_countDown,[life_bail_amount] call life_fnc_numberText,if (isNil "life_canpay_bail") then {"Yes"} else {"No"}];
    };




    if (player distance (getMarkerPos "jail_marker") > 60) exitWith {
        _esc = true;
    };




    if (life_bail_paid) exitWith {
        _bail = true;
    };




    if ((round(_time - time)) < 1) exitWith {hint ""};
    if (!alive player && ((round(_time - time)) > 0)) exitWith {};
    sleep 0.1;
};







switch (true) do {
    case (_bail): {
        life_is_arrested = false;
        life_bail_paid = false;
        hint localize "STR_Jail_Paid";
        serv_wanted_remove = [player];
        player setPos (getMarkerPos "jail_release");




        if (life_HC_isActive) then {
            [getPlayerUID player] remoteExecCall ["HC_fnc_wantedRemove",HC_Life];
        } else {
            [getPlayerUID player] remoteExecCall ["life_fnc_wantedRemove",RSERV];
        };




        [5] call SOCK_fnc_updatePartial;
    };




    case (_esc): {
        life_is_arrested = false;
        hint localize "STR_Jail_EscapeSelf";
        [0,"STR_Jail_EscapeNOTF",true,[profileName]] remoteExecCall ["life_fnc_broadcast",RCLIENT];




        if (life_HC_isActive) then {
            [getPlayerUID player,profileName,"901"] remoteExecCall ["HC_fnc_wantedAdd",HC_Life];
        } else {
            [getPlayerUID player,profileName,"901"] remoteExecCall ["life_fnc_wantedAdd",RSERV];
        };




        [5] call SOCK_fnc_updatePartial;
    };




    case (alive player && !_esc && !_bail): {
        life_is_arrested = false;
        hint localize "STR_Jail_Released";




        if (life_HC_isActive) then {
            [getPlayerUID player] remoteExecCall ["HC_fnc_wantedRemove",HC_Life];
        } else {
            [getPlayerUID player] remoteExecCall ["life_fnc_wantedRemove",RSERV];
        };




        player setPos (getMarkerPos "jail_release");
        [5] call SOCK_fnc_updatePartial;
    };
};

Alles anzeigen

Askeroth

So!
Hab es nun geschafft für die 4.4 R3, dasss man nun die Gefängnis Zeit einstellen kann.

Kurz zur Erklärung:

Ich hab diese Schritte in diesem Link befolgt.

und diese jailMe.sqf was ich poste.

Code: fn_jailMe.sqf

#include "..\..\script_macros.hpp"
/*
	Author Bryan "Tonic" Boardwine
	Description:
	Once word is received by the server the rest of the jail execution is completed.
*/
private["_time","_bail","_esc","_countDown"];




params [
	["_ret",[],[[]]],
	["_bad",false,[false]],
	["_time",15,[0]]
];




_time = time + (_time * 60);










if (count _ret > 0) then { life_bail_amount = (_ret select 2); } else { life_bail_amount = 1500; };
_esc = false;
_bail = false;




if(_time <= 0) then { _time = time + (15 * 60); hintC "Please Report to Admin: JAIL_FALLBACK_15, time is zero!"; };
[_bad,_time] spawn {
    life_canpay_bail = false;
    life_bail_amount = life_bail_amount * 5;
    if(_this select 0) then {
        sleep ( (_this select 1) * 0.5 );
    } else {
        sleep ( (_this select 1) * 0.2 );
    };
    life_canpay_bail = nil;
};




while {true} do {
	if((round(_time - time)) > 0) then {
		_countDown = if(round (_time - time) > 60) then {format["%1 Minuten",round(round(_time - time) / 60)]} else {format["%1 Sekunden",round(_time - time)]};
	        if(isNil "life_canpay_bail") then {
	            hintSilent format["Time Remaining:\n %1\n\nCan pay Bail: %3\nBail Amount: $%2",_countDown,[life_bail_amount] call life_fnc_numberText, "dass"];
	        } else {
	            hintSilent format["Time Remaining:\n %1\n",_countDown];
	        };
	};
	if(player distance (getMarkerPos "jail_marker") > 60) exitWith {
		_esc = true;
	};
	if(life_bail_paid) exitWith {
		_bail = true;
	};
	if((round(_time - time)) < 1) exitWith {hint ""};
	if(!alive player && ((round(_time - time)) > 0)) exitWith {};
	sleep 1;
};







switch (true) do {
	case (_bail): {
		life_is_arrested = false;
		life_bail_paid = false;
		hint localize "STR_Jail_Paid";
		serv_wanted_remove = [player];
		player setPos (getMarkerPos "jail_release");
		[getPlayerUID player] remoteExecCall ["life_fnc_wantedRemove",RSERV];
		[5] call SOCK_fnc_updatePartial;
	};
	case (_esc): {
		life_is_arrested = false;
		hint localize "STR_Jail_EscapeSelf";
		[0,"STR_Jail_EscapeNOTF",true,[profileName]] remoteExecCall ["life_fnc_broadcast",RCLIENT];
		[getPlayerUID player,profileName,"901"] remoteExecCall ["life_fnc_wantedAdd",RSERV];
		[5] call SOCK_fnc_updatePartial;
	};
	case (alive player && !_esc && !_bail): {
		life_is_arrested = false;
		hint localize "STR_Jail_Released";
		[getPlayerUID player] remoteExecCall ["life_fnc_wantedRemove",RSERV];
		player setPos (getMarkerPos "jail_release");
		[5] call SOCK_fnc_updatePartial;
	};
};

Alles anzeigen

Ich hoffe ich kann hiermit ein paar Leute helfen die auch Probleme mit der Jail Time haben

Von meiner Seite kann geclosed werden

PS: Danke an @B4v4r!4n_Str!k3r , @shenzox und @PoweredByte für die Hilfe

Tyreed

hi @Askeroth

Gibt es vielleicht eine Möglichkeit in deine datein reinzusehen,
Ich habe das Problem, dass meine DB immer hin und her switched,
Also ich sende jemand 60 Minuten ins Gefängnis,
und er zählt gleichzeitig die 15 Minuten mit runter,
schaltet die Uhr auf 59 Minuten runter tut er dieses ebenfalls bei den 15 Minuten auf 14.

Meine Log verzeichnet das ganze so:

15:18:44 "[Jailtime] sending jailtime to databse"
15:18:44 "[Jailtime] for the player Hans is 15"
15:18:44 "[Jailtime] sending jailtime to databse"
15:18:44 "[Jailtime] for the player Hans is 60"

Ich sehe den Wald vor lauter Bäume nicht.
Bin über jede Hilfe dankbar.
Gruss Tyreed

nappel4life

Hallo,

auch ich habe Probleme mit der Jailtime. Bei mir wird nichts in die DB eingetragen außer arrested = 1. Leider ist ja altisrpg nicht mehr erreichbar bzw wurde dort alles gelöscht. Könntest du @Askeroth uns die wichtigsten Files bereitstellen? Habe das Scripts vom 3.1.4.8 genommen und mit der Remoteexec-Programm entsprechend alles umgewandelt. Hab auch keinen Eintrag in der Serverlog, Clientlog und exdb-log.

Askeroth

Huhu

Ich werd mich heut evtl. noch dransetzen und ein tutorial machen bzw. die Files raussuchen.

LG

nappel4life

Das wäre sehr nett von ihnen.

Askeroth

So Nun hab ich das Tutorial Fertig

Zu finden ist es hier [Tutorial] Jail Time für 4.4 R3

nun aber Close

Jail Time Problem [Behoben]

Ähnliche Themen

Hilfe Cop uniform

Housing Problem wer kann mir helfen ???

SQL Eintrag

Ich kann mir nichts mehr Kaufen D:

SOS-Knöpfe für Cops

So 2 Problem jail time bei den cops

Tags