Fahrzeuge mit leeren Waffen spawnen

Beim Marid geht es sogar auszublenden... _vehicle animate ["HideTurret",1]; - habs eben mal nachgeschaut

Moin,

ansonsten würde ich Dir empfehlen die core/functions/clearVehicleAmmo.sqf zu verwenden. Hier kannst Du das definieren. Gegebenen falls baust Du da auch das von blackfisch ein

hier mal ein beispiel für den marid, der als reiner transporter fungiert, hier wurden die schütze (waffe) und kommander(thermal) sitze gesperrt

// MSE-3 Marid
if(EQUAL(_veh,"O_APC_Wheeled_02_rcws_F")) then 
{
    _vehicle animate ["HideTurret", 1];        // geschütz versteckt
    _vehicle lockTurret [[0], true];            // Schützesitz deaktiviert
    _vehicle lockTurret [[1], true];            // Kommandersitz deaktiviert
};

alternative man packt das in eine foreach Anweisung, dann muss man nicht jedes Geschütz einzeln eintragen. Tass mit deinem Befehl sperrst du den platz ;-). Hab leider meine Config gerade nicht zur Hand.

Wo fügt man das den ein was Tass geschrieben hat ?

in die clearVehicleAmmo

ich habe das bei Xian so gelöst

if (_veh == "O_T_VTOL_02_vehicle_F") then
{
  //Y-32 Vehicle
  {_vehicle removeWeapon _x} forEach weapons _vehicle;
  {_vehicle removeMagazine _x} forEach magazines _vehicle;
};

kann man im prinzip mit jedem Fahrzeug machen. Damit löschst Du die Magazine und deaktivierst die Waffen komplett.

Zitat von moeck

{_vehicle removeWeapon _x} forEach weapons _vehicle;

Entfernt bei Autos aber auch Hupen

kann man ja abfangen wenn man will

Zitat von moeck

kann man ja abfangen wenn man will

Wie geht das?

MFG Blake

Moin,

hier mal inklusive der Ausnahme. Habe mir jetzt einfach mal das Truckhorn rausgesucht. Man muss dann natürlich schauen welche Hupe verbaut ist

{
    if (!(_x isequalto "TruckHorn")) then {
          _vehicle removeWeapon _x;
    };
} forEach weapons _vehicle;

Gruß,

moeck

#include "..\..\script_macros.hpp"
/*
    File: fn_clearVehicleAmmo.sqf
    Author: Bryan "Tonic" Boardwine

    Description:
    Clears the vehicle of ammo types that we don't want.

    Syntax: _vehicle removeMagazinesTurret [magazineName, turretPath]
    Documentation: https://community.bistudio.com/wiki/removeMagazinesTurret
*/
private ["_vehicle","_veh"];
_vehicle = [_this,0,objNull,[objNull]] call BIS_fnc_param;
if (isNull _vehicle) exitWith {};
_veh = typeOf _vehicle;

if (_veh isEqualTo "B_Boat_Armed_01_minigun_F") then {
    _vehicle removeMagazinesTurret ["200Rnd_40mm_G_belt",[0]];
};

if (_veh isEqualTo "B_APC_Wheeled_01_cannon_F") then {
    _vehicle removeMagazinesTurret ["60Rnd_40mm_GPR_Tracer_Red_shells",[0]];
    _vehicle removeMagazinesTurret ["40Rnd_40mm_APFSDS_Tracer_Red_shells",[0]];
};

if (_veh isEqualTo "O_Heli_Attack_02_black_F") then {
    _vehicle removeMagazinesTurret ["250Rnd_30mm_APDS_shells",[0]];
    _vehicle removeMagazinesTurret ["8Rnd_LG_scalpel",[0]];
    _vehicle removeMagazinesTurret ["38Rnd_80mm_rockets",[0]];
};

if (_veh isEqualTo "B_Heli_Transport_01_F") then {
    _vehicle removeMagazinesTurret ["2000Rnd_65x39_Belt_Tracer_Red",[1]];
    _vehicle removeMagazinesTurret ["2000Rnd_65x39_Belt_Tracer_Red",[2]];
};

if (_veh == "O_T_VTOL_02_infantry_dynamicLoadout_F") then
{
 //Y-32 Transport
 {_vehicle removeWeapon _x} forEach weapons _vehicle;
 {_vehicle removeMagazine _x} forEach magazines _vehicle;
};

clearWeaponCargoGlobal _vehicle;
clearMagazineCargoGlobal _vehicle;
clearItemCargoGlobal _vehicle;
clearBackpackCargoGlobal _vehicle;

Moinsen wollte es auch gerade mal versuchen mit meiner Y32 Truppentransporter. ich hab einiges aus diesem thread versucht und jede mal sind wieder waffen drin was mach ich falsch?

moin füge das mal so ein

if (_veh isEqualTo "O_T_VTOL_02_infantry_F") then
{
  //Y-32 Infantry
  {_vehicle removeWeapon _x} forEach weapons _vehicle;
  {_vehicle removeMagazine _x} forEach magazines _vehicle;
};
if (_veh isEqualTo "O_T_VTOL_02_vehicle_F") then
{
  //Y-32 Vehicle
  {_vehicle removeWeapon _x} forEach weapons _vehicle;
  {_vehicle removeMagazine _x} forEach magazines _vehicle;
};

danke hat geklappt

klappt das auch bei dem Tempest Muni ?

Vom hören sagen her soll man sich dort dauerhaft frisch bestücken können an Munition.
Ich würde das Fahrzeug aber gerne auf meine Insel nutzen und deswegen müsste die Muni da raus =D

dazu musst du beim spawnen des Fahrzeugs, die Ammo rausnehmen

Ammo Cargo über den Link hast Du eine Anleitung

in die fn_spawnVehicle müsstest Du folgendes eintragen

_vehicle setAmmoCargo 0; am besten dort wo auch die Funktion life_fnc_clearVehicleAmmo auf gerufen wird

wird getestet =)