Verarbeiter Problem | Kosten kein Geld ohne Lizenz

x33Pingu

Hey wie oben schon erwähnt kostest das verarbeiten kein Geld (ohne Lizenz) das ist ja nicht Sinn der Sache vielleicht habe ich ja was falsch gemacht aber wäre nett wenn mir jemand dabei helfen könnte

C

this enableSimulation false; this allowDamage false; this addAction[localize"@STR_Process_Ver_himbeeren",life_fnc_processAction,"himbeeren",0,false,false,"",' life_inv_himbeeren > 0 && !life_is_processing']; this addAction[format["%1 ($%2)",localize (getText(missionConfigFile >> "Licenses" >> "destille" >> "displayName")), [(getNumber(missionConfigFile >> "Licenses" >> "destille" >> "price"))] call life_fnc_numberText],life_fnc_buyLicense,"destille",0,false,false,"",' !license_civ_destille && playerSide == civilian '];

br1zey

1 wäre die fn_processAction gut zu sehn ???? wenn könnte da der fehler sein

2 Verarbeiter class bei dir himbeeren und licenses variable bei dir destille sollten eigentlch immer gleich sein

also zeig bitte mal deine fn_processAction

x33Pingu

C

#include "..\..\script_macros.hpp"
/*
	File: fn_processAction.sqf
	Author: Bryan "Tonic" Boardwine

	Description:
	Master handling for processing an item.
*/
private["_vendor","_type","_itemInfo","_oldItem","_newItem","_cost","_upp","_hasLicense","_itemName","_oldVal","_ui","_progress","_pgText","_cP"];
_vendor = [_this,0,ObjNull,[ObjNull]] call BIS_fnc_param;
_type = [_this,3,"",[""]] call BIS_fnc_param;
//Error check
if(isNull _vendor OR EQUAL(_type,"") OR (player distance _vendor > 10)) exitWith {};




//unprocessed item,processed item, cost if no license,Text to display (I.e Processing  (percent) ..."
_itemInfo = switch (_type) do {
	//Himbeeren - Schnaps
	case "himbeeren": {["himbeeren","schnaps",880,(localize "STR_Process_schnaps")];};
	default {[];};
};




//Error checking
if(EQUAL(count _itemInfo,0)) exitWith {};




//Setup vars.
_oldItem = SEL(_itemInfo,0);
_newItem = SEL(_itemInfo,1);
_cost = SEL(_itemInfo,2);
_upp = SEL(_itemInfo,3);




if(_vendor in [himbeer_processor]) then {
	_hasLicense = true;
} else {
	_hasLicense = LICENSE_VALUE(_type,"civ");
};







_itemName = M_CONFIG(getText,"VirtualItems",_newItem,"displayName");
_oldVal = ITEM_VALUE(_oldItem);




_cost = _cost * _oldVal;
//Some more checks
if(EQUAL(_oldVal,0)) exitWith {};




//Setup our progress bar.
disableSerialization;
5 cutRsc ["life_progress","PLAIN"];
_ui = GVAR_UINS "life_progress";
_progress = _ui displayCtrl 38201;
_pgText = _ui displayCtrl 38202;
_pgText ctrlSetText format["%2 (1%1)...","%",_upp];
_progress progressSetPosition 0.01;
_cP = 0.01;




life_is_processing = true;




if(_hasLicense) then {
	while{true} do {
		sleep  0.3;
		_cP = _cP + 0.01;
		_progress progressSetPosition _cP;
		_pgText ctrlSetText format["%3 (%1%2)...",round(_cP * 100),"%",_upp];
		if(_cP >= 1) exitWith {};
		if(player distance _vendor > 10) exitWith {};
	};

	if(player distance _vendor > 10) exitWith {hint localize "STR_Process_Stay"; 5 cutText ["","PLAIN"]; life_is_processing = false;};
	if(!([false,_oldItem,_oldVal] call life_fnc_handleInv)) exitWith {5 cutText ["","PLAIN"]; life_is_processing = false;};
	if(!([true,_newItem,_oldVal] call life_fnc_handleInv)) exitWith {5 cutText ["","PLAIN"]; [true,_oldItem,_oldVal] call life_fnc_handleInv; life_is_processing = false;};
	5 cutText ["","PLAIN"];
	titleText[format[localize "STR_Process_Processed",_oldVal,localize _itemName],"PLAIN"];
	life_is_processing = false;
} else {
	if(CASH < _cost) exitWith {hint format[localize "STR_Process_License",[_cost] call life_fnc_numberText]; 5 cutText ["","PLAIN"]; life_is_processing = false;};

	while{true} do {
		sleep  0.9;
		_cP = _cP + 0.01;
		_progress progressSetPosition _cP;
		_pgText ctrlSetText format["%3 (%1%2)...",round(_cP * 100),"%",_upp];
		if(_cP >= 1) exitWith {};
		if(player distance _vendor > 10) exitWith {};
	};

	if(player distance _vendor > 10) exitWith {hint localize "STR_Process_Stay"; 5 cutText ["","PLAIN"]; life_is_processing = false;};
	if(CASH < _cost) exitWith {hint format[localize "STR_Process_License",[_cost] call life_fnc_numberText]; 5 cutText ["","PLAIN"]; life_is_processing = false;};
	if(!([false,_oldItem,_oldVal] call life_fnc_handleInv)) exitWith {5 cutText ["","PLAIN"]; life_is_processing = false;};
	if(!([true,_newItem,_oldVal] call life_fnc_handleInv)) exitWith {5 cutText ["","PLAIN"]; [true,_oldItem,_oldVal] call life_fnc_handleInv; life_is_processing = false;};
	5 cutText ["","PLAIN"];
	titleText[format[localize "STR_Process_Processed2",_oldVal,localize _itemName,[_cost] call life_fnc_numberText],"PLAIN"];
	SUB(CASH,_cost);
	life_is_processing = false;
};

Alles anzeigen

br1zey

dein Himberprocessor auf der map Heist nicht zufällig himbeer_processor

weil dan ist dein Problem hier

Code

if(_vendor in [himbeer_processor]) then {
 _hasLicense = true;
} else {
 _hasLicense = LICENSE_VALUE(_type,"civ");
};

x33Pingu

@br1zey ja war seine Name nun habe ich den rausgenommen und nun kann ich auch mit Lizenz nicht verarbeiten immer wieder wird Geld gefordert

br1zey

Zitat von br1zey

2 Verarbeiter class bei dir himbeeren und licenses variable bei dir destille sollten eigentlch immer gleich sein

x33Pingu

Ja danke habe ich auch schon bemerkt ich doofer junge xD