Beiträge von moeck

moeck

Ist sicher auch eine Möglichkeit . Vorallem wenn man die Nachrichten mit jedem Restart löscht.

moeck

Moin,

zu dem Fehler

wegen Ausweis:

Code

21:57:19 Scripting function 'life_fnc_ausweissehen' is not allowed to be remotely executed

kann ich nur sagen, schau Dir mal das Tut an, da ist alles beschrieben was Du für die Versionen größer 4 machen musst. Hier Playertags / Player Menü nur für bekannte Personen sichtbar steht unter Punkt 2 in rot dass Du das in der cfgRemote freigeben musst. Ich werde das aber auch nochmal explizit ins Tut reinschreiben

Bei dem 2. Fehler kann es sein, dass du den Prefix nicht richtig gesetzt hast?

Gruß,

moeck

moeck

Des Weiteren müsstest Du auch einen 2. Feld WSP_Bank anlegen oder soll der Spieler das nicht verlieren wenn er stirbt bzw. ausgeraubt wird? Die einfachere Lösung ist sicherlich, wenn der Spieler deine Währung nicht verliert aber dann entfällt die halt auch beim Ausrauben oder sterben

moeck

und eine der anderen Lynx musste so im Shop anbieten

moeck

Das Einzige was Du machen kannst ist, dass Du mehr Fahrzeug Skins anbietest oder um beim Thema Lynx zu bleiben für Spender auch die beiden anderen Farben mit anbietest. Was auch noch geht ist, dass Du zum Beispiel die Kopfbedeckungen und Uniformen begrenzt. Solange sie keinen Vorteil für den Spieler haben. Z.B. ein Gillie ist problematisch während Hose und Hemd kein Problem ist. Des Weiteren musst Du dir überlegen was passiert wenn der jenige kein Spender mehr ist.

Um einen vernüftiges Spender / Donator System aufzubauen musst Du erstmal ein solides Konzept dafür haben.

moeck

sorry vielleicht sollte ich mir die Files richtig anschauen, das war ja das client log. nein da brauchst Du das nicht, aber vielleicht solltest du den server log auh anhängen.

moeck

nein! aktiviere einfach das

Code

save_vehicle_inventory = true; //Save Arma inventory of vehicle to the database

moeck

Moin,

normalerweise kannst Du alles in den Häusern speichern. Ich habe bisher noch keine Beschränkung gesehen. Zum speichern des I-Iventars kommt es meines Wissens nach darauf an welche Version du verwendest.

In 5.0 stellst Du das in der Config_Master ein was gespeichert wird und was nicht.

C

/* Vehicle Data Saving */
    save_vehicle_virtualItems = false; //Save virtual items inside the vehicle (all sides)(-- See defined items on next line --)
    save_vehicle_items[] = { "pickaxe","fuelEmpty","fuelFull", "spikeStrip", "lockpick", "defuseKit","storageSmall","storageBig","redgull","coffee","waterBottle","apple","peach","tbacon","donuts","rabbit","salema","ornate","mackerel","tuna","mullet","catshark","turtle_soup","hen","rooster","sheep","goat","defibrillator","toolkit" };
    save_vehicle_inventory = false; //Save Arma inventory of vehicle to the database
    save_vehicle_fuel = false; //Save vehicle fuel level to the database (Impounded/Garaged).
    save_vehicle_damage = false; //Save vehicle damage to the database.
    save_vehicle_illegal = false; //This will allow cops to be advised when a vehicle, with illegal items in it, is impounded. This will also save illegal items as proof of crime, and needs "save_vehicle_virtualItems" set as true. Illegal items don't need to be set in save_vehicle_items[] for being saved, if it's enabled.

moeck

Ähm, ein Blick in die Logs hat mir verratten dass du weder den life_server noch extDB3 als servermod lädst.

Schau Dir mal deine Startparameter an

Code

"C:\Program Files (x86)\Steam\steamapps\common\Arma 3\Arma3_x64.exe" -mod=

moeck

Hi benutze doch einfach die Funktion Dateianhänge unter dem Eingabefenster für Posts. Da kannst Du die Dateien dann einfach hinzufügen.

moeck

Moin,

es handelt sich hier nicht um ein Tutorial, da die Änderung so minimal ist. Um die Garage nach den Fahrzeugnamen zu sortieren müsst ihr lediglich einen Befehl in die Datei fn_impoundMenu.sqf aufnehmen.

Code

lbSort _control;

Dieser Befehl muss einfach hinter die forEach _vehicles Schleife (Zeile 33) gehängt werden. Die Datei der 5.0 sieht anschliessend wie folgt aus. Es funktioniert aber auch in allen anderen Versionen.

C: /dialog/functions/fn_impoundMenu.sqf

#include "..\..\script_macros.hpp"
/*
    File: fn_impoundMenu.sqf
    Author: Bryan "Tonic" Boardwine

    Description:
    Not actually a impound menu, may act as confusion to some but that is what I wanted.
    The purpose of this menu is it is now called a 'Garage' where vehicles are stored (persistent ones).
*/
private ["_vehicles","_control"];
disableSerialization;
_vehicles = param [0,[],[[]]];

ctrlShow[2803,false];
ctrlShow[2830,false];
waitUntil {!isNull (findDisplay 2800)};

if (count _vehicles isEqualTo 0) exitWith {
    ctrlSetText[2811,localize "STR_Garage_NoVehicles"];
};

_control = CONTROL(2800,2802);
lbClear _control;

{
    _vehicleInfo = [(_x select 2)] call life_fnc_fetchVehInfo;
    _control lbAdd (_vehicleInfo select 3);
    _tmp = [(_x select 2),(_x select 8)];
    _tmp = str(_tmp);
    _control lbSetData [(lbSize _control)-1,_tmp];
    _control lbSetPicture [(lbSize _control)-1,(_vehicleInfo select 2)];
    _control lbSetValue [(lbSize _control)-1,(_x select 0)];
} forEach _vehicles;
lbSort _control; //Sortierung der Fahrzeuge
ctrlShow[2810,false];
ctrlShow[2811,false];

Alles anzeigen

Gruß,

moeck

moeck

Moin,

er möchte einen Wert in der DB ändern, wenn ich das richtig gelesen habe. Heißt per grep/awk irgendeinen Wert aus dem Logfile herausfiltern und wenn er einen Treffer hat im Log dann möchte er für den betroffenen User irgendwas in der DB ändern. Mein Ansatz wäre eine CSV Datei zu erstellen mit UserID (PlayerID) und dem gewünschtem Wert. Anschliessend kann man den MySQL Client aufrufen und ihm die Datei übergeben.

Ähnliche Sache habe ich bereits mit Oracle auf Linux gebaut nur, dass ich hier keine Daten eingespielt habe sondern regelmässig Statistiken für verschiedenen Tabellen erzeuge.

Gibt bestimmt für MySQL einen commandline Client mit dem das funzt. Alternativ per php/perl/... eine entsprechende Datei auslesen und importieren.

Gruß,

moeck

moeck

so fertig [TUTORIAL] Blaulicht für Fahrzeuge einfügen und Konfiguration vereinfachen

moeck

1.3. fn_medicLights.sqf

Diese Datei habe ich nicht nur mit den Fahrzeugen modifiziert sondern auch unterschiedliche Farben für unterschiedliche Fahrzeuge eingefügt. Aber nicht erschrecken sieht im ersten Moment komplizierter aus als es ist.

Code

/*
    File: fn_medicLights.sqf
    @Author: Tonic modified by moeck (Lost of Paradise)
    
    Description:
    Adds the light effect to cop vehicles, specifically the offroad.
*/

// LHM START

private ["_vehicle","_lightRed","_lightYellow","_lightBlue","_lightleft","_lightright","_leftRed","_brightness","_attach"];

_vehicle = _this select 0;

if (isNil "_vehicle" || isNull _vehicle || !(_vehicle getVariable "lights")) exitWith {};
//Definition der Farben
_lightRed = [1, 0.1, 0.1]; 
_lightBlue = [0.1, 0.1, 20];
_lightYellow = [20, 20, 0.1]; 
_lightleft = createVehicle ["#lightpoint", getPos _vehicle, [], 0, "CAN_COLLIDE"];
sleep 0.2;
_lightright = createVehicle ["#lightpoint", getPos _vehicle, [], 0, "CAN_COLLIDE"];
sleep 0.2;

switch (typeOf _vehicle) do {
    case "C_Offroad_01_F": { _attach = [[-0.45, 0.0, 0.56], [0.37, 0.0, 0.56]]; 
                             _lightleft setLightColor _lightBlue;
                             _lightright setLightColor _lightBlue;
    };
    case "B_MRAP_01_F": { _attach = [[-1, -2.8, 0.55], [1, -2.8, 0.55]]; 
                           _lightleft setLightColor _lightBlue;
                           _lightright setLightColor _lightBlue;    
    };
    case "C_SUV_01_F": { _attach = [[-0.4, 2.3, -0.55], [0.4, 2.3, -0.55]]; 
                        _lightleft setLightColor _lightBlue;
                        _lightright setLightColor _lightBlue;
    };
    case "C_Van_01_box_F": { _attach = [[-0.75, 0.2, 1.55], [0.67, 0.2, 1.55]]; 
                             _lightleft setLightColor _lightBlue;
                             _lightright setLightColor _lightBlue;
    }; 
    case "B_Heli_Light_01_F": { _attach = [[-0.37, 0.0, 0.56], [0.37, 0.0, 0.56]]; 
                                _lightleft setLightColor _lightBlue;
                                _lightright setLightColor _lightBlue;
    };
    case "O_Heli_Light_02_unarmed_F": { _attach = [[-0.90,1.26,0.45], [0.90,1.26,0.45]]; 
                                    _lightleft setLightColor _lightBlue;
                                    _lightright setLightColor _lightBlue;
    };
    case "I_Heli_Transport_02_F": { _attach = [[-1.79,0.98,-2.48], [1.79,0.98,-2.48]]; 
                                _lightleft setLightColor _lightBlue;
                                _lightright setLightColor _lightBlue;
    };
    case "C_Offroad_01_repair_F": { _attach = [[-0.45, 0.0, 0.50], [0.37, 0.0, 0.50]]; 
                                    _lightleft setLightColor _lightYellow;
                                    _lightright setLightColor _lightYellow;
    };
    case "I_MRAP_03_F": { _attach = [[-0.37, 0.0, 0.56], [0.37, 0.0, 0.56]]; 
                                _lightleft setLightColor _lightBlue;
                                _lightright setLightColor _lightBlue;
    };
    case "B_Heli_Transport_03_unarmed_F": { _attach = [[-0.37, 0.0, 0.56], [0.37, 0.0, 0.56]]; 
                                _lightleft setLightColor _lightBlue;
                                _lightright setLightColor _lightBlue;
    };
    case "O_Heli_Transport_04_F": { _attach = [[-0.37, 0.0, 0.56], [0.37, 0.0, 0.56]]; 
                                _lightleft setLightColor _lightBlue;
                                _lightright setLightColor _lightBlue;
    };
    case "B_Truck_01_covered_F": { _attach = [[-1.2, 4.85, -0.45], [1.25, 4.85, -0.45]]; 
                                _lightleft setLightColor _lightBlue;
                                _lightright setLightColor _lightBlue;
    };
    case "O_T_VTOL_02_infantry_F":{ _attach = [[-7,-1.25,-0.1],[7,-1.25,-0.1]];
                                _lightleft setLightColor _lightBlue;
                                _lightright setLightColor _lightBlue;
    };
    case "I_Heli_light_03_unarmed_F": { _attach = [[-1.23,4.7,-1.42],[1.23,4.7,-1.42]];
                                _lightleft setLightColor _lightBlue;
                                _lightright setLightColor _lightBlue;
    };
};

//_lightleft setLightColor _lightBlue;
_lightleft setLightBrightness 0;
_lightleft lightAttachObject [_vehicle, _attach select 0];
_lightleft setLightAttenuation [0.181, 0, 1000, 130];
_lightleft setLightIntensity 20;
_lightleft setLightFlareSize 0.38;
_lightleft setLightFlareMaxDistance 150;
_lightleft setLightUseFlare true;
_lightleft setLightDayLight true;

//_lightright setLightColor _lightBlue;
_lightright setLightBrightness 0;
_lightright lightAttachObject [_vehicle, _attach select 1];
_lightright setLightAttenuation [0.181, 0, 1000, 130];
_lightright setLightIntensity 20;
_lightright setLightFlareSize 0.38;
_lightright setLightFlareMaxDistance 150;
_lightright setLightUseFlare true;
_lightright setLightDayLight true;

if (sunOrMoon < 1) then {
    _brightness = 15;
} else {
    _brightness = 60;
};

_leftRed = true;  
while {(alive _vehicle)} do { 
    //hint format ["DEBUG: lights: %1 \n Vehicle Player: %2",!(_vehicle getVariable "lights"),!(vehicle player !=player)];
    if (!(_vehicle getVariable "lights")) exitWith {};
    if (_leftRed) then {  
        _leftRed = false;  
        _lightright setLightBrightness 0;  
        sleep 0.05;
        _lightleft setLightBrightness _brightness;  
    } else {  
        _leftRed = true;  
        _lightleft setLightBrightness 0;  
        sleep 0.05;
        _lightright setLightBrightness _brightness;  
    };
    sleep 0.22;  
};  
deleteVehicle _lightleft;
deleteVehicle _lightright;

// LHM END<<<<

Alles anzeigen

Also zum Aufbau der Datei. Ich habe hier neben den Lichtpunkten in der Konfiguration des Fahrzeuges auch festgelegt welche Farbe das (Blau)Licht haben soll. Ihr könnt die Farben natürlich beliebig ändern, je nachdem was ihr haben wollt. Der Fantasie sind hier keine Grenzen gesetzt .

1.4. fn_medicSirenLights.sqf

So hier wird nochmalerweise ebenfalls der Classname der Fahrzeuge eingetragen. Das habe ich nun entsprechend modifiziert, heißt wenn ihr das Tutorial nutz müsst ihr die Datei nicht mehr anfassen. In Zeile 13 findet ihr diesen Eintrag.

Code

if (!(typeOf _vehicle in ["C_Offroad_01_F"])) exitWith {}; //Last chance check to prevent something from defying humanity and creating a monster.

Bitte ersetzt den Eintrag durch den folgende

Code

if(!(typeOf _vehicle in life_medic_veh)) exitWith {}; //Last chance check to prevent something from defying humanity and creating a monster.

Ich poste hier nicht die gesamte Datei, da es Unterschiede zwischen den Versionen gibt und nicht beide Versionen hier dokumentieren möchte.

1.5. fn_keyHandler.sqf

Weil es immer so schön ist darf man normalerweise auch hier die Classnames der Fahrzeuge nochmal eintragen. Der Eintrag sieht im Standard keyHandler wie folgt aus.

Code

if (!(isNull objectParent player) && (typeOf vehicle player) in ["C_Offroad_01_F","B_MRAP_01_F","C_SUV_01_F","C_Hatchback_01_sport_F","B_Heli_Light_01_F","B_Heli_Transport_01_F"]) then {

Diesen Eintrag müsst ihr durch das folgende ersetzen

Code

if (!(isNull objectParent player) && (((typeOf vehicle player) in life_cop_veh) or ((typeOf vehicle player) in life_medic_veh))) then {

So damit hätten wir auch schon alle Änderungen in der Missiondatei geschafft und machen mit den beiden Änderungen im life_server weiter.

Optional ADAC mit einfügen

C

//L
case 38: 
 {
 //If cop run checks for turning lights on.
 if(_shift && playerSide in [west,independent,east]) then {
 if(vehicle player != player && (((typeOf vehicle player) in life_cop_veh) or ((typeOf vehicle player) in life_medic_veh))) then {
 if(!isNil {vehicle player getVariable "lights"}) then {
 if(playerSide == west) then {
 [vehicle player] call life_fnc_sirenLights;
 } 
 else 
 {
 [vehicle player] call life_fnc_medicSirenLights;
 };
 _handled = true;
 };
 };
 };
 
 if(!_alt && !_ctrlKey) then { [] call life_fnc_radar; };
 };

Alles anzeigen

2. life_server

2.1. fn_spawnVehicle.sqf

Hier müsst ihr 2 Zeilen austauschen. Zum einen für die Cops.

Code

if ((_vInfo select 1) isEqualTo "cop" && ((_vInfo select 2)) in ["C_Offroad_01_F","B_MRAP_01_F","C_SUV_01_F","C_Hatchback_01_sport_F","B_Heli_Light_01_F","B_Heli_Transport_01_F"]) then {

ersetzen durch

Code

if ((_vInfo select 1) isEqualTo "cop" && ((_vInfo select 2)) in life_cop_veh) then {

und das Ganze natürlich auch für die Medics.

Code

if ((_vInfo select 1) isEqualTo "med" && (_vInfo select 2) isEqualTo "C_Offroad_01_F") then {

ersetzen durch

Code

if ((_vInfo select 1) isEqualTo "med" && (_vInfo select 2) in life_medic_veh) then {

Zu Schluss müssen wir noch die beiden Variablen life_cop_veh und life_medic_veh definieren und das habe ich wie folgt gelöst.

2.2. init.sqf

Ich habe die beiden Variablen vor der Funktion initHouses reinkopiert aber man die auch an eine andere Stelle in der init packen.

Code

life_cop_veh = [
                "B_MRAP_01_hmg_F",
                "I_MRAP_03_hmg_F",
                "C_Offroad_01_F",
                "B_MRAP_01_F",
                "I_MRAP_03_F",
                "C_SUV_01_F",
                "C_Hatchback_01_sport_F",
                "B_Heli_Light_01_F",
                "B_Heli_Transport_01_F",
                "B_Truck_01_covered_F",
                "I_Heli_light_03_unarmed_F",
                "B_T_VTOL_01_vehicle_F",
                "B_T_VTOL_01_infantry_F",
                "B_Heli_Transport_03_unarmed_F",
                "O_Heli_Transport_04_bench_F"
                ];
publicVariable "life_cop_veh";
life_medic_veh = [
                "C_Offroad_01_F",
                "B_MRAP_01_F","C_SUV_01_F",
                "C_Van_01_box_F",
                "C_Hatchback_01_sport_F",
                "B_Heli_Light_01_F",
                "O_Heli_Light_02_unarmed_F",
                "I_Heli_Transport_02_F",
                "I_MRAP_03_F",
                "C_Offroad_01_repair_F",
                "B_Heli_Transport_03_unarmed_F",
                "O_Heli_Transport_04_F",
                "B_Truck_01_covered_F",
                "O_T_VTOL_02_infantry_F",
                "I_Heli_light_03_unarmed_F"
                ];
publicVariable "life_medic_veh";

Alles anzeigen

Damit hätten wir es auch schon geschafft und beim nächsten Fahrzeug müsst ihr es nur noch in die medicLights bzw. copLigths und in die init vom life_server eintragen.

Ich hoffe das hilft euch weiter . Achja falls irgendwer Koordinaten für den Qilin und Prowler hat könnte er/sie diese gern mal hier in den Thread posten.

Gruß und schönes WE,

moeck

moeck

Moin zusammen,

ich habe mir auf Grund der verschiedenen Fragen rund um das Thema Blaulicht bei Cops und Medics mal ein paar Gedanken gemacht wie man das Ganze mal vereinfachen kann. Statt bei jedem Fahrzeug jedes Mal 4 Dateien zu editieren, müsst ihr nach dem Tutorial lediglich das Fahrzeuge noch an 2 Stellen eintragen. Des Weiteren sind die beiden Dateien dann auch verständlich und nicht so umständlich wie bisher.

Wie immer gilt, das Tutorial darf ohne meine Zustimmung nicht weitergegeben werden.

Na dann fangen wir mal an. Es sind Änderungen sowohl im life_server als auch in der Missiondatei notwendig.

1. Missiondatei

1.1. fn_copLights.sqf

Diese Datei befindet sich noch im Orginalzustand, ich habe dort lediglich die Fahrzeuge der Cops mit den entsprechenden Punkten hinzugefügt.

C: fn_copLights.sqf

/*
    File: fn_copLights.sqf
    @Author: Tonic
    
    Description:
    Adds the light effect to cop vehicles, specifically the offroad.
*/

// LHM START

private ["_vehicle","_lightRed","_lightBlue","_lightleft","_lightright","_leftRed","_brightness","_attach"];

_vehicle = _this select 0;

if (isNil "_vehicle" || isNull _vehicle || !(_vehicle getVariable "lights")) exitWith {};

switch (typeOf _vehicle) do {
    case "C_Hatchback_01_F": { _attach = [[-0.6, 2, -0.95], [0.6, 2, -0.95]]; };
    case "C_Hatchback_01_sport_F": { _attach = [[-0.6, 2, -0.95], [0.6, 2, -0.95]]; };
    case "C_Offroad_01_F": { _attach = [[-0.45, 0.0, 0.56], [0.37, 0.0, 0.56]]; };
    case "C_SUV_01_F": { _attach = [[-0.4, 2.3, -0.55], [0.4, 2.3, -0.52]]; };
    case "B_Heli_Light_01_F": { _attach = [[-0.37, 0.0, 0.56], [0.37, 0.0, 0.56]]; };
    case "B_Heli_Transport_01_F": { _attach = [[-0.5, 0.0, 0.96], [0.5, 0.0, 0.96]]; };
    case "I_MRAP_03_hmg_F": { _attach = [[-0.37, 0.0, 0.56], [0.37, 0.0, 0.56]]; };
    case "I_MRAP_03_F": { _attach = [[-0.37, 0.0, 0.50], [0.37, 0.0, 0.50]]; };    
    case "B_APC_Wheeled_01_cannon_F": { _attach = [[-1, -2.8, 0.55], [1, -2.8, 0.55]]; };    
    case "B_MRAP_01_hmg_F": { _attach = [[-1, -2.8, 0.55], [1, -2.8, 0.55]]; };
    case "B_MRAP_01_F": { _attach = [[-1, -2.8, 0.55], [1, -2.8, 0.55]]; };
    case "O_MRAP_02_hmg_F": { _attach = [[-1, -2.8, 0.50], [1, -2.8, 0.50]]; };
    case "O_MRAP_02_F": { _attach = [[-1, -2.8, 0.55], [1, -2.8, 0.55]]; };
    case "B_Truck_01_covered_F": { _attach = [[-1.2, 4.85, -0.45], [1.25, 4.85, -0.45]];};
    case "B_Heli_Transport_03_unarmed_F": { _attach = [[-0.37, 0.0, 0.56], [0.37, 0.0, 0.56]]; };
    case "B_T_VTOL_01_infantry_F": { _attach = [[-7.6,3.3,-1.2],[7.65,3.35,-1.1]];};
    case "B_T_VTOL_01_vehicle_F": { _attach = [[-7.6,3.3,-1.2],[7.65,3.35,-1.1]];};
    case "I_Heli_light_03_unarmed_F": { _attach = [[-1.23,4.7,-1.42],[1.23,4.7,-1.42]];};
    case "O_Heli_Transport_04_bench_F": { _attach = [[-0.37, 0.0, 0.56], [0.37, 0.0, 0.56]];};
};

_lightRed = [20, 0.1, 0.1];
_lightBlue = [0.1, 0.1, 20];

_lightleft = createVehicle ["#lightpoint", getPos _vehicle, [], 0, "CAN_COLLIDE"];
sleep 0.2;
_lightleft setLightColor _lightRed;
_lightleft setLightBrightness 0;
_lightleft lightAttachObject [_vehicle, _attach select 0];
_lightleft setLightAttenuation [0.181, 0, 1000, 130];
_lightleft setLightIntensity 20;
_lightleft setLightFlareSize 0.38;
_lightleft setLightFlareMaxDistance 150;
_lightleft setLightUseFlare true;
_lightleft setLightDayLight true;

_lightright = createVehicle ["#lightpoint", getPos _vehicle, [], 0, "CAN_COLLIDE"];
sleep 0.2;
_lightright setLightColor _lightBlue;
_lightright setLightBrightness 0;
_lightright lightAttachObject [_vehicle, _attach select 1];
_lightright setLightAttenuation [0.181, 0, 1000, 130];
_lightright setLightIntensity 20;
_lightright setLightFlareSize 0.38;
_lightright setLightFlareMaxDistance 150;
_lightright setLightUseFlare true;
_lightright setLightDayLight true;

if (sunOrMoon < 1) then {
    _brightness = 15;
} else {
    _brightness = 60;
};

_leftRed = true;  
while {(alive _vehicle)} do { 
    // hint format ["DEBUG: lights: %1 \n Vehicle Player: %2",!(_vehicle getVariable "lights"),!(vehicle player !=player)];
    if (!(_vehicle getVariable "lights")) exitWith {};
    if (_leftRed) then {  
        _leftRed = false;  
        _lightright setLightBrightness 0;  
        sleep 0.05;
        _lightleft setLightBrightness _brightness;  
    } else {  
        _leftRed = true;  
        _lightleft setLightBrightness 0;  
        sleep 0.05;
        _lightright setLightBrightness _brightness;  
    };
    sleep 0.22;  
};  
deleteVehicle _lightleft;
deleteVehicle _lightright;

// LHM END

Alles anzeigen

Falls ihr andere oder weitere Fahrzeuge eintragen wollt einfach einen Eintrag kopieren und entsprechend des Fahrzeuges modifizieren. (Classname, Lichtpunkte)

1.2. fn_sirenLigths.sqf

So hier wird nochmalerweise ebenfalls der Classname der Fahrzeuge eingetragen. Das habe ich nun entsprechend modifiziert, heißt wenn ihr das Tutorial nutz müsst ihr die Datei nicht mehr anfassen. In Zeile 13 findet ihr diesen Eintrag.

C: fn_sirenLights.sqf

if (!(typeOf _vehicle in ["C_Offroad_01_F","B_MRAP_01_F","C_SUV_01_F","C_Hatchback_01_sport_F","B_Heli_Light_01_F","B_Heli_Transport_01_F"])) exitWith {}; //Last chance check to prevent something from defying humanity and creating a monster.

Bitte ersetzt den Eintrag durch den folgende

Code

if(!(typeOf _vehicle in life_cop_veh)) exitWith {}; //Last chance check to prevent something from defying humanity and creating a monster.

Ich poste hier nicht die gesamte Datei, da es Unterschiede zwischen den Versionen gibt und ich nicht beide Versionen hier dokumentieren möchte.

moeck

Mir ist gerade etwas aufgefallen, das werde ich mir mal in ruhe anschauen und wenn es klappt wie ich mir das vorstellen, dann schreibe ich ein TUT

moeck

achso , dann über den weg von blackfisch

moeck

Moin,

wenn ich das für die 3.1.4.8 nutzen möchte, muss ich die Zeile entsprechend anpassen oder?

Code

#include <macro.h>
/*
    File: fn_unimpound.sqf
    Author: Bryan "Tonic" Boardwine
    
    Description:
    Yeah... Gets the vehicle from the garage.
*/
private["_vehicle","_vid","_pid","_unit","_price","_texture"];
disableSerialization;
if(lbCurSel 2802 == -1) exitWith {hint localize "STR_Global_NoSelection"};
_vehicle = lbData[2802,(lbCurSel 2802)];
_vehicle = (call compile format["%1",_vehicle]) select 0;
_vid = lbValue[2802,(lbCurSel 2802)];
_pid = getPlayerUID player;
_unit = player;
_texture = [_vehicle] call life_fnc_vehicleColorCfg;
if(isNil "_vehicle") exitWith {hint localize "STR_Garage_Selection_Error"};

_price = [_vehicle,__GETC__(life_garage_prices)] call TON_fnc_index;
if(_price == -1) then {_price = 1000;} else {_price = (__GETC__(life_garage_prices) select _price) select 1;};
if(life_atm5cash < _price) exitWith {hint format[(localize "STR_Garage_CashError"),[_price] call life_fnc_numberText];};

if(typeName life_garage_sp == "ARRAY") then {
    [[_vid,_pid,life_garage_sp select 0,_unit,_price,life_garage_sp select 1],"TON_fnc_spawnVehicle",false,false] spawn life_fnc_MP;
} else {
    if(life_garage_sp in ["medic_spawn_1","medic_spawn_2","medic_spawn_3"]) then {
        [[_vid,_pid,life_garage_sp,_unit,_price,_texture],"TON_fnc_spawnVehicle",false,false] spawn life_fnc_MP;
    } else {
        [[_vid,_pid,(getMarkerPos life_garage_sp),_unit,_price,markerDir life_garage_sp,_texture],"TON_fnc_spawnVehicle",false,false] spawn life_fnc_MP;
    };
};

hint localize "STR_Garage_SpawningVeh";

life_atm5cash = life_atm5cash - _price;

Alles anzeigen

Also vorher noch die Prüfung auf den Spawn einbauen und anschliessend als 3. Wert an die Funktion übergeben oder?

Gruß,

moeck

moeck

Einfachste Lösung die legest im Key Handler eine Taste(nkombination) fest mit der zum Beispiel die Skins geladen werden können. Dort kannst Du die Rucksäcke auch wieder unsichtbar machen.

moeck

mache dafür aber mal einen eigenen Thread auf, dann lasse ich mit mir reden. Bzw. ich überlege gerade ob es nicht sinn macht ein tut zu schreiben

Beiträge von moeck

Was ist ein Sql basiertes Smartphone?

Anschnallgurt | Ausweis | Kleidung Skins Probleme

"Zweite Währung" einfügen?

Spender LEV auf shop machen

Spender LEV auf shop machen

Battleye Filter einstellen

I Inventar der Fahrzeuge, Waffen speichern?

I Inventar der Fahrzeuge, Waffen speichern?

Battleye Filter einstellen

Battleye Filter einstellen

Sortierung der Garage

Logs abfrage und Eintrag in Datenbank

Markt Fragen

[TUTORIAL] Blaulicht für Fahrzeuge einfügen und Konfiguration vereinfachen

[TUTORIAL] Blaulicht für Fahrzeuge einfügen und Konfiguration vereinfachen

Markt Fragen

Tempest Device von Apex zu farmen benüzen

Fahrzeug - Garagenspawn erhöhen ?

Hilfe beim erstellen von unsichtbaren Rucksäcken für Medic und Polizei

Markt Fragen