Wanted List - Grund einbinden

TheFireRunner Felix

Guten Tag ihr SQF Profis

Ich habe momentan folgenes Problem ich will bei der Benachrichtigung wenn jemand zur Fandungsliste hinzugefügt wird den Grund dafür hinzufügen.

Momentan sieht es wie folgt aus:

Code: fn_wantedAddP.sqf

#include "..\..\script_macros.hpp"
/*
    File: fn_wantedAddP.sqf
    Author:

    Description:

*/
//if !(playerSide isEqualTo west) exitWith {hint localize "STR_Cop_wantedList_notCop";};
if ((lbCurSel 2406) isEqualTo -1) exitWith {hint localize "STR_Cop_wantedList_noPlayerSelected";};
if ((lbCurSel 2407) isEqualTo -1) exitWith {hint localize "STR_Cop_wantedList_noCrimeSelected";};
private _unit = lbData [2406,lbCurSel 2406];
_unit = call compile format ["%1",_unit];
private _amount = lbData [2407,lbCurSel 2407];

[ format ["%1 hat %2 aufgrund von %3 auf die Fahndungsliste geschrieben", player getVariable["realname",name player], _unit getVariable["realname",name _unit],_amount], false ,"fast"] remoteExec ["life_fnc_notification_system",0];

if (life_HC_isActive) then {
    [getPlayerUID _unit,_unit getVariable ["realname",name _unit],_amount] remoteExecCall ["HC_fnc_wantedAdd",HC_Life];
} else {
    [getPlayerUID _unit,_unit getVariable ["realname",name _unit],_amount] remoteExecCall ["life_fnc_wantedAdd",RSERV];
};

Alles anzeigen

Nur jetzt ist das Problem dass da die Nummer von der Crime Liste (in dem Falle 187V)steht und nicht der Grund... Siehe hier:

Code: Config_Master.hpp

{"STR_Crime_187V","6500","187V"},

Weiß jemand wie ich den Text anzeigen lassen kann? Also localize "STR_Crime_187V"?

Mit grüßen Felix

Joe Barbaro

Format localize ["STR_Crime_%1",_amount];

Musst du noch ein wenig anpassen aber Versuchs mal

Mit freundlichen Grüßen

Joe Barbaro

Tass

in der stringtable.xml wo alle str_ sachen drinne stehen ?

Joe Barbaro

Zitat von Tass

in der stringtable.xml wo alle str_ sachen drinne stehen ?

Ne in deinem hint bzw notification system

TheFireRunner Felix

Joe Barbaro Danke dir dafür Mit ein paar Gehirnzellen wäre ich auch drauf gekommen aber du hast mir auf jeden Fall auf die Sprünge geholfen.

Mein Fertiger Code:

Code: fn_wantedAddP.sqf

#include "..\..\script_macros.hpp"
/*
    File: fn_wantedAddP.sqf
    Author:

    Description:

*/
//if !(playerSide isEqualTo west) exitWith {hint localize "STR_Cop_wantedList_notCop";};
if ((lbCurSel 2406) isEqualTo -1) exitWith {hint localize "STR_Cop_wantedList_noPlayerSelected";};
if ((lbCurSel 2407) isEqualTo -1) exitWith {hint localize "STR_Cop_wantedList_noCrimeSelected";};
private _unit = lbData [2406,lbCurSel 2406];
_unit = call compile format ["%1",_unit];
private _amount = lbData [2407,lbCurSel 2407];
private _grund1 = format ["STR_Crime_%1",_amount];
private _grund2 = localize _grund1;

[ format ["%1 hat %2 aufgrund von %3 auf die Fahndungsliste geschrieben", player getVariable["realname",name player], _unit getVariable["realname",name _unit], _grund2], false ,"fast"] remoteExec ["life_fnc_notification_system",0];

if (life_HC_isActive) then {
    [getPlayerUID _unit,_unit getVariable ["realname",name _unit],_amount] remoteExecCall ["HC_fnc_wantedAdd",HC_Life];
} else {
    [getPlayerUID _unit,_unit getVariable ["realname",name _unit],_amount] remoteExecCall ["life_fnc_wantedAdd",RSERV];
};

Alles anzeigen