Rangbild neben Namtag

Skilex

Grüß euch,

habe mal ein Paar Fragen zu den Bilder die Ingame neben dem Namen stehen. Ich würde diese gerne zu Österreichischen Rangbildern ändern.

Habe den Pfad der Bilder unter core/functions/fn_playerTags.sqf gefunden.

Hier die Datei:

Code

#include "..\..\script_macros.hpp"
/*
    File: fn_playerTags.sqf
    Author: Bryan "Tonic" Boardwine

    Description:
    Adds the tags above other players heads when close and have visible range.
*/
if (!life_settings_tagson) exitWith {};
private ["_ui","_units","_masks"];
#define iconID 78000
#define scale 0.8

if (visibleMap || {!alive player} || {dialog}) exitWith {
    500 cutText["","PLAIN"];
};

_ui = uiNamespace getVariable ["Life_HUD_nameTags",displayNull];
if (isNull _ui) then {
    500 cutRsc["Life_HUD_nameTags","PLAIN"];
    _ui = uiNamespace getVariable ["Life_HUD_nameTags",displayNull];
};

_units = nearestObjects[(visiblePosition player),["Man","Land_Pallet_MilBoxes_F","Land_Sink_F"],50];
_units = _units - [player];

_masks = LIFE_SETTINGS(getArray,"clothing_masks");

private _index = -1;
{
    private "_text";
    _idc = _ui displayCtrl (iconID + _forEachIndex);
    if (!(lineIntersects [eyePos player, eyePos _x, player, _x]) && alive _x && {!isNil {_x getVariable "realname"}}) then {
        _pos = switch (typeOf _x) do {
            case "Land_Pallet_MilBoxes_F": {[visiblePosition _x select 0, visiblePosition _x select 1, (getPosATL _x select 2) + 1.5]};
            case "Land_Sink_F": {[visiblePosition _x select 0, visiblePosition _x select 1, (getPosATL _x select 2) + 2]};
            default {[visiblePosition _x select 0, visiblePosition _x select 1, ((_x modelToWorld (_x selectionPosition "head")) select 2)+.5]};
        };
        _sPos = worldToScreen _pos;
        _distance = _pos distance player;
        if (!((headgear _x) in _masks || (goggles _x) in _masks || (uniform _x) in _masks)) then {
            if (count _sPos > 1 && {_distance < 15}) then {
                _text = switch (true) do {
                    case (_x in (units group player) && playerSide isEqualTo civilian): {format ["<t color='#00FF00'>%1</t>",(_x getVariable ["realname",name _x])];};
                    case (side _x isEqualTo west && {!isNil {_x getVariable "rank"}}): {format ["<img image='%1' size='1'></img> %2",switch ((_x getVariable "rank")) do {
                        case 2: {"textures\Inspektor.jpg"};
                        case 3: {"textures\Revierinspektor.jpg"};
                        case 4: {"textures\Gruppeninspektor.jpg"};
                        case 5: {"textures\Hauptmann.jpg"};
                        case 6: {"textures\Brigadier.jpg"};
                        case 7: {"textures\Generalmajor.jpg"};
                        case 8: {"textures\sek.png"};
                        case 9: {"textures\General.jpg"};
                        default {"textures\Aspirant.jpg"};
                        },_x getVariable ["realname",name _x]]};
                    case (side _x isEqualTo independent): {format ["<t color='#FF0000'><img image='a3\ui_f\data\map\MapControl\hospital_ca.paa' size='1.5'></img></t> %1",_x getVariable ["realname",name _x]]};
                    default {
                        if (!isNil {(group _x) getVariable "gang_name"}) then {
                            format ["%1<br/><t size='0.8' color='#B6B6B6'>%2</t>",_x getVariable ["realname",name _x],(group _x) getVariable ["gang_name",""]];
                        } else {
                            if (alive _x) then {
                                _x getVariable ["realname",name _x];
                            } else {
                                if (!isPlayer _x) then {
                                    _x getVariable ["realname","ERROR"];
                                };
                            };
                        };
                    };
                };

                _idc ctrlSetStructuredText parseText _text;
                _idc ctrlSetPosition [_sPos select 0, _sPos select 1, 0.4, 0.65];
                _idc ctrlSetScale scale;
                _idc ctrlSetFade 0;
                _idc ctrlCommit 0;
                _idc ctrlShow true;
            } else {
                _idc ctrlShow false;
            };
        } else {
            _idc ctrlShow false;
        };
    } else {
        _idc ctrlShow false;
    };
    _index = _forEachIndex;
} forEach _units;
(_ui displayCtrl (iconID + _index + 1)) ctrlSetStructuredText parseText "";

Alles anzeigen

Habe desweiteren den Rang 8 (SEK) sowie Rang 9 (General) in der Mysql hinzugefügt und hier in der Datei eingefügt. Wieso zeigt der mir nun jetzt nicht die Bilder Ingame an und schreibt das Generalmajor.jpg fehlt ??

Bitte um Hilfe bin am verzweifeln.

MFG

NiceKype

Wie wäre es erstmals paa Dateien zu benutzen wie es von Anfang an angegeben war

Zudem wäre es sinnvoll 1. in den Logs nachzuschauen und 2. deine Life Version dazu zu schreiben.

Ich habe mal meine alten Backups durchsucht und eine Datei gefunden die funktionieren sollte. Kannst du ja mal ausprobieren. Am besten aber mit Backup

Code

#include <macro.h>
/*
    File: fn_playerTags.sqf
    Author: Bryan "Tonic" Boardwine
    
    Description:
    Adds the tags above other players heads when close and have visible range.
*/
private["_ui","_units","_goggles"];
#define iconID 78000
#define scale 0.8
_goggles = ["G_Bandanna_aviator","G_Bandanna_beast","G_Balaclava_blk"];
_uniform = ["U_I_GhillieSuit"];
_headgear = ["H_Shemag_olive","H_ShemagOpen_khk","H_CrewHelmetHeli_B"];

if(visibleMap OR {!alive player} OR {dialog} OR {life_isFlashed}) exitWith {
    500 cutText["","PLAIN"];
};

_ui = uiNamespace getVariable ["Life_HUD_nameTags",displayNull];
if(isNull _ui) then {
    500 cutRsc["Life_HUD_nameTags","PLAIN"];
    _ui = uiNamespace getVariable ["Life_HUD_nameTags",displayNull];
};

_units = nearestObjects[(visiblePosition player),["Man","Land_Pallet_MilBoxes_F","Land_Sink_F"],50];

_units = _units - [player];

{
    private["_text"];
    _idc = _ui displayCtrl (iconID + _forEachIndex);
    if(!(lineIntersects [eyePos player, eyePos _x, player, _x]) && {!isNil {_x getVariable "realname"}}) then {
        _pos = switch(typeOf _x) do {
            case "Land_Pallet_MilBoxes_F": {[visiblePosition _x select 0, visiblePosition _x select 1, (getPosATL _x select 2) + 1.5]};
            case "Land_Sink_F": {[visiblePosition _x select 0, visiblePosition _x select 1, (getPosATL _x select 2) + 2]};
            default {[visiblePosition _x select 0, visiblePosition _x select 1, ((_x modelToWorld (_x selectionPosition "head")) select 2)+.5]};
        };
        _sPos = worldToScreen _pos;
        _distance = _pos distance player;
        if(count _sPos > 1 && {_distance < 15}) then {
            _text = switch (true) do {
                case ((headgear _x) in _headgear): {format["<t color='#000000'></t>"];};
                case ((goggles _x) in _goggles): {format["<t color='#000000'></t>"];};
                case (_x in (units grpPlayer) && playerSide == civilian): {format["<t color='#00FF00'>%1</t>",(_x getVariable ["realname",name _x])];};
                case(_x getVariable["vip",false]): {format["<t color='#00FF00'>[VIP] %1</t>",(_x getVariable ["realname",name _x])]};
                case (!isNil {(_x getVariable "rank")} &&  side _x == west): {format["<img image='%1' size='1'></img> <t size='1.2' color='#318CE7'>%3<br/></t>%2",
                    switch ((_x getVariable "rank")) do {
                        case 2: {"icons\cop\rank2.paa"};
                        case 3: {"icons\cop\rank3.paa"};
                        case 4: {"icons\cop\rank4.paa"};
                        case 5: {"icons\cop\rank5.paa"};
                        case 6: {"icons\cop\rank6.paa"};
                        case 7: {"icons\cop\rank7.paa"};
                        case 8: {"icons\cop\rank8.paa"};
                        case 9: {"icons\cop\rank9.paa"};
                        case 10: {"icons\cop\rank10.paa"};
                        case 11: {"icons\cop\rank11.paa"};
                        default {"icons\cop\rank1.paa"};
                    },
                    _x getVariable ["realname",name _x],
                    switch ((_x getVariable "rank")) do {
                            case 2: {"Meister"};
                            case 3: {"Wachtmeister"};
                            case 4: {"Oberwachtmeister"};
                            case 5: {"Hauptwachtmeister"};
                            case 6: {"Kommissar"};
                            case 7: {"Oberkommissar"};
                            case 8: {"Hauptkommissar"};
                            case 9: {"Polizeidirektor"};
                            case 10: {"Stellv. Polizeipräsident"};
                            case 11: {"Polizeipräsident"};
                            default {"Anwärter"};
                        }
                    ]
                };
                case (!isNil {(_x getVariable "med")} &&  side _x == independent): {format["<img image='%1' size='1'></img> <t size='1.2' color='#ff0000'>%3<br/></t>%2",
                    switch ((_x getVariable "med")) do {
                        case 2: {"icons\med\rank2.paa"};
                        case 3: {"icons\med\rank3.paa"};
                        case 4: {"icons\med\rank4.paa"};
                        case 5: {"icons\med\rank5.paa"};
                        case 6: {"icons\med\rank6.paa"};
                        case 7: {"icons\med\rank7.paa"};
                        case 8: {"icons\med\rank8.paa"};
                        default {"icons\med\rank1.paa"};
                    },
                    _x getVariable ["realname",name _x],
                    switch ((_x getVariable "med")) do {
                            case 2: {"Brandmeister"};
                            case 3: {"Oberbrandmeister"};
                            case 4: {"Brandinspektor"};
                            case 5: {"Oberbrandinspektor"};
                            case 6: {"Brandrat"};
                            case 7: {"Branddirektor"};
                            case 8: {"Leitender Branddirektor"};
                            default {"Azubi"};
                        }
                    ]
                };
                case (_x isequalto nsa) : {"FBI"};
                default {
                    if(!isNil {(group _x) getVariable "gang_name"}) then {
                        format["%1<br/><t size='0.8' color='#B6B6B6'>%2</t>",_x getVariable ["realname",name _x],(group _x) getVariable ["gang_name",""]];
                    } else {
                        _x getVariable ["realname",name _x];
                    };
                };
            };
            if(_x getVariable ["speaking",false]) then {
                _text = format ["<img image='\A3\ui_f\data\igui\rscingameui\rscdisplayvoicechat\microphone_ca.paa' size='1.5'></img>"] + _text;
            };
            _idc ctrlSetStructuredText parseText _text;
            _idc ctrlSetPosition [_sPos select 0, _sPos select 1, 0.4, 0.65];
            _idc ctrlSetScale scale;
            _idc ctrlSetFade 0;
            _idc ctrlCommit 0;
            _idc ctrlShow true;
        } else {
            _idc ctrlShow false;
        };
    } else {
        _idc ctrlShow false;
    };
} foreach _units;

Alles anzeigen

Skilex

Danke dir Probiere das mal

Skilex

Deine Datei hat leider nicht Funktioniert, aber habe sämtliche Bilder in eine Paa umgewandelt und es hat funktioniert.

Danke dir.

NiceKype

Arma liest nur png und paa dateien. Da png aber erst bei max 10m angezeigt wird empfehle ich immer paa zu nehmen.

Das meine Datei nicht funktioniert ist zwar schade aber erwartenswert gewesen. Weiß nichtmal mehr von welcher Version das war

aber bitte bitte

#erledigt

zlTricks

Das wär mir neu das Arma nur png und paas ließt :O

Benutze vieles mit jpg NiceKype

Mfg

NiceKype

Endschuldiegung, falsch ausgedrückt. Bei den meißten Skripten und Inhalten werden nur png und paa gelesen.

blackfisch

Zitat von =Recon=

Endschuldiegung, falsch ausgedrückt. Bei den meißten Skripten und Inhalten werden nur png und paa gelesen.

Arma 3 unterstützt keine PNG-Dateien. nur JPG und PAA

NiceKype

Ups verwechselt

BetaDog

ist die größe egal bei den Bildern?

Kuchenplatte

Zitat von Mabu2025

ist die größe egal bei den Bildern?

16x16 32x32 64x64 usw

BetaDog

ok danke