While Schleife hängt A3 für 2 min auf.

Tom Chandler

Moin zusammen,

Ich habe ein Problem mit einer While Schleife die mein Arma immer einfrieht.

Code

_run = true;

while {_run} do {
  if ("B_CombinationUnitRespirator_01_F" in backpack player) then {
      hint "Alles Save!";
  } else {
      hint "Du wirst sterben!!!";
      [player, 0.25, "body", "punch"] call ace_medical_fnc_addDamageToUnit;
    };
    sleep 5;
};

Alles anzeigen

Einstellung Trigger:

Aktivierung: Jeder Spieler

Aktivierungstyp: Vorhanden

Wiederholbar

Bei Deaktivierung: _run = false;

Ich habe zwar Sleep mit drin. Aber wenn ich in den Trigger laufe friehrt A3 ab.

Aufgabe davon ist es wenn jemand den Atemschutzgerät an hat bekommt der Spieler kein Schaden. Wenn er es nicht auf dem Rücken hat bekommt er schaden.

Übersehe ich etwas?

Danke schonmal für die Hilfe

Basti0208

Also ich sehe da mehrere Fehler.
Erstens (außer ich verbreite jetzt Halbwissen), muss die Variable _run als globale Variable deklariert werden. Hab mich nicht mit Triggern wirklich beschäftigt, könnte mir aber denken, dass das so sein muss.
Zweitens ist deine if-Abfrage nicht wirklich falsch, aber unnötig kompliziert. Du kannst ganz einfach "B_CombinationUnitRespirator_01_F" isEqualTo (backpack player) schreiben und musst nicht prüfen, ob der String in demString vorhanden ist.

Ansonsten würde mir spontan nichts auffallen, bin aber auch nicht der Trigger Experte.

Tom Chandler

Danke für die Hilfe.

Habe es am ende so gelöst

Code

contaminated = _this select 0;
_type = _this select 1;
_protected = false;
_masks = ["G_RegulatorMask_F"];
_uniform = ["U_I_E_CBRN_Suit_01_EAF_F"];
_backpack = ["B_CombinationUnitRespirator_01_F"];
_notify = false;
_sound = "warning";


while {contaminated} do {
if ("ChemicalDetector_01_watch_F" in (assignedItems player)) then {_notify = true} else {_notify = false};
if (( goggles player in _masks)&&(uniform player in _uniform)&&(backpack player in _backpack)) then {_protected = true} else {_protected = false};


switch (_protected) do {
case true: {
if (_notify) then {playSound _sound;};
};
case false: {
if (_notify) then {playSound _sound;};
[player, selectRandom[0.01,0.2,0.25,0.3] , "Body", selectrandom ["stab","falling","bite"]] call ace_medical_fnc_addDamageToUnit;
};
};
uiSleep 5;
};

Alles anzeigen

Basti0208

Das freut mich, dass du eine eigene Lösung gefunden hast.
Ich habe diese einfach mal aus Spaß ein bisschen umgeschrieben, damit es schöner umgesetzt ist
Kannst es dir gerne anschauen, ist definitiv leichter als dein Code-Schnipsel.

Code

contaminated = _this select 0;
private _masks = ["G_RegulatorMask_F"];
private _uniforms = ["U_I_E_CBRN_Suit_01_EAF_F"];
private _backpacks = ["B_CombinationUnitRespirator_01_F"];
private _sound = "warning";
while {contaminated} do {
    if ("ChemicalDetector_01_watch_F" in (assignedItems player)) then {
        playSound _sound;
    };
    if !((goggles player) in _masks && {(uniform player) in _uniforms} && {(backpack player) in _backpacks}) then {
        [player, selectRandom[0.01,0.2,0.25,0.3] , "Body", selectrandom ["stab","falling","bite"]] call ace_medical_fnc_addDamageToUnit;
    };
    uiSleep 5;
};

Alles anzeigen

Tom Chandler

Danke Basti. Sieht auf jeden fall besser aus.

Habe erst vorkurzem mit SQF angefangen. Benutze die Scripts auch nur für Clan Missionen. Da ist es nicht so schlimm wenn sie nicht so Optimiert sind.

nox 15. Juni 2023 um 23:56