Fahrzeuginventar abrufen

Jens Rudolph

Hallo liebe Community,

das ist mein erster Post und falls ich etwas falsch gemacht habe bitte ich euch mich darauf hinzuweisen Danke!

Es geht mir darum:

Code

_vehicle = cursorObject;
if(_value > 0) then {
    [0,"Ein Fahrzeug wurde durchsucht und es wurden Drogen / Schmuggelware im Wert von $%1 gefunden. Die illegalen Gegenstände wurden beschlagnahmt!",true,[[_value] call life_fnc_numberText]] remoteExecCall ["life_fnc_broadcast",-2];
    min3factorylif3_4tmb4nk = min3factorylif3_4tmb4nk + _value;

    private _trunk = _vehicle getVariable["Trunk",[]];
    private _removedIllegal = false;
    _vehicle_data = _vehicle GVAR ["Trunk",[]];
    //hint format ["%1",_vehicle_data];

    {
        if(((_vehicle_data select 0) == "cocaine_processed") || ((_vehicle_data select 0) == "cocaine_unprocessed") || ((_vehicle_data select 0) == "heroin_processed") || ((_vehicle_data select 0) == "heroin_unprocessed") || ((_vehicle_data select 0) == "marijuana") || ((_vehicle_data select 0) == "cannabis") || ((_vehicle_data select 0) == "lsdp") || ((_vehicle_data select 0) == "lsdu") || ((_vehicle_data select 0) == "frosch_processed") || ((_vehicle_data select 0) == "frosch_unprocessed") || ((_vehicle_data select 0) == "Crystal") || ((_vehicle_data select 0) == "turtle_raw") || ((_vehicle_data select 0) == "turtle_soup")) then { 
            _removedIllegal = true;
            (_trunk select 0) set [_forEachIndex, -1];
            //hint "Test";
        };
    } forEach (_trunk select 0);

    if(_removedIllegal) then {
          _trunk set [0,((_trunk select 0) - [-1])]; 
           _trunk set [1,[_trunk select 0] call life_fnc_calculateWeight]; 
    };
    ["Illegale Gegenstände gefunden.",false,"fast"] call life_fnc_NachrichtSys;
} else {
    ["Keine illegalen Gegenstände gefunden.",false,"fast"] call life_fnc_NachrichtSys;
};

Alles anzeigen

Das Problem liegt an folgendem Codestück:

Code

if(((_vehicle_data select 0) == "cocaine_processed")...) then {...

Ich möchte vergleichen, ob ein Item in dem Kofferraum meines Fahrzeuges unverarbeitetes Kokain ist. Das selbe für alle anderen Items. Nur leider gehen diese Stellen nicht.. ich habe es auch mit isEqualTo versucht, hat jedoch nichts gebracht. Ich bin ratlos und weiß nicht mehr was ich versuchen könnte. Es gibt keine Fehlermeldung..

Hoffentlich kann mir jemand von euch helfen

Viele Grüße

Jens

wepper

Mach statt _vehicle_data select 0 _x select 0.

_vehicle_data enthält ein Array nach folgendem Mustrer: [['item1',mengeItem1],['item2',mengeItem2]]; Mit deiner Abfrage vergleichst du den ersten Index (['item1',mengeItem1]) mit "cocaine_unprocessed" -> Was nicht gleich ist.

_x ist eine magische Variable in der ForEach schleife, die den jeweiligen Eintrag enthält, in diesem Falle ['item1',mengeItem1] usw. Davon willst du den ersten Eintrag (select 0) und diesen kannst du dann vergleichen.

blackfisch

Zitat von Jens Rudolph

das ist mein erster Post und falls ich etwas falsch gemacht habe bitte ich euch mich darauf hinzuweisen

auch wenns böse klingt, an dem Code ist nichts richtig.

zunächst eine Erklärung.

Die Trunk Variable Auf dem Fahrzeug ist so aufgebaut: [[[Item 1, Anzahl], [Item 2, Anzahl], ..., [Item n, Anzahl]], Gewicht aller Items]

Fehler in deinem Code mal zusammengefasst:

Da _vehicle_data der Variable Trunk (siehe oben) entspricht ist der Vergleich in der forEach (_vehicle_data select 0) == "cocaine_processed" quatsch. Aufgelöst wäre das [[Item 1, Anzahl], [Item 2, Anzahl], ..., [Item n, Anzahl]] == "cocaine_processed" - ergibt keinen Sinn, oder?
Du hast zwar eine forEach, nutzt aber nirgends das aktuelle Argument _x sondern pauschal (_vehicle_data select 0) - du machst quasi n-Mal den selben Vergleich.

Also, verbessern wir das ganze:

(Hinweis: ich gehe davon aus, du definierst _value auch vorher!!!)

C

_vehicle = cursorObject;
if(_value > 0) then {
    [0,"Ein Fahrzeug wurde durchsucht und es wurden Drogen / Schmuggelware im Wert von $%1 gefunden. Die illegalen Gegenstände wurden beschlagnahmt!",true,[[_value] call life_fnc_numberText]] remoteExecCall ["life_fnc_broadcast",-2];
    min3factorylif3_4tmb4nk = min3factorylif3_4tmb4nk + _value;
    
    private _trunk = _vehicle getVariable["Trunk",[]];
    private _removedIllegal = false;
    _vehicle_data = _vehicle GVAR ["Trunk",[]];
    //hint format ["%1",_vehicle_data];
    
    {
        private _item = _x select 0;
        
        if((_item == "cocaine_processed") || (_item == "cocaine_unprocessed") || (_item == "heroin_processed") || (_item == "heroin_unprocessed") || (_item == "marijuana") || (_item == "cannabis") || (_item == "lsdp") || (_item == "lsdu") || (_item == "frosch_processed") || (_item == "frosch_unprocessed") || (_item == "Crystal") || (_item == "turtle_raw") || (_item == "turtle_soup")) then { 
            _removedIllegal = true;
            (_trunk select 0) set [_forEachIndex, -1];
            //hint "Test";
        };
    } forEach (_trunk select 0);
        
    if(_removedIllegal) then {
        _trunk set [0,((_trunk select 0) - [-1])]; 
        _trunk set [1,[_trunk select 0] call life_fnc_calculateWeight]; 
    };
    ["Illegale Gegenstände gefunden.",false,"fast"] call life_fnc_NachrichtSys;
} else {
    ["Keine illegalen Gegenstände gefunden.",false,"fast"] call life_fnc_NachrichtSys;
};

Alles anzeigen

Jetzt machen wir noch ein paar Schöneitsänderungen und räumen auf:

C

private _vehicle = cursorObject;
if(_value > 0) then {
    [0,"Ein Fahrzeug wurde durchsucht und es wurden Drogen / Schmuggelware im Wert von $%1 gefunden. Die illegalen Gegenstände wurden beschlagnahmt!",true,[[_value] call life_fnc_numberText]] remoteExecCall ["life_fnc_broadcast",-2];
    min3factorylif3_4tmb4nk = min3factorylif3_4tmb4nk + _value;
    
    private _trunk = _vehicle getVariable["Trunk",[]];
    private _removedIllegal = false;
    
    {
        _x params [
            ["_item", "", [""]]
        ];
        
        if(_item in ["cocaine_processed", "cocaine_unprocessed", "heroin_processed", "heroin_unprocessed", "marijuana", "cannabis", "lsdp", "lsdu", "frosch_processed", "frosch_unprocessed", "Crystal", "turtle_raw", "turtle_soup"]) then { 
            _removedIllegal = true;
            (_trunk select 0) set [_forEachIndex, -1];
        };
    } forEach (_trunk select 0);
        
    if(_removedIllegal) then {
        _trunk set [0,((_trunk select 0) - [-1])]; 
        _trunk set [1,[_trunk select 0] call life_fnc_calculateWeight]; 
    };
    ["Illegale Gegenstände gefunden.",false,"fast"] call life_fnc_NachrichtSys;
} else {
    ["Keine illegalen Gegenstände gefunden.",false,"fast"] call life_fnc_NachrichtSys;
};

Alles anzeigen

Ich gehe davon auf die life_fnc_calculateWeight funktioniert so wie gedacht, die Datei find ich nur nirgends wird also wohl von euch sein

Im Anhang ist das ganze als Datei in ordentlich formatiert.

Jens Rudolph

Heyho,

danke für euer schnelle Hilfe. Ich habe wieder was dazu gelernt

Deine Variante funktioniert einwandfrei. blackfisch

Vielen Dank und viele Grüße

Jens

Benutzer online in diesem Thema