TFAR Blackscreen Scriptsuche

Hannkok

Suche ein Script für Task force radio, das einen Blackscreen auf dem Gameserver verursacht wenn man nicht im richtigen Teamspeak channel ist. Es gibt schon derartige Scripts, allerdings nur laut lesen für die 3.1.4.8 Version.
Ich würde das gerne für die 4.4r3 ist, wenn sich damit jemand auskennt. Und dies möglich und Umsetzbar, wäre sehr lieb.

Danke im vorraus

MFG
Pascal / hannkok

Kuchenplatte

Du musst TFR mit als Mod mitladen.
Dann gehst du in den Editor und setzt einen Marker.

Fertig.

Hannkok

Es geht mir nicht darum, tfar etc. klappt alles.

Es geht mir darum, das wenn die Leute aus dem Taskforceradio Channel gehen und sich woanders aufhalten, das sie ingame am Spielen gehindert werden sollen. Weil viele einfach auf den Server gehen und dann wieder aus dem Modserver channel rausgehen, um sich mit anderen Leuten zu unterhalten und man sie Ingame dann nicht hört. Weil sie nicht im TFAR channel sind.

PoweredByte

Du kannst dir dafür einen TS3 BOT schreiben

powerafro2

Hier das einfach in der init_survival.sqf 3er Version in der 4.0 Version in die fn_survival.sqf

Spoiler anzeigen

//TFAR - Task Force Radio - ChannelCheck:
[] spawn
{
private["_ChannelName","_ServerName","_isTeamSpeakPluginEnabled"];
sleep 15;
while{true}do
{
_ChannelName = call TFAR_fnc_getTeamSpeakChannelName;
_ServerName = call TFAR_fnc_getTeamSpeakServerName;
_isTeamSpeakPluginEnabled = call TFAR_fnc_isTeamSpeakPluginEnabled;

_DarfNixSehen = false;
_IstAdmin = ((call life_adminlevel) > 0);
_WhiteListedChannels = ["TaskForceRadio"];

if(!_IstAdmin && _ServerName != "DEINTS3Name" )then{_DarfNixSehen = true;};
if(!_IstAdmin && !(_ChannelName in _WhiteListedChannels))then{_DarfNixSehen = true;};
if(!_IstAdmin && !_isTeamSpeakPluginEnabled)then{_DarfNixSehen = true;};

if(_DarfNixSehen) then{cutText["Falscher Channel/Server oder Plugin Disabled","BLACK FADED"];}
else{cutText ["","PLAIN"];};
sleep 3;
};
};

Jedoch musst du da dein Ts3 Name reinschreiben.

DEINTS3Name

ich hoffe ich konnte dir helfen mfg power

br1zey

das ist aus der 4.4

in der core/init.sqf

Bash

//TFAR Channel Check
if(FETCH_CONST(life_adminlevel) > 0) exitWith {};
_showTf = LIFE_SETTINGS(getNumber,"showTFARMessage");
if(EQUAL(_showTf,0))exitWith {};




_TFenabled = [] call TFAR_fnc_isTeamSpeakPluginEnabled;




if (isNil "TFAR_fnc_isTeamSpeakPluginEnabled") exitwith {
	999999 cutText ["Task Force Radio is not running on your computer. Please re-sync and retry","BLACK FADED"];
	999999 cutFadeOut 99999999;
};




if (!(_TFenabled)) then {
	while {!([] call TFAR_fnc_isTeamSpeakPluginEnabled)} do {
		titleText ["Du benötigst Tast Force Radio", "BLACK"];
		sleep 2;
	};
};




RL_TFEnabled = true;
RL_onTsServer = "dein TS name" == (call TFAR_fnc_getTeamSpeakServerName);
RL_onChannel = "TaskForceRadio" == (call TFAR_fnc_getTeamSpeakChannelName);
titleText ["Task Force Radio erfolgreich geladen!","BLACK IN"];




[] spawn {
	while {true} do {
		_TFenabled = [] call TFAR_fnc_isTeamSpeakPluginEnabled;
		if ((!(_TFenabled)) && (RL_TFEnabled)) then {
			titleText ["Bitte Aktiviere das Teamspeak 3 TFAR Plugin! || TS3 -> Settings -> Plugins", "BLACK"];
			RL_TFEnabled = false;
		};




		_onTsServer = "TeamSpeakName Eintragen" == (call TFAR_fnc_getTeamSpeakServerName);
		if (!(_onTsServer)) then {
			titleText ["Bitte tritt unserem Teamspeak 3 Server bei!", "BLACK"];
			RL_onTsServer = false;
		} else {
			if (!(RL_onTsServer)) then {
				titleText ["TS server check Fertig. Willkommen!","BLACK IN"];
				RL_onTsServer = true;
			};
		};




		_onChannel = "TaskForceRadio" == (call TFAR_fnc_getTeamSpeakChannelName);
		if (!(_onChannel)) then {
			titleText ["Du bist nicht nicht im richtigen Channel! Bitte lade das TFAR Plugin neu! || Settings -> Plugins -> Reload All", "BLACK"];
			RL_onChannel = false;
		} else {
			if (!(RL_onChannel)) then {
				titleText ["TS channel check Fertig. Willkommen!","BLACK IN"];
				RL_onChannel = true;
			};
		};




		if ((_TFenabled) && (!(RL_TFEnabled))) then {
			titleText ["Plugin aktiviert, Willkommen!","BLACK IN"];
			RL_TFEnabled = true;
		};
    	uiSleep 30;
    };
};

Alles anzeigen

VariatoX

Es gibt etliche Möglichkeiten, um dem Spieler zu sagen, dass er TFAR nicht richtig benutzt.
Das Ganze habe ich auf meinem derzeitigen Server so gelöst (kannste individuell nach deinem belieben anpassen):

C

0 spawn {
	if(call(life_adminlevel) >= 1) exitWith {systemChat "TFAR > Du bist ein Administrator. Daher wird dein Client nicht auf TFAR geprüft.";}; //Administratoren werden grundsätzlich nicht geprüft - Kannst du auch rausnehmen
	if(getPlayerUID player in ["765611980123456","765611980654321"]) exitWith {}; //Spieler-IDs von Spielern die nie einen Blackscreen erhalten sollen (Kannst du nach belieben erweitern oder auch rausnehmen)
	_fnc_tfarCheck = {
		private _serverName = "Server_Name"; //CASE-SENSITIVE! - Dein TeamSpeak3 Servername
		private _tfarChannel = ["Channel_1","Channel_2","Channel_3","TaskForceRadio"]; //CASE-SENSITIVE! - Whitelisted Channels (da darf sich der Spieler aufhalten und bekommt keinen Blackscreen)
		if(!(call TFAR_fnc_isTeamSpeakPluginEnabled)) exitWith {true};
		if((call TFAR_fnc_getTeamSpeakServerName) != _serverName) exitWith {true};
		if(!((call TFAR_fnc_getTeamSpeakChannelName) in _tfarChannel)) exitWith {true};
		false;
	};
	for "_i" from 0 to 1 step 0 do {
		uiSleep 0.01;
		_cd = false;
		if(call _fnc_tfarCheck) then {
			_cd = true;
			titleText ["== BITTE AKTIVIERE DEIN TASK FORCE RADIO UND PRÜFE, OB DU AUF DEM RICHTIGEN SERVER UND IM RICHTIGEN RAUM BIST ==","BLACK"];
			uiSleep 8;
			titleText [" ","BLACK IN"];
		};
		if(_cd) then {
			uiSleep 1;
		} else {
			uiSleep 10;
		};
	};
};

Alles anzeigen

Einfach am Anfang des Skripts init_survival.sqf bzw. fn_survival.sqf werfen.

Cetrux

Moin Moin,

Variatox dein Script ist super aber ich habe allgemein das Problem das die TFAR Scripts mei mir nicht gehen.

Code

#include "..\script_macros.hpp"
/*
    File: fn_survival.sqf
    Author: Bryan "Tonic" Boardwine




    Description:
    All survival? things merged into one thread.
*/




0 spawn {
     if(call(life_adminlevel) >= 1) exitWith {systemChat "TFAR > Du bist ein Administrator. Daher wird dein Client nicht auf TFAR geprüft.";}; //Administratoren werden grundsätzlich nicht geprüft - Kannst du auch rausnehmen
     if(getPlayerUID player in [",""]) exitWith {}; //Spieler-IDs von Spielern die nie einen Blackscreen erhalten sollen (Kannst du nach belieben erweitern oder auch rausnehmen)
     _fnc_tfarCheck = {
     private _serverName = "Gamers Program"; //CASE-SENSITIVE! - Dein TeamSpeak3 Servername
     private _tfarChannel = ["Channel_1","Channel_2","Channel_3","[cspacer0]Insel_Funk"]; //CASE-SENSITIVE! - Whitelisted Channels (da darf sich der Spieler aufhalten und bekommt keinen Blackscreen)
     if(!(call TFAR_fnc_isTeamSpeakPluginEnabled)) exitWith {true};
     if((call TFAR_fnc_getTeamSpeakServerName) != _serverName) exitWith {true};
     if(!((call TFAR_fnc_getTeamSpeakChannelName) in _tfarChannel)) exitWith {true};
     false;
     };
     for "_i" from 0 to 1 step 0 do {
     uiSleep 0.01;
     _cd = false;
     if(call _fnc_tfarCheck) then {
     _cd = true;
     titleText ["== BITTE AKTIVIERE DEIN TASK FORCE RADIO UND PRÜFE, OB DU AUF DEM RICHTIGEN SERVER UND IM RICHTIGEN RAUM BIST ==","BLACK"];
     uiSleep 8;
     titleText [" ","BLACK IN"];
     };
     if(_cd) then {
     uiSleep 1;
     } else {
     uiSleep 10;
     };
     };
};




private ["_fnc_food","_fnc_water","_foodTime","_waterTime","_bp","_walkDis","_lastPos","_curPos"];
_fnc_food =  {
    if (life_hunger < 2) then {player setDamage 1; hint localize "STR_NOTF_EatMSG_Death";}
    else
    {
        life_hunger = life_hunger - 10;
        [] call life_fnc_hudUpdate;
        if (life_hunger < 2) then {player setDamage 1; hint localize "STR_NOTF_EatMSG_Death";};
        switch (life_hunger) do {
            case 30: {hint localize "STR_NOTF_EatMSG_1";};
            case 20: {hint localize "STR_NOTF_EatMSG_2";};
            case 10: {
                hint localize "STR_NOTF_EatMSG_3";
                if (LIFE_SETTINGS(getNumber,"enable_fatigue") isEqualTo 1) then {player setFatigue 1;};
            };
        };
    };
};




_fnc_water = {
    if (life_thirst < 2) then {player setDamage 1; hint localize "STR_NOTF_DrinkMSG_Death";}
    else
    {
        life_thirst = life_thirst - 10;
        [] call life_fnc_hudUpdate;
        if (life_thirst < 2) then {player setDamage 1; hint localize "STR_NOTF_DrinkMSG_Death";};
        switch (life_thirst) do  {
            case 30: {hint localize "STR_NOTF_DrinkMSG_1";};
            case 20: {
                hint localize "STR_NOTF_DrinkMSG_2";
                if (LIFE_SETTINGS(getNumber,"enable_fatigue") isEqualTo 1) then {player setFatigue 1;};
            };
            case 10: {
                hint localize "STR_NOTF_DrinkMSG_3";
                if (LIFE_SETTINGS(getNumber,"enable_fatigue") isEqualTo 1) then {player setFatigue 1;};
            };
        };
    };
};




//Setup the time-based variables.
_foodTime = time;
_waterTime = time;
_walkDis = 0;
_bp = "";
_lastPos = visiblePosition player;
_lastPos = (_lastPos select 0) + (_lastPos select 1);
_lastState = vehicle player;




for "_i" from 0 to 1 step 0 do {
    /* Thirst / Hunger adjustment that is time based */
    if ((time - _waterTime) > 600) then {[] call _fnc_water; _waterTime = time;};
    if ((time - _foodTime) > 850) then {[] call _fnc_food; _foodTime = time;};




    /* Adjustment of carrying capacity based on backpack changes */
    if (backpack player isEqualTo "") then {
        life_maxWeight = LIFE_SETTINGS(getNumber,"total_maxWeight");
        _bp = backpack player;
    } else {
        if (!(backpack player isEqualTo "") && {!(backpack player isEqualTo _bp)}) then {
            _bp = backpack player;
            life_maxWeight = LIFE_SETTINGS(getNumber,"total_maxWeight") + round(FETCH_CONFIG2(getNumber,"CfgVehicles",_bp,"maximumload") / 4);
        };
    };




    /* Check if the player's state changed? */
    if (vehicle player != _lastState || {!alive player}) then {
        [] call life_fnc_updateViewDistance;
        _lastState = vehicle player;
    };




    /* Check if the weight has changed and the player is carrying to much */
    if (life_carryWeight > life_maxWeight && {!isForcedWalk player}) then {
        player forceWalk true;
        if (LIFE_SETTINGS(getNumber,"enable_fatigue") isEqualTo 1) then {player setFatigue 1;};
        hint localize "STR_NOTF_MaxWeight";
    } else {
        if (isForcedWalk player) then {
            player forceWalk false;
        };
    };




    /* Travelling distance to decrease thirst/hunger which is captured every second so the distance is actually greater then 650 */
    if (!alive player) then {_walkDis = 0;} else {
        _curPos = visiblePosition player;
        _curPos = (_curPos select 0) + (_curPos select 1);
        if (!(_curPos isEqualTo _lastPos) && {(isNull objectParent player)}) then {
            _walkDis = _walkDis + 1;
            if (_walkDis isEqualTo 650) then {
                _walkDis = 0;
                life_thirst = life_thirst - 5;
                life_hunger = life_hunger - 5;
                [] call life_fnc_hudUpdate;
            };
        };
        _lastPos = visiblePosition player;
        _lastPos = (_lastPos select 0) + (_lastPos select 1);
    };
    if !(isNull (unitBackpack player)) then {(unitBackpack player) setObjectTextureGlobal [0, ""];};
    uiSleep 1;
};




[] spawn {
    private["_bp","_load","_cfg"];
    while{true} do
        {
        waitUntil {backpack player != ""};
        _bp = backpack player;
        _cfg = getNumber(configFile >> "CfgVehicles" >> (backpack player) >> "maximumload");
        _load = round(_cfg / 8);
        life_maxWeight = life_maxWeightT + _load;
        waitUntil {backpack player != _bp};
        if(backpack player == "") then 
        {  
        life_maxWeight = life_maxWeightT;
        };
};

Alles anzeigen

Hat jemand eine Idee?

Danke

Kuchenplatte

Das muss in die initciv

Tropical Life · TS: 5.9.80.55:2015

Ich habe hier jetzt alles ausprobiert aber nichts klappt.
Habe ingame immer noch den normalen Bildschirm.

trenton87

Funktioniert auch bei der 5.0 -

Cetrux

Also ich habe dieses Script nun am Ende der fn_initCiv.sqf , fn_initCop.sqf und der fn_initMedic.sqf angefügt und es funktioniert wunderbar!

Die drei Dateien findet man einfach in der Mission im Ordner "Core"

TFAR Blackscreen Scriptsuche

Ähnliche Themen

TFAR Blackscreen geht nicht

Benutzer online in diesem Thema