Hi Leute ich hab da ein Problem auf meinem Server

Master041013

Vielleicht kann mir ja einer von euch bei meinem Problem helfen.
Undzwar habe ich folgendes Problem:
wenn ich als cop ein fahrzeug beschlagnahme wird im chat nur STR_NOTF_BeingImpounded angezeigt.
das gleiche problem habe ich (natürlich mit einem anderen text xD) bei festnahmen.

kann mir jemand von euch sagen in welcher Datei ich nach dem fehler suchen muss ?

Mfg Master041013

Shinji

Was auch immer du genau sagen möchtest, es ist ne schwammige anfrage. Ich denke du meinst dass der String nicht von der Stringtable kommt, sondern der String direkt ausgegeben wird.

Wenn das der Fall ist, dann schau bitte in deine Stringtable ob der Eintrag fehlt.
Andernfalls schau in die impoundAction.sqf, da wird er an die broadcast übergeben.

Shadow l Eagle

Wie frage ich richtig um Hilfe? - Leitfaden <--- Das ist kein Deko Thread...

Master041013

Hier einfach mal ein Bild zu meinem Problem da ich nicht weis wie ich es erklären soll. Leider hat mir die Antwort von Shinji nicht weiter geholfen. Trotzdem danke für die Antwort

Shinji

Dummerweise war meine Antwort korrekt.

Gehe in die Stringtable.xml im Hauptverzeichnis

Suche dort nach den Einträgen

Code

STR_NOTF_HasImpounded




STR_NOTF_Impounded

Wenn sie nicht vorhanden sind, füge sie bitte hinzu.

Code

<Key ID="STR_NOTF_Impounded">
			<Original>You have impounded a %1\n\nYou have received $%2 for cleaning up the streets!</Original>
			<German>Du hast einen %1 beschlagnahmt\n\nDu hast $%2 für das Aufräumen der Straßen bekommen!</German>
			<French>Vous avez mis en fourrière un(e) %1\n\nVous avez reçus $%2 pour avoir nettoyé les rues!</French>
			<Italian>Hai sequestrato un %1\n\nHai ricevuto €%2 per aver mantenuto l'ordine nelle strade!</Italian>
			<Portuguese>Você apreendeu %1\n\nVocê recebeu R$%2 por deixar as ruas mais seguras!</Portuguese>
		</Key>
		<Key ID="STR_NOTF_HasImpounded">
			<Original>%1 has impounded %2's %3</Original>
			<German>%1 hat %2's %3 beschlagnahmt</German>
			<French>%1 a mis en fourrière le %3 de %2.</French>
			<Italian>%1 ha sequestrato il %2 di %3</Italian>
			<Portuguese>%1 apreendeu %3 de %2</Portuguese>
		</Key>

Alles anzeigen

Master041013

Da ich den Fehler einfach nicht finden kann in der Datei hier meine Stringtable.xml

und danke für die schnelle Antwort

Shinji

Ich bitte darum (erneut) dich klar auszudrücken.

Da die beiden Lines drin sind schätze ich es liegt es an folgender Datei:

Code

fn_impoundAction.sqf

Dort werden beide Strings behandelt und ausgegeben. Kann sein dass dort jeweils ein "localize" fehlt.

Hannkok

O.o wenn die Hells angels die Westen sieht, das finden die bestimmt nicht lustig

Und Bohemia bzw die Urheber bestimmt auch nicht. Kann ne Anzeige, Server Schließung , und viel Geld kosten.

Sorry das ich vom Thema abgekommen bin

Master041013

Da ich nich weis wie klar ich mich da ausdrücken soll und auch keinen großen Plan von scripten habe kann ich halt nicht mehr schreiben
ich würde euch gerne eine richtige fehler beschreibung liefern nur hab ich selbst kein plan was da überhaupt der fehler ist ich seh nur auf dem server im chat das diese meldung kommt wenn ich etwas beschlagnahme und es kommen auch solche meldungen wenn ich jemanden festnehme, ein haus durchsuche oder ein strafzettel ausstelle die meldungen fangen im chat immer an mit STR_NOTF

wenn ich jemanden festnehme kommt im chat STR_Cop_Retrained

wenn ich ein haus durchsuche kommt im chatt diese meldung STR_House_Raid_NOTF

wenn jemand ein ticket welches ich ausstelle nicht bezahlt kommt STR_Cop_Ticket_Refuse

wenn ich jemanden ein ticket ausstelle kommt das im chat STR_Cop_TicketGive

wenn jemand dem ich ein ticket ausgestellt habe sein ticket bezahlt kommt diese meldung im chat STR_Cop_Ticket_PaidNOTF

und mehr als das kann ich dazu nicht schreiben da ich wie gesagt einfach keine ahnung habe was dort der fehler sein könnte oder wo er liegen könnte oder wie ich den sonst beschreiben soll

Shinji

Zeig mir bitte zunächst ersteinmal die impound datei die ich oben geschrieben habe.

Master041013

Code: fn_impoundaction.sqf

/*
	File: fn_impoundAction.sqf
	Author: Bryan "Tonic" Boardwine

	Description:
	Impounds the vehicle
*/
private["_vehicle","_type","_time","_price","_vehicleData","_upp","_ui","_progress","_pgText","_cP"];
_vehicle = cursorTarget;
if(!((_vehicle isKindOf "Car") || (_vehicle isKindOf "Air") || (_vehicle isKindOf "Ship"))) exitWith {};
if(player distance cursorTarget > 10) exitWith {};
if((_vehicle isKindOf "Car") || (_vehicle isKindOf "Air") || (_vehicle isKindOf "Ship")) then
{
	_vehicleData = _vehicle getVariable["vehicle_info_owners",[]];
	if(count _vehicleData == 0) exitWith {deleteVehicle _vehicle}; //Bad vehicle.
	_vehicleName = getText(configFile >> "CfgVehicles" >> (typeOf _vehicle) >> "displayName");
	[[0,"STR_NOTF_BeingImpounded",true,[(_vehicleData select 0) select 1,_vehicleName]],"life_fnc_broadcast",true,false] spawn life_fnc_MP;
	life_action_inUse = true;

	_upp = localize "STR_NOTF_Impounding";
	//Setup our progress bar.
	disableSerialization;
	5 cutRsc ["life_progress","PLAIN"];
	_ui = uiNameSpace getVariable "life_progress";
	_progress = _ui displayCtrl 38201;
	_pgText = _ui displayCtrl 38202;
	_pgText ctrlSetText format["%2 (1%1)...","%",_upp];
	_progress progressSetPosition 0.01;
	_cP = 0.01;
	while{true} do
	{
		uiSleep 0.09;
		_cP = _cP + 0.01;
		_progress progressSetPosition _cP;
		_pgText ctrlSetText format["%3 (%1%2)...",round(_cP * 100),"%",_upp];
		if(_cP >= 1) exitWith {};
		if(player distance _vehicle > 10) exitWith {};
		if(!alive player) exitWith {};
	};
	5 cutText ["","PLAIN"];

	if(player distance _vehicle > 10) exitWith {hintSilent localize "STR_NOTF_ImpoundingCancelled"; life_action_inUse = false;};
	if(!alive player) exitWith {life_action_inUse = false;};
	//_time = _vehicle getVariable "time";
	//if(isNil {_time}) exitWith {deleteVehicle _vehicle; hintSilent "This vehicle was hacked in"};
	//if((time - _time)  < 120) exitWith {hintSilent "This is a freshly spawned vehicle, you have no right impounding it."};
	if((count crew _vehicle) == 0) then
	{
		if(!((_vehicle isKindOf "Car") || (_vehicle isKindOf "Air") || (_vehicle isKindOf "Ship"))) exitWith {life_action_inUse = false;};
		_type = getText(configFile >> "CfgVehicles" >> (typeOf _vehicle) >> "displayName");
		switch (true) do
		{
			case (_vehicle isKindOf "Car"): {_price = (call life_impound_car);};
			case (_vehicle isKindOf "Ship"): {_price = (call life_impound_boat);};
			case (_vehicle isKindOf "Air"): {_price = (call life_impound_air);};
		};

		life_impound_inuse = true;
		[[_vehicle,true,player],"TON_fnc_vehicleStore",false,false] spawn life_fnc_MP;
		waitUntil {!life_impound_inuse};
		hintSilent format[localize "STR_NOTF_Impounded",_type,_price];
		[[0,"STR_NOTF_HasImpounded",true,[profileName,(_vehicleData select 0) select 1,_vehicleName]],"life_fnc_broadcast",true,false] spawn life_fnc_MP;
		life_atmcash = life_atmcash + _price;
	}
		else
	{
		hintSilent localize "STR_NOTF_ImpoundingCancelled";
	};
};
life_action_inUse = false;

Alles anzeigen

Shinji

jetzt mal noch eben bitte die

fn_broadcast.sqf nur zum vergleich

#Edit Maus war schneller als mein Kopf

Denn wie ich sehe, hatte ich recht mit dem localize. Sollte nun auch in der boradCast das localize fehlen, ist es ein klacks das zu fixen.

James B.

Moin, hast du das ScriptChannel 7 News installiert?
Bei uns hat das genau zu den gleichen Fehlern geführt.
Haben es schlussendlich dann rausgenommen

Master041013

/*
File: fn_broadcast.sqf
Author: Bryan "Tonic" Boardwine
Description:
Broadcast system used in the life mission for multi-notification purposes.
*/
private["_type","_message"];
_type = [_this,0,0,[[],0]] call BIS_fnc_param;
_message = [_this,1,"",[""]] call BIS_fnc_param;
if(_message == "") exitwith {};

if(typeName _type == typeName []) then
{
for "_i" from 0 to (count _type)-1 do
{
switch((_type select _i)) do
{
case 0: {systemChat _message};
case 1: {hint format["%1", _message]};
case 2: {titleText[format["%1",_message],"PLAIN"];};
case 3: {[_message,(player getVariable["realname",name player])] call life_fnc_AAN;};
};
};
}
else
{
switch (_type) do
{
case 0: {systemChat _message};
case 1: {hint format["%1", _message]};
case 2: {titleText[format["%1",_message],"PLAIN"];};
case 3: {[_message,(player getVariable["realname",name player])] call life_fnc_AAN;};
};
};

Master041013

ups da hab ich zu flott auf absenden geklickt

Shinji

Okay alles klar. Du musst nur folgendes eintragen.

unter der Zeile:

Code

if(_message == "") exitwith {};

fügst du

Code

_message = format ["%1",(localize _message)];

ein. Dann ist der Fehler behoben. < bzw. die der broadcasts

Master041013

Code: fn_broadcast.sqf

/*
	File: fn_broadcast.sqf
	Author: Bryan "Tonic" Boardwine

	Description:
	Broadcast system used in the life mission for multi-notification purposes.
*/
private["_type","_message"];
_type = [_this,0,0,[[],0]] call BIS_fnc_param;
_message = [_this,1,"",[""]] call BIS_fnc_param;
if(_message == "") exitwith {};
_message = format ["%1",(localize _message)];




if(typeName _type == typeName []) then
{
	for "_i" from 0 to (count _type)-1 do
	{
		switch((_type select _i)) do
		{
			case 0: {systemChat _message};
			case 1: {hint format["%1", _message]};
			case 2: {titleText[format["%1",_message],"PLAIN"];};
			case 3: {[_message,(player getVariable["realname",name player])] call life_fnc_AAN;};
		};
	};
}
	else
{
	switch (_type) do
	{
		case 0: {systemChat _message};
		case 1: {hint format["%1", _message]};
		case 2: {titleText[format["%1",_message],"PLAIN"];};
		case 3: {[_message,(player getVariable["realname",name player])] call life_fnc_AAN;};
	};
};

Alles anzeigen

hoffe ich habs richtig eingefügt

Master041013

habs getestet und es hat geholfen ich bedanke mich

Yuri Koxarov

Zitat von Master041013

habs getestet und es hat geholfen ich bedanke mich

Nur kurze Frage aus Interesse. Hast du versucht Channel 7 News zu integrieren?

Hi Leute ich hab da ein Problem auf meinem Server

nox 25. März 2023 um 00:47

Ähnliche Themen

Medic I Inventar buggt weg

Nach Server Neustart ist alles Weg

Extdb3 kein Connect mit 5.0

Cup Vehicles nicht einparkbar

TaskForceRadio Problem Altis Life 4.4r3

Server spinnt!

Benutzer online in diesem Thema