Ace Interaktion als Cop zum beschlagnahmen

1NickZ1

Hallo, ich hätte da eine Frage. Mein Windows Menü ist komischer Weise verschwunden, was ich auch eigentlich wollte, nur das Problem ist allerdings, wie kann ich als BLUFOR also als Polizist per Ace System das Fahrzeug beschlagnahmen?

_action = ["Beschlagnahmen", "Beschlagnahmen", "", {hint format ["Fahrzeug wird beschlagnahmt: %1", process _target]}, {true}] call ace_interact_menu_fnc_createAction;["LandVehicle", 0, ["ACE_MainActions"], _action, true] call ace_interact_menu_fnc_addActionToClass;aber so funktioniert das nicht wirklich... ich weiß nichtmehr weiter.

br1zey

was soll bei dem Code auch passieren ????

hint format ["Fahrzeug wird beschlagnahmt: %1", process _target]

hast den den den das Ace Mmenu oder kommt das auch nicht

Probier das mal SO

C

_rl_ace = ["Beschlagnahmen", "Beschlagnahmen", "", {[_target] spawn life_fnc_impoundAction;}, {true}, {},"",[0, 0, 0],10] call ace_interact_menu_fnc_createAction;
["LandVehicle", 0, ["ACE_MainActions"], _rl_ace, true] call ace_interact_menu_fnc_addActionToClass;

1NickZ1

Das Ace Menü kommt, wenn du das meinst. Aber das funktioniert auch noch nicht... mache ich was falsch?

br1zey

hast du mein code jetzt mal probiert ?

1NickZ1

Ja, das habe ich.

br1zey

mhhh aso Änder mal
Zeile 13 in der fn_impoundAction.sqf

von
if (player distance cursorObject > 10) exitWith {};
in
if (player distance _vehicle > 10) exitWith {};

und habe noch was am Code geändert

1NickZ1

Ist auch geändert, passiert immer noch nichts.^^

br1zey

grade getestet geht bei mir

wo fürst du den Code aus ?

Du sagst der ACE Punkt kommt jetzt die Frage fehlermeldung ? ist was im RPT ?

1NickZ1

Nein, dachte du meinst das Menü allgemein, der Punkt kommt nicht.

br1zey

Wo führst du das script aus ?

1NickZ1

fn_copInteractionMenu.sqf

br1zey

....

dan ruf die datei auch auf ....

sprich in der init im core ordner

[] spawn life_fnc_copInteractionMenu;

einfach unten einfügen

1NickZ1

Der Punkt taucht auf, hat aber keine Funktion.

//Edit:
Das funktioniert, nur das Fahrzeug verschwindet nicht.

br1zey

dan ist entwerde in der impoundAction was Falsch oder am code selber bei mir geht der code also würde ich sagen an der impoundAction ist was falsch schike die mal bitte rein

1NickZ1

Wo genau finde ich diese? Wenn sie im gleichen .sqf ist , dann ist sie garnicht definiert.

br1zey

ok anders Zeig mal deine fncopInteractionMenu.sqf

was du da gemacht hast

1NickZ1

Code

/*
	File: fn_copInteractionMenu.sqf
	Author: Bryan "Tonic" Boardwine

	Description:
	Replaces the mass addactions for various cop actions towards another player.
*/
_rl_ace = ["Beschlagnahmen", "Beschlagnahmen", "_icon", {[_target] spawn life_fnc_impoundAction;}, {true}, {},"",[0, 0, 0],10] call ace_interact_menu_fnc_createAction;
["LandVehicle", 0, ["ACE_MainActions"], _rl_ace, true] call ace_interact_menu_fnc_addActionToClass;




#define Btn1 37450
#define Btn2 37451
#define Btn3 37452
#define Btn4 37453
#define Btn5 37454
#define Btn6 37455
#define Btn7 37456
#define Btn8 37457
#define Btn9 37458
#define Title 37401




private["_display","_curTarget","_Btn1","_Btn2","_Btn3","_Btn4","_Btn5","_Btn6","_Btn7","_Btn8","_Btn9"];
if(!dialog) then {
	createDialog "pInteraction_Menu";
};
disableSerialization;
_curTarget = [_this,0,ObjNull,[ObjNull]] call BIS_fnc_param;
if(isNull _curTarget) exitWith {closeDialog 0;}; //Bad target




if(_curTarget isKindOf "House_F") exitWith {
	if((nearestObject [[16019.5,16952.9,0],"Land_Dome_Big_F"]) == _curTarget OR (nearestObject [[16019.5,16952.9,0],"Land_Research_house_V1_F"]) == _curTarget) then {
		_display = findDisplay 37400;
		_Btn1 = _display displayCtrl Btn1;
		_Btn2 = _display displayCtrl Btn2;
		_Btn3 = _display displayCtrl Btn3;
		_Btn4 = _display displayCtrl Btn4;
		_Btn5 = _display displayCtrl Btn5;
		_Btn6 = _display displayCtrl Btn6;
		_Btn7 = _display displayCtrl Btn7;
		_Btn8 = _display displayCtrl Btn8;
		_Btn9 = _display displayCtrl Btn9;




		life_pInact_curTarget = _curTarget;

		_Btn1 ctrlSetText localize "STR_pInAct_Repair";
		_Btn1 buttonSetAction "[life_pInact_curTarget] spawn life_fnc_repairDoor;";

		_Btn2 ctrlSetText localize "STR_pInAct_CloseOpen";
		_Btn2 buttonSetAction "[life_pInact_curTarget] call life_fnc_doorAnimate;";
		_Btn3 ctrlShow false;
		_Btn4 ctrlShow false;
		_Btn5 ctrlShow false;
		_Btn6 ctrlShow false;
		_Btn7 ctrlShow false;
		_Btn8 ctrlShow false;
		_Btn9 ctrlShow false;
	} else {
		closeDialog 0;
	};
};

if(!isPlayer _curTarget && side _curTarget == civilian) exitWith {closeDialog 0;}; //Bad side check?
_display = findDisplay 37400;
_Btn1 = _display displayCtrl Btn1;
_Btn2 = _display displayCtrl Btn2;
_Btn3 = _display displayCtrl Btn3;
_Btn4 = _display displayCtrl Btn4;
_Btn5 = _display displayCtrl Btn5;
_Btn6 = _display displayCtrl Btn6;
_Btn7 = _display displayCtrl Btn7;
_Btn8 = _display displayCtrl Btn8;
_Btn9 = _display displayCtrl Btn9;




life_pInact_curTarget = _curTarget;




//Set Unrestrain Button
_Btn1 ctrlSetText localize "STR_pInAct_Unrestrain";
_Btn1 buttonSetAction "[life_pInact_curTarget] call life_fnc_unrestrain; closeDialog 0;";




//Set Check Licenses Button
_Btn2 ctrlSetText localize "STR_pInAct_checkLicenses";
_Btn2 buttonSetAction "[[player],""life_fnc_licenseCheck"",life_pInact_curTarget,FALSE] spawn life_fnc_MP";




//Set Search Button
_Btn3 ctrlSetText localize "STR_pInAct_SearchPlayer";
_Btn3 buttonSetAction "[life_pInact_curTarget] spawn life_fnc_searchAction; closeDialog 0;";




//Set Escort Button
if((_curTarget getVariable["Escorting",false])) then {
	_Btn4 ctrlSetText localize "STR_pInAct_StopEscort";
	_Btn4 buttonSetAction "[life_pInact_curTarget] call life_fnc_stopEscorting; [life_pInact_curTarget] call life_fnc_copInteractionMenu;";
} else {
	_Btn4 ctrlSetText localize "STR_pInAct_Escort";
	_Btn4 buttonSetAction "[life_pInact_curTarget] call life_fnc_escortAction; closeDialog 0;";
};




//Set Ticket Button
_Btn5 ctrlSetText localize "STR_pInAct_TicketBtn";
_Btn5 buttonSetAction "[life_pInact_curTarget] call life_fnc_ticketAction;";




_Btn6 ctrlSetText localize "STR_pInAct_Arrest";
_Btn6 buttonSetAction "[life_pInact_curTarget] call fnc_arrestmenu;";




_Btn7 ctrlSetText localize "STR_pInAct_PutInCar";
_Btn7 buttonSetAction "[life_pInact_curTarget] call life_fnc_putInCar;";




_Btn8 ctrlSetText localize "STR_pInAct_RemoveWeapons";
_Btn8 buttonSetAction "[life_pInact_curTarget] spawn life_fnc_removeWeaponAction; closeDialog 0;";




_Btn9 ctrlSetText localize "STR_pInAct_TestIntox";
_Btn9 buttonSetAction "[life_pInact_curTarget] spawn life_fnc_testIntox;";




//Check that you are near a place to jail them.
if(!((player distance (getMarkerPos "police_hq_1") < 30) OR  (player distance (getMarkerPos "police_hq_2") < 30) OR (player distance (getMarkerPos "cop_spawn_3") < 30) OR (player distance (getMarkerPos "cop_spawn_5") < 30))) then 
{
	_Btn6 ctrlEnable false;
};

Alles anzeigen

br1zey

... kann es sein das du nciht wirklich die grundlagen vom Scripting kannst aber willst mit ACE arbeiten ?

ok Mal zum Anfang

entfern den ace coder aus der copInteractionMenu und entferne auch das aus der Init

Erstell eine Neue Datei sagen wir mal im Ordner
Core mit dem Namen

fn_AceActionSetup.sqf
dort Schreibst du den coder rein

Brainfuck

_rl_ace = ["Beschlagnahmen", "Beschlagnahmen", "", {[_target] spawn life_fnc_impoundAction;}, {true}, {},"",[0, 0, 0],10] call ace_interact_menu_fnc_createAction;
["LandVehicle", 0, ["ACE_MainActions"], _rl_ace, true] call ace_interact_menu_fnc_addActionToClass;

jetzt gehst du in die

Function.hpp

und Trägst unter
class setupEVH {};
das ein
class AceActionSetup {};

sollte dan so Aussehn

Brainfuck

class Master_Directory {
        file = "core";
        class initCiv {};
        class initCop {};
        class initMedic {};
        class setupActions {};
        class setupEVH {};
        class AceActionSetup {};
        class survival {};
        class welcomeNotification {};
    };

Alles anzeigen

jetzt gest du in core/init.sqf

und trägst da
unter
[] call life_fnc_hudSetup;
folgende ein
[] spawn life_fnc_AceActionSetup;

jetzt gest aufn Server und Guckst das der Ace Punkt Belschlagnahmen auf dem Auto ist wenn Ja aber er nix macht Poste bitte noch deine

fn_ImpoundAction.sqf

1NickZ1

Das Farhzeug verschwindet immer noch nicht. Hier die .sqf.

Code

/*
	File: fn_impoundAction.sqf
	Author: Bryan "Tonic" Boardwine

	Description:
	Impounds the vehicle
*/
private["_vehicle","_type","_time","_price","_vehicleData","_upp","_ui","_progress","_pgText","_cP"];
_vehicle = cursorTarget;
if(!((_vehicle isKindOf "Car") || (_vehicle isKindOf "Air") || (_vehicle isKindOf "Ship") || (_vehicle isKindOf "Motorcycle") || (_vehicle isKindOf "A3L_Tahoe_Base"))) exitWith {};
if(player distance cursorTarget > 10) exitWith {};
if((_vehicle isKindOf "Car") || (_vehicle isKindOf "Air") || (_vehicle isKindOf "Ship") || (_vehicle isKindOf "Motorcycle") || (_vehicle isKindOf "A3L_Tahoe_Base")) then
{
	_vehicleData = _vehicle getVariable["vehicle_info_owners",[]];
	if(count _vehicleData == 0) exitWith {deleteVehicle _vehicle}; //Bad vehicle.
	_vehicleName = getText(configFile >> "CfgVehicles" >> (typeOf _vehicle) >> "displayName");
	[[0,format[localize "STR_NOTF_BeingImpounded",(_vehicleData select 0) select 1,_vehicleName]],"life_fnc_broadcast",true,false] spawn life_fnc_MP;
	life_action_inUse = true;

	_upp = localize "STR_NOTF_Impounding";
	//Setup our progress bar.
	disableSerialization;
	5 cutRsc ["life_progress","PLAIN"];
	_ui = uiNameSpace getVariable "life_progress";
	_progress = _ui displayCtrl 38201;
	_pgText = _ui displayCtrl 38202;
	_pgText ctrlSetText format["%2 (1%1)...","%",_upp];
	_progress progressSetPosition 0.01;
	_cP = 0.01;
	while{true} do
	{
		sleep 0.09;
		_cP = _cP + 0.01;
		_progress progressSetPosition _cP;
		_pgText ctrlSetText format["%3 (%1%2)...",round(_cP * 100),"%",_upp];
		if(_cP >= 1) exitWith {};
		if(player distance _vehicle > 10) exitWith {};
		if(!alive player) exitWith {};
	};
	5 cutText ["","PLAIN"];

	if(player distance _vehicle > 10) exitWith {hint localize "STR_NOTF_ImpoundingCancelled"; life_action_inUse = false;};
	if(!alive player) exitWith {life_action_inUse = false;};
	//_time = _vehicle getVariable "time";
	//if(isNil {_time}) exitWith {deleteVehicle _vehicle; hint "This vehicle was hacked in"};
	//if((time - _time)  < 120) exitWith {hint "This is a freshly spawned vehicle, you have no right impounding it."};
	if((count crew _vehicle) == 0) then
	{
		if(!((_vehicle isKindOf "Car") || (_vehicle isKindOf "Air") || (_vehicle isKindOf "Ship"))) exitWith {life_action_inUse = false;};
		_type = getText(configFile >> "CfgVehicles" >> (typeOf _vehicle) >> "displayName");
		switch (true) do
		{
			case (_vehicle isKindOf "Car"): {_price = (call life_impound_car);};
			case (_vehicle isKindOf "Ship"): {_price = (call life_impound_boat);};
			case (_vehicle isKindOf "Air"): {_price = (call life_impound_air);};
		};

		life_impound_inuse = true;
		[[_vehicle,true,player],"TON_fnc_vehicleStore",false,false] spawn life_fnc_MP;
		waitUntil {!life_impound_inuse};
		hint format[localize "STR_NOTF_Impounded",_type,_price];
		[[0,format[localize "STR_NOTF_HasImpounded",profileName,(_vehicleData select 0) select 1,_vehicleName]],"life_fnc_broadcast",true,false] spawn life_fnc_MP;
		life_atmcash = life_atmcash + _price;
	}
		else
	{
		hint localize "STR_NOTF_ImpoundingCancelled";
	};
};
life_action_inUse = false;

Alles anzeigen

br1zey

änder mal Zeile 9

von
_vehicle = cursorTarget;
in
_vehicle = _this select 0;

und zeile 11
von
if(player distance cursorTarget > 10) exitWith {};
in
if(player distance _vehicle > 10) exitWith {};

Benutzer online in diesem Thema