Beiträge von br1zey

#include "\life_server\script_macros.hpp"
/*
 File: fn_spawnVehicle.sqf
 Author: Bryan "Tonic" Boardwine
 Description:
 Sends the query request to the database, if an array is returned then it creates
 the vehicle if it's not in use or dead.
*/
private["_vid","_sp","_pid","_query","_sql","_vehicle","_nearVehicles","_name","_side","_tickTime","_dir","_servIndex"];
_vid = [_this,0,-1,[0]] call BIS_fnc_param;
_pid = [_this,1,"",[""]] call BIS_fnc_param;
_sp = [_this,2,[],[[],""]] call BIS_fnc_param;
_unit = [_this,3,ObjNull,[ObjNull]] call BIS_fnc_param;
_price = [_this,4,0,[0]] call BIS_fnc_param;
_dir = [_this,5,0,[0]] call BIS_fnc_param;
_unit_return = _unit;
_name = name _unit;
_side = side _unit;
_unit = owner _unit;
if(EQUAL(_vid,-1) OR EQUAL(_pid,"")) exitWith {};
if(_vid in serv_sv_use) exitWith {};
serv_sv_use pushBack _vid;
_servIndex = serv_sv_use find _vid;
_query = format["SELECT id, side, classname, type, pid, alive, active, plate, color, inventory, gear, fuel FROM vehicles WHERE id='%1' AND pid='%2'",_vid,_pid];
_tickTime = diag_tickTime;
_queryResult = [_query,2] call DB_fnc_asyncCall;
if(EXTDB_SETTING(getNumber,"DebugMode") == 1) then {
 diag_log "------------- Client Query Request -------------";
 diag_log format["QUERY: %1",_query];
 diag_log format["Time to complete: %1 (in seconds)",(diag_tickTime - _tickTime)];
 diag_log format["Result: %1",_queryResult];
 diag_log "------------------------------------------------";
};
if(EQUAL(typeName _queryResult,typeName "")) exitWith {};
_vInfo = _queryResult;
if(isNil "_vInfo") exitWith {serv_sv_use deleteAt _servIndex;};
if(EQUAL(count _vInfo,0)) exitWith {serv_sv_use deleteAt _servIndex;};
if(EQUAL(SEL(_vInfo,5),0)) exitWith {
 serv_sv_use deleteAt _servIndex;
 [1,format[(localize "STR_Garage_SQLError_Destroyed"),_vInfo select 2]] remoteExecCall ["life_fnc_broadcast",_unit];
};
if(EQUAL(SEL(_vInfo,6),1)) exitWith {
 serv_sv_use deleteAt _servIndex;
 [1,format[(localize "STR_Garage_SQLError_Active"),_vInfo select 2]] remoteExecCall ["life_fnc_broadcast",_unit];
};
if!(EQUAL(typeName _sp,typeName "")) then {
 _nearVehicles = nearestObjects[_sp,["Car","Air","Ship"],10];
} else {
 _nearVehicles = [];
};
if(count _nearVehicles > 0) exitWith {
 serv_sv_use deleteAt _servIndex;
 [_price,_unit_return] remoteExecCall ["life_fnc_garageRefund",_unit];
 [1,(localize "STR_Garage_SpawnPointError")] remoteExecCall ["life_fnc_broadcast",_unit];
};
_query = format["UPDATE vehicles SET active='1' WHERE pid='%1' AND id='%2'",_pid,_vid];
_trunk = [_vInfo select 9] call DB_fnc_mresToArray;
_gear = [_vInfo select 10] call DB_fnc_mresToArray;
[_query,false] spawn DB_fnc_asyncCall;
if(typeName _sp == "STRING") then {
 _vehicle = createVehicle[(_vInfo select 2),[0,0,999],[],0,"NONE"];
 waitUntil {!isNil "_vehicle" && {!isNull _vehicle}};
 _vehicle allowDamage false;
 _hs = nearestObjects[getMarkerPos _sp,["Land_Hospital_side2_F"],50] select 0;
 _vehicle setPosATL (_hs modelToWorld [-0.4,-4,12.65]);
 sleep 0.6;
} else {
 _vehicle = createVehicle [(_vInfo select 2),_sp,[],0,"NONE"];
 waitUntil {!isNil "_vehicle" && {!isNull _vehicle}};
 _vehicle allowDamage false;
 _vehicle setPos _sp;
 _vehicle setVectorUp (surfaceNormal _sp);
 _vehicle setDir _dir;
};
_vehicle setFuel (_vInfo select 11);
_vehicle allowDamage true;
//Send keys over the network.
[_vehicle] remoteExecCall ["life_fnc_addVehicle2Chain",_unit];
[_pid,_side,_vehicle,1] call TON_fnc_keyManagement;
_vehicle lock 2;
//Reskin the vehicle
[_vehicle,_vInfo select 8] remoteExecCall ["life_fnc_colorVehicle",_unit];
_vehicle setVariable["vehicle_info_owners",[[_pid,_name]],true];
_vehicle setVariable["dbInfo",[(_vInfo select 4),_vInfo select 7]];
_vehicle setVariable["Trunk",_trunk,true];
_vehicle disableTIEquipment true; //No Thermals.. They're cheap but addictive.
[_vehicle] call life_fnc_clearVehicleAmmo;
if (count _gear > 0) then {
 _items = _gear select 0;
 _mags = _gear select 1;
 _weapons = _gear select 2;
 _backpacks = _gear select 3;
 for "_i" from 0 to ((count (_items select 0)) - 1) do {
 _vehicle addItemCargoGlobal [((_items select 0) select _i), ((_items select 1) select _i)];
 };
 for "_i" from 0 to ((count (_mags select 0)) - 1) do {
 _vehicle addMagazineCargoGlobal [((_mags select 0) select _i), ((_mags select 1) select _i)];
 };
 for "_i" from 0 to ((count (_weapons select 0)) - 1) do {
 _vehicle addWeaponCargoGlobal [((_weapons select 0) select _i), ((_weapons select 1) select _i)];
 };
 for "_i" from 0 to ((count (_backpacks select 0)) - 1) do {
 _vehicle addBackpackCargoGlobal [((_backpacks select 0) select _i), ((_backpacks select 1) select _i)];
 };
};
if(_side isEqualTo west) then {this animate ["daylights_hide", 1];this animate ["Secondary", 1];this animate ["Switch_2", 1];this animate ["Lightbar", 1];};
//Sets of animations
switch((SEL(_vInfo,1))) do {
	case "cop": {
		[_vehicle,"cop_offroad",true] spawn life_fnc_vehicleAnimate;




    _vehicle animate ["daylights_hide", 1];
    _vehicle animate ["Secondary", 1];
    _vehicle animate ["Switch_2", 1];
    _vehicle animate ["Lightbar", 1];
    _vehicle setVariable ["Red", 0, TRUE]; 
    _vehicle setVariable ["Green", 0, TRUE]; 
    _vehicle setVariable ["Blue", 0.4, TRUE];




		if((SEL(_vInfo,2)) in ["C_Offroad_01_F","B_MRAP_01_F","C_SUV_01_F","C_Hatchback_01_sport_F","B_Heli_Light_01_F","B_Heli_Transport_01_F"]) then {
			[_vehicle,"cop_offroad",true] remoteExecCall ["life_fnc_vehicleAnimate",_unit];
		};
	};




	case "civ": {










		if((SEL(_vInfo,2)) in ["C_Offroad_01_F"])then{
			[_vehicle,"civ_offroad",true] remoteExecCall ["life_fnc_vehicleAnimate",_unit];
		};
		if(EQUAL(SEL(_vInfo,2),"B_Heli_Light_01_F") && !(EQUAL(SEL(_vInfo,8),13))) then {
			[_vehicle,"civ_littlebird",true] remoteExecCall ["life_fnc_vehicleAnimate",_unit];
		};
	};




	case "med": {







		if((SEL(_vInfo,2)) in ["C_Offroad_01_F","B_MRAP_01_F","C_SUV_01_F","C_Hatchback_01_sport_F","B_Heli_Light_01_F","B_Heli_Transport_01_F"]) then {
			[_vehicle,"med_offroad",true] remoteExecCall ["life_fnc_vehicleAnimate",_unit];
		};
	};
};




[1,"Your vehicle is ready!"] remoteExecCall ["life_fnc_broadcast",_unit];
serv_sv_use deleteAt _servIndex;

/*
File: fn_copInteractionMenu.sqf
Author: Bryan "Tonic" Boardwine
Description:
Replaces the mass addactions for various cop actions towards another player.
*/
#define Btn1 37450
#define Btn2 37451
#define Btn3 37452
#define Btn4 37453
#define Btn5 37454
#define Btn6 37455
#define Btn7 37456
#define Btn8 37457
#define Btn9 37458
#define Btn10 37459
#define Title 37401




private["_display","_curTarget","_Btn1","_Btn2","_Btn3","_Btn4","_Btn5","_Btn6","_Btn7","_Btn8","_Btn9","_Btn10"];
if(!dialog) then {
createDialog "pInteraction_Menu";
};
disableSerialization;
_curTarget = [_this,0,ObjNull,[ObjNull]] call BIS_fnc_param;
if(isNull _curTarget) exitWith {closeDialog 0;}; //Bad target







if(!isPlayer _curTarget && side _curTarget == civilian) exitWith {closeDialog 0;}; //Bad side check?




_display = findDisplay 37400;
_Btn1 = _display displayCtrl Btn1;
_Btn2 = _display displayCtrl Btn2;
_Btn3 = _display displayCtrl Btn3;
_Btn4 = _display displayCtrl Btn4;
_Btn5 = _display displayCtrl Btn5;
_Btn6 = _display displayCtrl Btn6;
_Btn7 = _display displayCtrl Btn7;
_Btn8 = _display displayCtrl Btn8;
_Btn9 = _display displayCtrl Btn9;
_Btn10 = _display displayCtrl Btn10;
life_pInact_curTarget = _curTarget;




//Set Heal Button
_Btn1 ctrlSetText localize "STR_Medic_Heal";
_Btn1 buttonSetAction "[life_pInact_curTarget] call life_fnc_healPlayer; closeDialog 0;";




//Set Check Licenses Button
_Btn2 ctrlSetText localize "STR_pInAct_checkLicenses";
_Btn2 buttonSetAction "[[player],""life_fnc_licenseCheck"",life_pInact_curTarget,FALSE] spawn life_fnc_MP";




//Set Search Button
_Btn3 ctrlSetText localize "STR_pInAct_SearchPlayer";
_Btn3 buttonSetAction "[life_pInact_curTarget] spawn life_fnc_searchAction;";




//Set Escort Button
if((_curTarget getVariable["Escorting",false])) then {
_Btn4 ctrlSetText localize "STR_pInAct_StopEscort";
_Btn4 buttonSetAction "[life_pInact_curTarget] call life_fnc_stopEscorting; [life_pInact_curTarget] call life_fnc_medInteractionMenu;";
} else {
_Btn4 ctrlSetText localize "STR_pInAct_Escort";
_Btn4 buttonSetAction "[life_pInact_curTarget] call life_fnc_escortAction; closeDialog 0;";
};




//Set Ticket Button
_Btn5 ctrlSetText localize "STR_pInAct_TicketBtn";
_Btn5 buttonSetAction "[life_pInact_curTarget] call life_fnc_ticketAction;";




_Btn6 ctrlSetText localize "STR_pInAct_Arrest";
_Btn6 buttonSetAction "closeDialog 0; [] call life_fnc_showArrestDialog;";




_Btn7 ctrlSetText localize "STR_pInAct_PutInCar";
_Btn7 buttonSetAction "[life_pInact_curTarget] call life_fnc_putInCar; closeDialog 0;";




//Remove Weapons
_Btn8 ctrlSetText localize "STR_pInAct_RemoveWeapons";
_Btn8 buttonSetAction "[life_pInact_curTarget] spawn life_fnc_removeWeaponAction; closeDialog 0;";




_Btn9 ctrlSetText localize "STR_pInAct_Breathalyzer";
_Btn9 buttonSetAction "[[player],""life_fnc_breathalyzer"",life_pInact_curTarget,FALSE] spawn life_fnc_MP;closeDialog 0";




_Btn10 ctrlSetText localize "STR_pInAct_RevokeLicense";
_Btn10 buttonSetAction "[life_pInact_curTarget] call life_fnc_revokeLicense;";




//Check that you are near a place to jail them.
if(!((player distance (getMarkerPos "cop_spawn_1") < 50) OR (player distance (getMarkerPos "cop_spawn_2") < 50) OR (player distance (getMarkerPos "cop_spawn_3") < 50) OR (player distance (getMarkerPos "cop_spawn_bane") < 50))) then
{
_Btn6 ctrlEnable false;
};