Kisten in Häusern buggen weg

moeck

Moin,

aktuell haben wir folgendes Problem. Bei einigen Häusern gehen die platzierten Kisten kaputt. Es scheint nach den bisherigen Erkenntnissen sich immer wieder um die selben Häuser zu handeln. Bisher habe ich noch keinen Anhaltspunkt gefunden warum die Kisten wegbuggen. Zum Teil kauft ein Spieler das Haus platziert die Kiste und kann auch darauf zugreifen. Nach einem Disconnect bzw. Server Restart ist die Kiste dann nicht mehr vorhanden. In der DB finde ich aber die Kiste inklusive Inhalt noch zu mindestens so lange kein weiterer Restart erfolgt ist. Danach wurde die Kiste inkl. I-Inventar auch in den DB gelöscht. Wenn der Spieler dann eine neue Kiste platziert kann er zu mindestens auf das T-Inventar zugreifen aber das ist keine befriedingten Lösung . Achja wir haben die Anzahl der möglichen Kisten von ehemals 4 auf eine reduzierte um den Effekt etwas abzuschwächen.

Ich poste hier mal das Script zum Platzieren der Kiste beim Connect.

C

/*
    BLAH BLAH
    I LOVE NOTEPAD++ GET OVER IT
    BLAH!
*/
private["_house","_houseID","_containers","_query"];
_house = [_this,0,ObjNull,[ObjNull]] call BIS_fnc_param;
if(isNull _house) exitWith {systemChat "House null";};
_houseID = _house getVariable["house_id",-1];
if(_houseID == -1) exitWith {systemChat "HouseID invalid";};

_containers = _house getVariable ["containers",[]];

systemChat format["Number of containers found: %1",count _containers];
_arr = [];
{
    _className = typeOf _x;
    _weapons = getWeaponCargo _x;
    _magazines = getMagazineCargo _x;
    _items = getItemCargo _x;
    _backpacks = getBackpackCargo _x;
    
    _arr pushBack [_className,[_weapons,_magazines,_items,_backpacks]];
} foreach _containers;

_arr = [_arr] call DB_fnc_mresArray;
_query = format["UPDATE houses SET containers='%1' WHERE id='%2'",_arr,_houseID];
waitUntil{!DB_Async_Active};
[_query,1] call DB_fnc_asyncCall;
//systemChat "Query ran?";

Alles anzeigen

Gruß,

moeck

Shinji

Hmm, zeig mal die containerInit ~ dass hier is nix besonders nur das Speichern für die DB.

moeck

bin gerade am suchen nach der richtigen Datei

C

/*
    Author: Bryan "Tonic" Boardwine
    
    Description:
    Fetches all the players houses and sets them up.
*/
private["_query","_houses"];
if(_this == "") exitWith {};

_query = format["SELECT pid, pos, inventory, containers FROM houses WHERE pid='%1' AND owned='1'",_this];
waitUntil{!DB_Async_Active};
_houses = [_query,2,true] call DB_fnc_asyncCall;

_return = [];
{
    _pos = call compile format["%1",_x select 1];
    _house = nearestBuilding _pos;
    //_house = (nearestObjects[_pos, ["House_F"],12] select 0);
    _house allowDamage false;
    _containers = [];
    _house setVariable["slots",[],true];
    if(!isNil {(_house getVariable "containers")}) then {
        {if(!isNull _x) then {deleteVehicle _x;};} foreach (_house getVariable "containers");
    };
    
    _trunk = [_x select 2] call DB_fnc_mresToArray;
    if(typeName _trunk == "STRING") then {_trunk = call compile format["%1", _trunk];};
    _containerData = [_x select 3] call DB_fnc_mresToArray;
    if(typeName _containerData == "STRING") then {_containerData = call compile format["%1", _containerData];};
    _house setVariable["Trunk",_trunk,true];
    {
        if(count _x == 0) exitWith {}; //No containers / items.
        _className = _x select 0;
        _weapons = (_x select 1) select 0;
        _magazines = (_x select 1) select 1;
        _items = (_x select 1) select 2;
        _backpacks = (_x select 1) select 3;
        
        //Setup the variables
        _positions = [_house] call life_fnc_getBuildingPositions;
        _pos = [0,0,0];
        
        {
            _slots = _house getVariable ["slots",[]];
            if(!(_forEachIndex in _slots)) exitWith {
                _slots pushBack _forEachIndex;
                _house setVariable["slots",_slots,true];
                _pos = _x;
            };
        } foreach _positions;
        
        if(_pos isEqualTo [0,0,0]) exitWith {};
        
        _container = createVehicle[_className,_pos,[],0,"NONE"];
        waitUntil{!isNil "_container"};
        _container setPosATL _pos;
        //_container enableSimulation false;
        
        _containers pushBack _container;
        clearWeaponCargoGlobal _container;
        clearItemCargoGlobal _container;
        clearMagazineCargoGlobal _container;
        clearBackpackCargoGlobal _container;
        //Add weapons to the crate.
        {
            _weaponCount = (_weapons select 1) select _forEachIndex;
            _container addWeaponCargoGlobal [_x,_weaponCount];
        } foreach (_weapons select 0);
        
        //Add magazines
        {
            _magazineCount = (_magazines select 1) select _forEachIndex;
            _container addMagazineCargoGlobal [_x,_magazineCount];
        } foreach (_magazines select 0);
            
        //Add items
        {
            _itemCount = (_items select 1) select _forEachIndex;
            _container addItemCargoGlobal [_x,_itemCount];
        } foreach (_items select 0);
        
        //Add backpacks
        {
            _backpackCount = (_backpacks select 1) select _forEachIndex;
            _container addBackpackCargoGlobal [_x,_backpackCount];
        } foreach (_backpacks select 0);
        
    } foreach _containerData;
    
    _house setVariable["containers",_containers,true];
    _return pushBack [_x select 1,_containers];
} foreach _houses;

missionNamespace setVariable[format["houses_%1",_this],_return];

Alles anzeigen

nflug

Wie siehts aus sind die Häuser selber Platziert oder die originalen von altis

moeck

Ich sehe gerade, dass das alles in 5.x umgeschrieben ist. Vielleicht kann ich das einfach übernehmen

moeck

sind nur orginale Häuser, platzierte kann man zwar kaufen aber keine Kisten setzen

Shinji

Interessant ist der Part hier:

Code

_trunk = [_x select 2] call DB_fnc_mresToArray;
 if(typeName _trunk == "STRING") then {_trunk = call compile format["%1", _trunk];};
 _containerData = [_x select 3] call DB_fnc_mresToArray;
 if(typeName _containerData == "STRING") then {_containerData = call compile format["%1", _containerData];};
 _house setVariable["Trunk",_trunk,true];

Okay, versuch mal spaßenshalber Diag_logs zu machen o.o unter folgender Zeile:

_house setVariable["Trunk",_trunk,true];

Diag_log format ["### %1",_containerData];

Und mal ein Haus mit container laden lassen was verbuggt wäre etc.

moeck

Werde ich heute abend mal versuchen. Mal schauen ob ich was in den Logs sehe

ZorG

Nachgefragt, meinst Du mit den selben Häusern die gleichen nach Classname oder die gleichen an einem Standort?

Falls Standort, ist das Haus stellenweise etwas in den Boden versunken?

Versuch mal folgendes:

C: fn_fetchPlayerHouses.sqf

... 
if(_pos isEqualTo [0,0,0]) exitWith {};

_container = createVehicle[_className,[0,0,500],[],0,"NONE"]; //<- NEU
 waitUntil{!isNil "_container"};
_container allowDamage false; // <- NEU
_container setPosATL _pos;
 //_container enableSimulation false;
...

Könnte sein, das die Kisten beim erstellen sich zerstören.

moeck

Ich meinte den Standort. ich werde es testen

nflug

Also wenn es selbst gesetzte Häuser sind kann es sein das Diese zum 0 Punkt gespawnt werden wenn du das Haus in Editor gesetzt hast.

moeck

Alles klar, gut zu wissen, trifft aber bei uns nicht zu

moeck

Hi,

habe die Änderungen jetzt mal getestet und es sieht ganz gut aus. Die Kisten stehen zwar nicht sondern liegen auf der Seite aber das ist ja erstmal egal

Gruß,

moeck

ZorG

Dann spawn die vielleicht zu Tief.

Kannst ja noch folgendes ändern:

_container setPosATL [_pos select 0,_pos select 1,(_pos select 2) +0.5];

moeck

Jo werde das auf jeden fall mal austesten . kann aber auch sein, dass sie links oder rechts gegen die Wände buggen.

Benutzer online in diesem Thema