[Tutorial] [Altis Life 5.0] V- und I-Items nach dem Tod in einer Lootbox

#include "..\..\script_macros.hpp"
/*
 File: fn_dropItems.sqf
 Author: moeck
 Description:
 Called on death, Player drops any 'virtual' items and items. They are stored in a plastic case.
 
*/
params [
    ["_unit",objNull,[objNull]]
];
private _restricted_items = LIFE_SETTINGS(getArray,"drop_restricted_vitems");
private _pos = _unit modelToWorld[0,3,0];
_pos = [(_pos select 0),(_pos select 1),0];
private _obj = "Land_PlasticCase_01_small_F" createVehicle _pos; //Solltet ihr ein anderes Objekt wollen, den Classname in allen für diese Funktion benötigten Scripts ändern.
clearWeaponCargoGlobal _obj;
clearItemCargoGlobal _obj;
clearMagazineCargoGlobal _obj;
clearBackpackCargoGlobal _obj;
_name = format ["%1's Lootbox",name _unit];
_obj setVariable ["Name",_name,true]; // %1 bewirkt die Anzeige des Namens des verstorbenen Spielers an, so dass ihr das "'s Lootbox" ändern könnt falls gewünscht.
private _trunk =[];
private _weight = 0;
{
    private _value = 0;
    private _iweight = 0;
    private _itemName= "";
    private _item = "";
    if (_x isEqualType "") then {_item = _x;} else {_item = configName _x};
    if (_item isEqualTo "life_cash") then {
        _value = CASH;
        _itemName = "CASH";
        _item = "money";
    } else {
        _value = ITEM_VALUE(_item);
        _iweight = (([_item] call life_fnc_itemWeight) * _value);
        _itemName = ITEM_VARNAME(_item);
    };
    _weight = _weight + _iweight;
    if (_value > 0 && !(_item in _restricted_items)) then {
        _trunk pushBack [_item,_value];
    };
    missionNamespace setVariable [_itemName,0];
} forEach (("true" configClasses (missionConfigFile >> "VirtualItems")) + ["life_cash"]);
_obj setVariable["Trunk",[_trunk,_weight],true];
if (LIFE_SETTINGS(getNumber,"drop_iitems_onDeath") isEqualTo 1) then {
    private _restricted_iitems = LIFE_SETTINGS(getArray,"restricted_iitems_onDeath");
    if (!(uniform _unit isEqualTo "")) then {
        {        
            if !(_x in _restricted_iitems) then {_obj addItemCargoGlobal [_x, 1]};
            _unit removeItem _x
        } forEach (uniformItems _unit);
        if (LIFE_SETTINGS(getNumber,"drop_cloth_onDeath") isEqualTo 1 && !(uniform _unit in _restricted_iitems)) then {_obj addItemCargoGlobal [uniform _unit, 1];removeUniform _unit};
    };
    if (!(backpack _unit isEqualTo "")) then {
        {
            if !(_x in _restricted_iitems) then {_obj addItemCargoGlobal [_x, 1]};
            _unit removeItem _x;
        } forEach (backpackItems _unit);
        if (LIFE_SETTINGS(getNumber,"drop_cloth_onDeath") isEqualTo 1 && !(backpack _unit in _restricted_iitems)) then {_obj addItemCargoGlobal [backpack _unit, 1];removeBackpack _unit};
    };
    if (!(vest _unit isEqualTo "")) then {
        {
            if !(_x in _restricted_iitems) then {_obj addItemCargoGlobal [_x, 1]};
            _unit removeItem _x
        } forEach (vestItems _unit);
        if (LIFE_SETTINGS(getNumber,"drop_cloth_onDeath") isEqualTo 1  && !(vest _unit in _restricted_iitems)) then {_obj addItemCargoGlobal [vest _unit, 1];removeVest _unit};
    };
    if (count (primaryWeaponItems _unit) > 0) then {
        {
            if !(_x in _restricted_iitems) then {_obj addItemCargoGlobal [_x, 1]};
            _unit removeItem _x
        } forEach (primaryWeaponItems _unit);
    };
    if (count (handgunItems _unit) > 0) then {
        {
            if !(_x in _restricted_iitems) then {_obj addItemCargoGlobal [_x, 1]};
            _unit removeItem _x
        } forEach (handGunItems _unit);
    };
    if (!(primaryWeapon _unit isEqualTo "") && !(primaryWeapon _unit in _restricted_iitems)) then {_obj addItemCargoGlobal [(primaryWeapon _unit), 1]};
    if (!(handgunWeapon _unit isEqualTo "") && !(handgunWeapon _unit in _restricted_iitems)) then {_obj addItemCargoGlobal [(handgunWeapon _unit), 1]};
    if (!(headgear _unit isEqualTo "") && !(primaryWeapon _unit in _restricted_iitems) && LIFE_SETTINGS(getNumber,"drop_cloth_onDeath") isEqualTo 1) then {_obj addItemCargoGlobal [(headgear _unit), 1]; removeHeadgear _unit};
    removeAllWeapons _unit;
    {player removeMagazine _x;} forEach (magazines _unit);
};
[_obj] spawn {
    params ["_obj"];
    _timer = LIFE_SETTINGS(getNumber,"lootbox_timer");
    uisleep (_timer*60);
    deleteVehicle _obj;
};