Beiträge von Lucian

Weiß nicht genau, was du mit Firmen-System meinst, aber wenn du meinst, dass man als Gruppe ein gemeinsames Lager hat und auch Rechte verteilen und beschränken kann, dann kannst du dir Mal mein repository von DE100 anschauen.

Da ist ein Gang System dabei was genau die von mir oben beschriebenen Dinge macht.

https://github.com/Clon1998/DE100_public

Einfach ein Intro bauen und dann, hast du eigentlich zwei Möglichkeiten.

Du kannst entweder in der DB eine extra Spalte einfügen und auf Grund des Wertes der Spalte das Intro starten oder nicht.

Und die zweite und auch bessere Möglichkeit ist, dass du eine Variable in der profileNamespace speicherst und dann ebenfalls abhängig von dem Wert dieser Variable das Intro startest oder nicht.

Zitat von TaktischerSpeck

Danke

[getPlayerUID player, playerSide, _type, player] remoteExec["TON_fnc_getVehicles", 2];

Der rote teil werden die argumente sein womit der server die abfrage an die db stellt (zb. damit er weis um welchen spieler es geht)

Der orange ist die Server function

Der Blaue steht dann für was?

Ich sehe es richtig das diese code zeile die infos wieder zurück gibt oder?

[1,_type,_queryResult] remoteExecCall ["life_fnc_openGarage",_unit];

In dem fall schick er doch als ergebnis

1,_type,_queryResult

zurück richtig?

Alles anzeigen

90% richtig.

Der Befehl remoteExec ist nicht der Befehl, der die DB Anfragen stellt. remoteExec ist ein Befehl von der Arma Engine um Funktionsaufrufe remote zu starten. Also z.b. Client A will eine Methode test_rem auf Client B ausführen. In diesem Fall nutzt man remoteExec, wobei der Syntax so aussieht [ÜbergabeDaten] remoteExec ["zielMethode",Target]bei target kann man die clientId, ein Object oder eine Liste/Array aus Kombinationen von ClientIds und Objecten übergeben. Also um das Beispiel weiter zu führen ["SomeData"] remoteExec ["test_rem",Client_B]

Also worauf ich hinaus will ist, dass der rote Teil nur die übergeben Daten sind, die dann in der Methode "TON_fnc_getVehicles" genutzt werden um die DB-Query zu bauen.

Der Blaue Teil ist wie gesagt das Target und wie bereits erwähnt, kann das Target als ID oder Objekt angegeben werden. Hier haben wir eine ID, wobei die 2 immer für den Server steht (Mehr zu den ClientIds/IDs/Ints als Target kanns du dir im A3 Wiki anschauen)

Der Rest hat soweit gepasst.

Ich glaube am einfachsten ist es, wenn du dir Codebeispiele, wie meine Mission (DE100) anschaust. Deshalb habe ich dir hier mal die Reihenfolge für den Aufruf "Garage Öffnen" dargestellt.

i. Spieler öffnet Garage (Z.22-37) (Client)

- (HC/TON)_fnc_getVehicles mit den Params [getPlayerUID player, playerSide, _type, player]

ii.(HC/TON)_fnc_getVehicles (Server)

- In dieser Methode werden die Anfrage vom Client behandelt und es wird eine DB-Query gemacht und das DB-Result an den Client zurück geschickt

iii. life_fnc_openGarage (Z.38-End) (Client)

- Daten werden in den Dialog geladen.

Zitat von blackfisch

das klappt aber net bei Stecker ziehen

Doch klar lol. Hatte das System bei DE100 am laufen und für LYL das selbe gemacht.

Das ganze läuft ja auf Server-Seite und triggert immer wenn jemand DCed. Die Unit in diesem Trigger ist jene Unit, die von dem Spieler belegt war und hat somit noch alle Arma Items im Inventar/Ausgerüstet.

Man kann sogar soweit gehen und checken, ob es ein "Verifyed" Disconnect oder ein "Bad" Disconnect war und nur die "Bad" Disconnects resyncen über diese Methode.

Edit:

blackfisch du kannst dir das auch hier im Quellcode anschauen.

Setup vom EVH

EVH-Code/Fkt (Ab Zeile 37)

DB-Sync

Zitat von br1zey

Du könntest auch entweder beim Schließen vom Inv Speichern wobei wenn die Spieler das Raus bekommen sie das inv offen lassen und den Stecker ziehen

und die Belastende Version währe bei jeder Item Bewegung zu Speichern

Oder ihr nutzt einfach den Mission EVH "HandleDisconnect" und führt auf die _unit von dem EVH ein getUnitLoadout aus. Z-Inv kann dabei aber verloren gehen, außer man speichert bei jeder Interaktion mit dem VInv alle VInvs auf dem SpielerObj als Var.

Nein, das "Verschlüsseln" übernimmt die Konsolen Anwendung, welche in C# geschrieben ist.

Das "Entschlüsseln" liegt auf Serverseite in einer Funktion, die cfgCrypt.hpp wird von der C# Anwendung erstellt damit die Funktion in SQF weiß wo sie die Dateien Findet.

Naja mit dem Key wird Ver und Entschlüsselt

Update: Habe gerade auf das Git eine neuere Version von meinem L_makePbo hochgeladen. Also das Tool was ich geschrieben habe um die SQF Files zu verschleiern.

Mit dem Update soll es nun hoffentlich möglich sein sämtliche Custom Makros, welche man im Skript oder extern in einer .hpp definiert, im SQF File zu ersetzen und dadurch mehr Leuten die Möglichkeit zu geben, mein Tool zu benutzen

PS: Hatte heute einfach bisschen Langeweile und wollte das schon die ganze Zeit mal machen, da ich inzwischen bisschen besser in OOP's programmieren kann. Hatte leider nicht eine Richtige MissionFile um das Macro replacment richtig zu testen. Allerdings habe ich es mit einzelnen Files mit Komplexen und weniger Komplexen Macros getestet. Wenn jemand will kann er ja mal schauen ob es klappt oder ggef. Änderungen am Code vornehmen damit das besser Funktioniert.

Oder ihr schaut euch an wie der Obfu bei mir im DE100 Repo geht

Dann lernt ihr dabei vlt. auch noch was ^^.

Zitat von br1zey

Tja dadurch erhöht sich der Traffic zwischen Server und Client aber was halt doch Unnötig ist und auf die Performance geht

Das ist nur Meine Meinung aber jeder Client der Connected muss sich Erstmal die Functions vom Server Holen

Naja es geht, wenn man die Methoden einmalig beim Verbinden des Clients an den Client schickt, macht das nicht wirklich einen Unterschied.

life_hc ist das addon für den hc und life_shared ist ein addon was von server und hc genutzt wird.

Zitat von XFireFighter

Also soweit ich mich erinnere kann ich ja einfach mal loslegen, Lucian kann dann ja ergänzen/nachlegen:

-Gangsystem mit Lagerhäusern, welche man leveln kann.

-Ingame-Farmrechner mit allem drum und dran

-Man kann sich mit medikamenten

gegenseitig alle 60 min reviven. (Morphin und epinephrine)

- Lockpick system mit einem"Minigame"

- Beim Tod spawnt neben dem Spieler eine lootbare Kiste, welche man zuerst knacken muss

- Graffiti-Tagging

-einstellbare Mapmarker

- 2 Jobs. Tanklastfahrer und Taxifahrer. Wenn die Tankstellen auf der Karte leer sind müssen sie wieder aufgefüllt werden, da man ansonsten nich mehr tanken kann

- Eigenes Admin Tool mit allen möglichen funktionen ( finde ich persönlich um einiges besser wie InfiStar)

-Cfg sind teils web-basiert und können im Life Betrieb bearbeitet werden.

-Bank Heist System, möglichkeit die Bank Interaktiv zu bearbeiten (ähnlich wie z.B die "Gefallen" bei Payday2). Zudem ein strahlendes Objekt, Strahlenschutzanzüge und ein zufällig auftauchender Verkäufer für das Raubgut um campen zu vermeiden.

-GPS Traker

-Containereinbau um Fahrzeugkapazitäten zu erhöhen.

-Kaufbare Z-Items wie schranken etc. (Fuer cops glaube ich)

-ein voll ausgereiftes und ausgewachsenes Smartphone mit Jackpot, Markt, Sms, Ingame Telefon etc...

Und halt das was von vielen als Standart angesehen wird. Dyn.Markt etc.... Falls mir noch was einfällt ergänze ich das einfach hier.

Alternativ kannst du ja auch auf den DE100-Server joinen und selber schauen was es gibt oder die DE100 Changelogs im Forum studieren

Lg

Alles anzeigen

Habe die Sachen und noch paar andere Sachen im ersten Post ergänzt

Falls du das meinst, wir haben einige Mechanismen eingebaut die dies verhindern sollten.

- Ping/Pong System (Öffnet das Inventar nur wenn der User eine aktive Verbindung zum Server hat siehe fn_ping.sqf, fn_pong.sqf)

- dupeProtectionFSM (dupeProtection.fsm und gewisse Zeilen Code in den entsprechenden Stellen in Invenar-Skripten)

- Weitere Sachen, die mir nicht mehr einfallen....

Zitat von Lorenz Marco

in Open Trunk gibt es diese zeile:

if (missionNamespace getVariable ["auc_isLoading", false]) exitWith { ["Aufgrund eines potenziellen Netzwerklags darfst du das Inventar erst öffnen wenn das Auktionshaus alle Daten geladen hat.",true,"fast"] call life_fnc_notification_system; };

Das ist schön das dort diese Zeile steht. Leider weiß ich nur nicht was du von mir wissen willst,

Meinst du vlt. das durch das nutzen eines Lagswitches die User in der Lage waren gleichzeitig auf den Trunk zuzugreifen?

Bei welcher Sache genau? Also wo was behoben, wenn die Leute einen Lagswitch nutzen=?

Zitat von Marius1773

Ehrenmann.

Das noch in der heutigen Arma Community zu machen, Respekt.

Ich sehe jetzt schon 5 DE100 Server xD

Aber die meisten werden mit den Files nichts anfangen können xD

Da man erstmal die Pseudo Verschlüsselung zum laufen kriegen muss/deaktivieren muss, wird das ganze nicht sooo einfach

Hali hallo Nativ

Da ich nicht mehr an DE100 Entwickle und der Code ansonsten nur nutzlos auf meiner Festplatte vergammelt, habe ich mir gedacht ich könnte das ganze auch einfach als Repo hochladen.

Hier der Link zum Repo: https://github.com/Clon1998/DE100_public

Dort sind alle unverschlüsselten Skripte sowie ggef. Tools drinnen, welche ich bei DE100 benutzt habe bzw. welche ich dafür geschrieben habe.

Bitte beachtet die Lizenz (Was im Header der SQF-Files steht kann ignoriert werden).

Da ich ein faules Stück bin, habe ich jetzt keine Lust alle "Features"/Skripte rauszusuchen bzw. aufzuschreiben. Werde ich vlt. später nochmal machen.

Ihr könnt gerne Fragen zu dem ganzen Spaß hier im Thread stellen die ich dann auch, wenn ich Zeit finde, so gut wie möglich beantworten werde.

PS: Das Repo dient nicht dazu einen eigenen Ready2Go Server auf meinen SQF Dateien aufzubauen. Das ist auch nicht so ganz einfach damit, aber möglich .

Autoren:

Patrick "Lucian" Schmidt - Most of the Scripts and Database Structure

Anton "Molaron" - Scripts

XFireFighter - Scripts

"Nick Grimes" - Map

Den Disclaimer könnt ihr ignorieren... bin zu faul den raus zu machen

Hier ein paar Methoden um Zeitstempel/Datumsstempel in Arma 3 zu verwenden.

Die Code in fn_timeUnix.sqf berechnet keinen Unix TimeStamp da die Zahlen ansonsten zu Groß werden und Arma bei der Umrechnung Probleme bekommt/ungenau wird.

Aus diesem Grund kann man entweder einen eigenen Epoch verwenden oder den standart Epoch 2015 verwenden.

Viel Spaß damit

/*
    File:    fn_timeUnix.sqf
    Date:   2017-08-24 22:33:24
    Author: Patrick "Lucian" Schmidt
    Disclaimer: No one is allowed to use and edit my Script except for the DE100-ALTIS.life server and me.
    
    Description:
    Calcs seconds since 1 Feb. 00:00 _startYear(def. 2015)
    
    Note:
    Timerange getting longer mins are getting unpercise
*/

params[
    ["_input", 0, [0,[]]],
    ["_startYear",2015]
];

if (_input isEqualType []) exitWith {
    private _d = 0;
    for "_i" from _startYear to (_input select 0) - 1 do 
    {
        _d = _d + round linearConversion [0, 1, dateToNumber [_i, 12, 31, 23, 59], 0, 365, false];
    };
    _d = _d + floor(linearConversion [0, 1, dateToNumber (_input select[0,5]), 0, 365, false]);
    _d *60*60*24+((_input select 3))*60*60+(_input select 4)*60;

};
private _y = _startYear;
private _m = 1;
private _d = 0;
private _h = 0;
private _mi = 0;
private _ticks = _input;
for "_i" from 0 to 1 step 0 do {
    private _yD = if (_y call BIS_fnc_isLeapYear) then {
        366;
    } else {
        365;
    };
    _ticks = _ticks - _yD*24*60*60;
    if (_ticks < 0) exitWith {
        _d = (_yD*24*60*60 - abs(_ticks))/60/60/24;
    };
    _y = _y + 1;
};
private _months = [
    ["Jan",31],
    ["Feb",if (_y call BIS_fnc_isLeapYear) then {29;} else {28;}],
    ["Mrz",31],
    ["April",30],
    ["Mai",31],
    ["Juni",30],
    ["Juli",31],
    ["August",31],
    ["September",30],
    ["Oktober",31],
    ["November",30],
    ["Dezember",31]
];
_ticks = _d;
{
    _ticks = _ticks - (_x select 1);
    if (_ticks < 0) exitWith {
        _m = _forEachIndex + 1;
        _d = (_x select 1)-abs _ticks+1;
        _h = (_d - floor _d)*24;
        _mi = (_h - (floor _h))*60;
    };
} forEach _months;

[_y,_m,floor _d,floor _h,round _mi,0];

/*
    File:    fn_timeToStr.sqf
    Date:   2016-10-30 20:48:50
    Author: Patrick "Lucian" Schmidt
    Disclaimer: No one is allowed to use and edit my Script except for the DE100-ALTIS.life server and me.
    
    Description:
    Transforms time var into a nice looking string.
    Returns time and date in two seperate strings

    _mode
    0 - str
    1 - db
    2 - array
*/
params[
    ["_mode", 0],
    ["_date",life_real_time]
];
private _addZero = {
    params[
        ["_number", 0, [0]]
    ];
    if (_number < 10) exitWith {
        format ["0%1",_number];
    };
    _number;
};

private _year = _date select 0;
private _month = [_date select 1] call _addZero;
private _day = [_date select 2] call _addZero;
private _hr = [_date select 3] call _addZero;
private _min = [_date select 4] call _addZero;

private _return = call {
    if (_mode == 0) exitWith {
        format["%1.%2.%3 %4:%5",_day,_month,_year,_hr,_min];
    };

    if (_mode == 1) exitWith {
        format["%1-%2-%3 %4:%5:00",_year,_month,_day,_hr,_min];
    };

    if (_mode == 2) exitWith {
        [format["%1:%2", _hr, _min],format["%1.%2.%3", _day, _month, _year]];
    };
};

_return;

/*
    File:    fn_timeDiff.sqf
    Date:   2017-08-13 01:47:09
    Author: Patrick "Lucian" Schmidt
    Disclaimer: No one is allowed to use and edit my Script except for the DE100-ALTIS.life server and me.
    
    Description:
    Take a look for yourself.
*/
params[
    ["_date1", [], [[]]],
    ["_date2", [], [[]]]
];

private _raw = ([_date1] call life_fnc_timeUnix) - ([_date2] call life_fnc_timeUnix);
private _left = abs _raw;
private _week = floor(_left/(60*60*24*7));
_left = _left - _week*60*60*24*7;
private _day = floor(_left/(60*60*24));
_left = _left - _day*60*60*24;
private _hr = floor(_left/(60*60));
_left = _left - _hr*60*60;
private _min = floor(_left/(60));
_left = _left - _min*60;
private _sec = _left;

private _ret = call {
    if (_week > 0) exitWith {
        if (_week > 1) then {
            format["%1 Wochen",_week];
        } else {
            format["%1 Woche",_week];
        };
    };

    if (_day > 0) exitWith {
        if (_day > 1) then {
            format["%1 Tage",_day];
        } else {
            format["%1 Tag",_day];
        };
    };

    if (_hr > 0) exitWith {
        if (_hr > 1) then {
            format["%1 Stunden",_hr];
        } else {
            format["%1 Stunde",_hr];
        };
    };

    if (_min > 0) exitWith {
        if (_min > 1) then {
            format["%1 Minuten",_min];
        } else {
            format["%1 Minute",_min];
        };
    };

    if (_sec > 0) exitWith {
        if (_sec > 1) then {
            format["%1 Sekunden",_sec];
        } else {
            format["%1 Sekunde",_sec];
        };
    };
};

[_raw <= 0,_ret,_raw];

/*
    File:    fn_timeAdd.sqf
    Date:   2017-08-24 19:45:22
    Author: Patrick "Lucian" Schmidt
    Disclaimer: No one is allowed to use and edit my Script except for the DE100-ALTIS.life server and me.
    
    Description:
    Take a look for yourself.
*/

params[
    ["_time", [], [[]]],
    ["_add", 0, [0]],
    ["_array",false]
];

private _unix = [_time] call life_fnc_timeUnix;
private _newTime = [_unix+_add] call life_fnc_timeUnix;

if (_array) exitWith {
    _newTime;
};
[0,_newTime] call life_fnc_timeToStr;