Beiträge von Julian

#include "..\..\script_macros.hpp"
/*
 File: fn_onPlayerRespawn.sqf
 Author: Bryan "Tonic" Boardwine
 Description:
 Does something but I won't know till I write it...
*/
private ["_unit","_corpse","_containers"];
_unit = _this select 0;
_corpse = _this select 1;
life_corpse = _corpse;
//Set some vars on our new body.
_unit setVariable ["restrained",false,true];
_unit setVariable ["Escorting",false,true];
_unit setVariable ["transporting",false,true];
_unit setVariable ["playerSurrender",false,true];
_unit setVariable ["steam64id",getPlayerUID player,true]; //Reset the UID.
//_unit setVariable ["realname",profileName,true]; //Reset the players name.
[_unit] call life_fnc_nameTag;
_unit addRating 1e12; //Set our rating to a high value, this is for a ARMA engine thing.
player playMoveNow "AmovPpneMstpSrasWrflDnon";
[] call life_fnc_setupActions;
[_unit,life_settings_enableSidechannel,playerSide] remoteExecCall ["TON_fnc_manageSC",RSERV];
if (LIFE_SETTINGS(getNumber,"enable_fatigue") isEqualTo 0) then {player enableFatigue false;};

#include "..\..\script_macros.hpp"
private ["_gangName","_length","_badChar","_chrByte","_allowed"];
disableSerialization;
_gangName = ctrlText (CONTROL(2520,2522));
private _gangTag = ctrlText (CONTROL(2520,2523));
_length = count (toArray(_gangName));
_chrByte = toArray (_gangName);
private _chrByteTag = toArray (_gangTag);
private _lengthTag = count (_chrByteTag); 
_allowed = toArray("ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789_ ");
if (_length > 32) exitWith {hint localize "STR_GNOTF_Over32"};
if (_lengthTag > 4) exitWith {hint localize "STR_GNOTF_Over4"}; 
_badChar = false;
{if (!(_x in _allowed)) exitWith {_badChar = true;};} forEach _chrByte;
if (_badChar) exitWith {hint localize "STR_GNOTF_IncorrectChar";};
{if (!(_x in _allowed)) exitWith {_badCharTag = true;};} forEach _chrByteTag;
if (_badChar) exitWith {hint localize "STR_GNOTF_IncorrectChar";}; 
if (_lengthTag > 1) then {_gangTag = format ["[%1]",_gangTag];};
if (BANK < (LIFE_SETTINGS(getNumber,"gang_price"))) exitWith {hint format [localize "STR_GNOTF_NotEnoughMoney",[((LIFE_SETTINGS(getNumber,"gang_price")) - BANK)] call life_fnc_numberText];};
if (life_HC_isActive) then {
 [player,getPlayerUID player,_gangName,_gangTag] remoteExec ["HC_fnc_insertGang",HC_Life]; 
} else {
 [player,getPlayerUID player,_gangName,_gangTag] remoteExec ["TON_fnc_insertGang",RSERV]; 
};
if (LIFE_SETTINGS(getNumber,"player_advancedLog") isEqualTo 1) then {
 if (LIFE_SETTINGS(getNumber,"battlEye_friendlyLogging") isEqualTo 1) then {
 advanced_log = format [localize "STR_DL_AL_createdGang_BEF",_gangName,(LIFE_SETTINGS(getNumber,"gang_price"))];
 } else {
 advanced_log = format [localize "STR_DL_AL_createdGang",profileName,(getPlayerUID player),_gangName,(LIFE_SETTINGS(getNumber,"gang_price"))];
 };
 publicVariableServer "advanced_log";
};
hint localize "STR_NOTF_SendingData";
closeDialog 0;
life_action_gangInUse = true;

/*
 File: fn_queryPlayerGang.sqf
 Author: Bryan "Tonic" Boardwine
 modified: moeck
 Description:
 Queries to see if the player belongs to any gang.
*/
private ["_query","_queryResult"];
_query = format ["SELECT id, owner, name, maxmembers, bank, members, gangtag FROM gangs WHERE active='1' AND members LIKE '%2%1%2'",_this,"%"];
_queryResult = [_query,2] call DB_fnc_asyncCall;
if !(count _queryResult isEqualTo 0) then {
 _tmp = [_queryResult select 5] call DB_fnc_mresToArray;
 if (_tmp isEqualType "") then {_tmp = call compile format ["%1", _tmp];};
 _queryResult set[5, _tmp];
};
missionNamespace setVariable [format ["gang_%1",_this],_queryResult];

#include "..\..\script_macros.hpp"
/*
 File: fn_initGang.sqf
 Author: Bryan "Tonic" Boardwine
 modified: moeck
 Description:
 Main initialization for gangs.
*/
private ["_exitLoop","_group","_wait"];
if !(playerSide isEqualTo civilian) exitWith {}; //What in the hell?
[player] join (createGroup civilian);
player setVariable ["playername",(name player),true];
if (count life_gangData isEqualTo 0) exitWith {}; //Dafuq?
_wait = round(random(8));
sleep _wait;
//Loop through to make sure there is not a group already created with the gang.
_exitLoop = false;
{
 _groupName = _x getVariable "gang_name";
 if (!isNil "_groupName") then {
 _groupOwner = _x getVariable ["gang_owner",""];
 _groupID = _x getVariable "gang_id";
 if (_groupOwner isEqualTo "" || isNil "_groupID") exitWith {}; //Seriously?
 if ((life_gangData select 0) isEqualTo _groupID && {(life_gangData select 1) isEqualTo _groupOwner}) exitWith {_group = _x; _exitLoop = true;};
 };
} forEach allGroups;
if (!isNil "_group") then {
 [player] join _group;
 if ((life_gangData select 1) isEqualTo getPlayerUID player) then {
 _group selectLeader player;
 [player,_group] remoteExecCall ["TON_fnc_clientGangLeader",(units _group)];
 };
} else {
 _group = group player;
 _group setVariable ["gang_id",(life_gangData select 0),true];
 _group setVariable ["gang_owner",(life_gangData select 1),true];
 _group setVariable ["gang_name",(life_gangData select 2),true];
 _group setVariable ["gang_maxMembers",(life_gangData select 3),true];
 _group setVariable ["gang_bank",(life_gangData select 4),true];
 _group setVariable ["gang_members",(life_gangData select 5),true];
 _group setVariable ["gang_tag",(life_gangData select 6),true];
};
_playername = format ["%1 %2",(life_gangData select 6),(name player)];
player setVariable ["playername",_playername,true];

#include "..\script_macros.hpp"
/*
 File: fn_initCiv.sqf
 Author: Bryan "Tonic" Boardwine
 Description:
 Initializes the civilian.
*/
private _altisArray = ["Land_i_Shop_01_V1_F","Land_i_Shop_01_V2_F","Land_i_Shop_01_V3_F","Land_i_Shop_02_V1_F","Land_i_Shop_02_V2_F","Land_i_Shop_02_V3_F"];
private _tanoaArray = ["Land_House_Small_01_F"];
private _spawnBuildings = [[["Altis", _altisArray], ["Tanoa", _tanoaArray]]] call TON_fnc_terrainSort;
civ_spawn_1 = nearestObjects[getMarkerPos "civ_spawn_1", _spawnBuildings,350];
civ_spawn_2 = nearestObjects[getMarkerPos "civ_spawn_2", _spawnBuildings,350];
civ_spawn_3 = nearestObjects[getMarkerPos "civ_spawn_3", _spawnBuildings,350];
civ_spawn_4 = nearestObjects[getMarkerPos "civ_spawn_4", _spawnBuildings,350];
waitUntil {!(isNull (findDisplay 46))};
if (life_is_alive && !life_is_arrested) then {
 /* Spawn at our last position */
 player setVehiclePosition [life_civ_position, [], 0, "CAN_COLLIDE"];
} else {
 if (!life_is_alive && !life_is_arrested) then {
 if (LIFE_SETTINGS(getNumber,"save_civilian_positionStrict") isEqualTo 1) then {
 _handle = [] spawn life_fnc_civLoadout;
 waitUntil {scriptDone _handle};
 CASH = 0;
 [0] call SOCK_fnc_updatePartial;
 };
 [] call life_fnc_spawnMenu;
 waitUntil{!isNull (findDisplay 38500)}; //Wait for the spawn selection to be open.
 waitUntil{isNull (findDisplay 38500)}; //Wait for the spawn selection to be done.
 } else {
 if (life_is_arrested) then {
 life_is_arrested = false;
 [player,true] spawn life_fnc_jail;
 };
 };
};
if (LIFE_SETTINGS(getNumber,"civ_extendedNames") isEqualTo 1) then { [] call life_fnc_nameTag;};
life_is_alive = true;

#include "..\script_macros.hpp"
/*
 File: fn_initCop.sqf
 Author: Bryan "Tonic" Boardwine
 modified: moeck
 Description:
 Cop Initialization file.
 Set name tags based on the license and rank
*/
waitUntil {!(isNull (findDisplay 46))};
if (life_blacklisted) exitWith {
 ["Blacklisted",false,true] call BIS_fnc_endMission;
 sleep 30;
};
if (!(str(player) in ["cop_1","cop_2","cop_3","cop_4"])) then {
 if ((FETCH_CONST(life_coplevel) isEqualTo 0) && (FETCH_CONST(life_adminlevel) isEqualTo 0)) then {
 ["NotWhitelisted",false,true] call BIS_fnc_endMission;
 sleep 35;
 };
};
player setVariable ["rank",(FETCH_CONST(life_coplevel)),true];
if (LIFE_SETTINGS(getNumber,cop_extendedNames") isEqualTo 1) then { [] call life_fnc_nameTag;};
[] call life_fnc_spawnMenu;
waitUntil{!isNull (findDisplay 38500)}; //Wait for the spawn selection to be open.
waitUntil{isNull (findDisplay 38500)}; //Wait for the spawn selection to be done.

#include "..\script_macros.hpp"
/*
 File: fn_initMedic.sqf
 Author: Bryan "Tonic" Boardwine
 modified: moeck
 Description:
 Initializes the medic..
*/
waitUntil {!(isNull (findDisplay 46))};
if ((FETCH_CONST(life_medicLevel)) < 1 && (FETCH_CONST(life_adminlevel) isEqualTo 0)) exitWith {
 ["Notwhitelisted",false,true] call BIS_fnc_endMission;
 sleep 35;
};
if (LIFE_SETTINGS(getNumber,"medic_extendedNames") isEqualTo 1) then { [] call life_fnc_nameTag;};
[] call life_fnc_spawnMenu;
waitUntil{!isNull (findDisplay 38500)}; //Wait for the spawn selection to be open.
waitUntil{isNull (findDisplay 38500)}; //Wait for the spawn selection to be done.

#include "..\..\script_macros.hpp"
/*
 File: fn_nameTag.sqf
 Author: moeck
 
 Description:
 Sets alternate Names
*/
params ["_unit", ObjNull, [ObjNull]];
if (isNUll _unit) then {_unit = player};
private _nameTag = "";
private _newName = "";
call {
 //Cops
 if (side _unit isEqualTo west) exitWith {
 if (license_cop_chief) exitWith {"[Chief]"};
 //Die Reihenfolge musst Du selber festlegen welche Lizenz angezeigt werden soll!
 if (license_cop_statepolice) exitWith {_nameTag = format ["[SP-%1]",FETCH_CONST(life_coplevel)]};
 if (license_cop_police) exitWith {_nameTag = format ["[PD-%1]",FETCH_CONST(life_coplevel)]};
 };
 //Medics
 if (side _unit isEqualTo independent) exitWith {
 //Die Reihenfolge musst Du selber festlegen welche Lizenz angezeigt werden soll!
 if (((FETCH_CONST(life_medicLevel)) >= 1) && ((FETCH_CONST(life_medicLevel)) < 9)) exitWith {_nameTag = format ["[ADAC-%1]",(FETCH_CONST(life_medicLevel))]};
 if ((FETCH_CONST(life_medicLevel)) >= 9) exitWith {_nameTag = format ["[Feuerwehr-%1]",(FETCH_CONST(life_medicLevel))]};
 };
 if (side _unit isEqualTo civilian) exitWith {
 if (count life_gangData isEqualTo 0) exitWith {_nameTag = ""};
 _nameTag = format ["%1",(life_gangData select 6)];
 };
};
if !(_nameTag isEqualTo "") then {
 _newName = format ["%1 %2",_nameTag,(name _unit)];
} else {
 _newName = (name _unit);
};
_unit setVariable ["realname",_newName,true];

#include "\life_server\script_macros.hpp"
/*
 File: fn_insertGang.sqf
 Author: Bryan "Tonic" Boardwine
 modified: moeck
 Description:
 Inserts the gang into the database. Including now clantags (moeck)
*/
private ["_query","_queryResult","_gangMembers","_group"];
params [
 ["_ownerID",objNull,[objNull]],
 ["_uid","",[""]],
 ["_gangName","",[""]],
 ["_gangTag","",[""]]
];
_group = group _ownerID;
if (isNull _ownerID || _uid isEqualTo "" || _gangName isEqualTo "" || _gangTag isEqualTo "") exitWith {}; //Fail
_ownerID = owner _ownerID;
_gangName = [_gangName] call DB_fnc_mresString;
_gangTag = [_gangTag] call DB_fnc_mresString;
_query = format ["SELECT id FROM gangs WHERE (name='%1' or gangtag = '%2') AND active='1'",_gangName,_gangTag];
_queryResult = [_query,2] call DB_fnc_asyncCall;
//Check to see if the gang name already exists.
if (!(count _queryResult isEqualTo 0)) exitWith {
 [1,"There is already a gang created with that name or gang tag please pick another name or clantag."] remoteExecCall ["life_fnc_broadcast",_ownerID];
 life_action_gangInUse = nil;
 _ownerID publicVariableClient "life_action_gangInUse";
};
_query = format ["SELECT id FROM gangs WHERE members LIKE '%2%1%2' AND active='1'",_uid,"%"];
_queryResult = [_query,2] call DB_fnc_asyncCall;
//Check to see if this person already owns or belongs to a gang.
if (!(count _queryResult isEqualTo 0)) exitWith {
 [1,"You are currently already active in a gang, please leave the gang first."] remoteExecCall ["life_fnc_broadcast",_ownerID];
 life_action_gangInUse = nil;
 _ownerID publicVariableClient "life_action_gangInUse";
};
//Check to see if a gang with that name already exists but is inactive.
_query = format ["SELECT id, active FROM gangs WHERE (name='%1' or gangtag = '%2') AND active='0'",_gangName,_gangTag];
_queryResult = [_query,2] call DB_fnc_asyncCall;
_gangMembers = [[_uid]] call DB_fnc_mresArray;
if (!(count _queryResult isEqualTo 0)) then {
 _query = format ["UPDATE gangs SET active='1', owner='%1',members='%2', name='%4', gangtag='%5' WHERE id='%3'",_uid,_gangMembers,(_queryResult select 0),_gangName,_gangTag];
} else {
 _query = format ["INSERT INTO gangs (owner, name, members, gangtag) VALUES('%1','%2','%3','%4')",_uid,_gangName,_gangMembers,_gangTag];
};
_queryResult = [_query,1] call DB_fnc_asyncCall;
_group setVariable ["gang_name",_gangName,true];
_group setVariable ["gang_owner",_uid,true];
_group setVariable ["gang_bank",0,true];
_group setVariable ["gang_maxMembers",8,true];
_group setVariable ["gang_members",[_uid],true];
_group setVariable ["gang_tag",_gangTag,true];
[_group] remoteExecCall ["life_fnc_gangCreated",_ownerID];
uiSleep 0.35;
_query = format ["SELECT id FROM gangs WHERE owner='%1' AND active='1'",_uid];
_queryResult = [_query,2] call DB_fnc_asyncCall;
_group setVariable ["gang_id",(_queryResult select 0),true];