Spieler in der nähe abfragen

taker9999

Hallo,

seit längerem arbeite ich daran, für einen Taktik Server, eine Belebte Stadt zu Simulieren. Das klappt auch soweit. Ich nutze dafür die von CBA gelieferte "CBA_fnc_taskPatrol". Nun zu meinem Kleinen Problem. Die NPC´s sollen, sobald ein Spieler näher als 2 Meter ist, Stehen bleiben. Meine Bisherigen Versuche scheitern.

Mein aufbau:

Code: NPC Init

[this, getmarkerpos "npc_town_1", 40, 7, "MOVE", "CARELESS", "BLUE", "LIMITED", "LINE", "this call CBA_fnc_searchNearby", [3,6,9]] call CBA_fnc_taskPatrol; [this]execVM "npcstop.sqf";

Code: npcstop.sqf

private ["_ki"];
_ki = [_this,0,objNull,[objNull]] call BIS_fnc_param;
while {true} do
    {
        _player = _x;
        _dist = 2;
        if (!isPlayer _player) exitWith {/*nix Spieler*/};

        if ((_player distance2D _ki)<_dist) then {
             diag_log "Spieler";
         }else{
             diag_log "Kein Spieler";
         };

    } foreach playableunits;
    sleep 10;
};

Alles anzeigen

Ich habe erstmal über diag_log mir ausgeben lassen ob es überhaupt Prüft ob der Spieler da ist oder nicht. Das Script Funktioniert zumindest beim Start. Aber nur während die Mission lädt danach wird der Code nicht weiter ausgeführt. Was mach ich Falsch?

blackfisch

1. mach keine execVM -> definier das Script als Funktion und rufe es über spawn auf.

2. nutze keine while {true} do sonden for "_i" from 0 to 1 step 0 do - hat Laufzeitgründe...

3. das mit der forEach ist eklig und man sollte forEach mit count ersetzen wo geht und das geht hier super: ({ isPlayer _x && {alive _x} && {(_x distance2D _ki)<_dist} } count playableUnits) > 0 - gibt true wenn Spieler anwesend oder false wenn nicht

4. nimm uisleep statt sleep, ist immer genauer und es gibt eigentlich kaum eine stelle wo man es nicht anstelle von sleep verwenden sollte.

taker9999

mit execVM wollt ich erstmal testen ob es überhaupt Funktionier. Hab es jetzt als Funktion eingetragen und per Spawn aufgerufen. Danke für die Tipps. Mein Code sieht aktuell so aus. Er Registriert keinen Spieler in seiner Nähe.

Code: NPC Init

[this, getmarkerpos "npc_town_2", 40, 7, "MOVE", "CARELESS", "BLUE", "LIMITED", "LINE", "this call CBA_fnc_searchNearby", [3,6,9]] call CBA_fnc_taskPatrol; this call DPG_fnc_randomloudout; [] spawn { 
 for "_i" from 0 to 1 step 0 do { 
  uisleep 10;    [this]call DPG_fnc_npcstop 
 }; 
};

Code: npcstop.sqf

params [
    ["_ki", ObjNull, [ObjNull]],
    ["_player", ObjNull, [ObjNull]]
];
//_ki = [_this,0,objNull,[objNull]] call BIS_fnc_param;
//_player = _x;
_dist = 2;
if ({ isPlayer _player && {alive _player} && {(_player distance2D _ki)<_dist} } count playableUnits) > 0 then {
     diag_log "Spieler";
 }else{
     diag_log "Kein Spieler";
};

Alles anzeigen

Ich habe gerade echt ein Brett vor dem Kopf

B4v4r!4n_Str!k3r

Du rufst dein Script mit einem Parameter auf (this). Das hat die Folge, dass _player automatisch objNull ist.

Probiere es mal mit https://community.bistudio.com/wiki/nearEntities und als Type "Man"

blackfisch

was nein pfui ahhhhhhhh

if (({ isPlayer _x && {alive _x} && {(_xdistance2D _ki)<_dist} } count playableUnits) > 0) then {

und jetzt über nearEntities besser machen (hatte ich net aufm Schirm heute morgen B4v4r!4n_Str!k3r :D)

if (({ isPlayer _x && {alive _x} && {(_xdistance2D _ki)<_dist} } count nearEntities ["Man", _dist]) > 0) then {

taker9999

Ich habe das mal eingefügt und auch mich dran versucht selbst zu lösen. Aber ich bin gerade echt zu blöde zu

Das ist wie er aktuell ist der Code. Im Anhang ist die aktuell Client RPT wo auch der Fehler drin ist

Code

params [
    ["_ki", ObjNull, [ObjNull]]
];

_dist = 5;
_player = _x;

if (({ isPlayer _x && {alive _x} && {(_x distance2D _ki) < _dist} } count nearEntities ["Man", _dist]) > 0) then {  
    diag_log "Spieler"; 
} else { 
    diag_log "Kein Spieler"; 
};

Alles anzeigen

MfG

B4v4r!4n_Str!k3r

Zitat von taker9999

_player = _x;

muss weg. _x ist undefiniert und _player wird sowieso nicht verwendet.

Zitat von taker9999

if (({ isPlayer _x && {alive _x} && {(_x distance2D _ki) < _dist} } count nearEntities ["Man", _dist]) > 0) then {

der fett markierte Teil kann weggelassen werden, da auf Distanz schon in nearEntities "gefiltert" wird.

Außerdem braucht nearEntities eine Position laut Wiki, fügen wir also die Position der KI ein.

if (({ isPlayer _x && {alive _x} } count (_ki nearEntities ["Man", _dist])) > 0) then {

taker9999

Zitat von B4v4r!4n_Str!k3r

muss weg. _x ist undefiniert und _player wird sowieso nicht verwendet.

der fett markierte Teil kann weggelassen werden, da auf Distanz schon in nearEntities "gefiltert" wird.

Außerdem braucht nearEntities eine Position laut Wiki, fügen wir also die Position der KI ein.

if (({ isPlayer _x && {alive _x} } count (_ki nearEntities ["Man", _dist])) > 0) then {

danke für den tipp.

Jedoch habe ich gerade einen ganz anderen Fehler.

Spoiler anzeigen

21:43:30 Error in expression <

params [

["_ki", ObjNull, [ObjNull]]

>

21:43:30 Error position: <params [

["_ki", ObjNull, [ObjNull]]

>

21:43:30 Error Ungültige Zahl in Ausdruck

21:43:30 File NPC\fn_npcstop.sqf [DPG_fnc_npcstop], line 81

21:43:30 Error in expression <

params [

["_ki", ObjNull, [ObjNull]]

>

21:43:30 Error position: <params [

["_ki", ObjNull, [ObjNull]]

>

21:43:30 Error Ungültige Zahl in Ausdruck

21:43:30 File NPC\fn_npcstop.sqf [DPG_fnc_npcstop], line 81

B4v4r!4n_Str!k3r

Zitat von taker9999

Jedoch habe ich gerade einen ganz anderen Fehler.

Hast du es denn versucht?

Ich denke nämlich schon das die falsche Syntax vom Befehl nearEntities den Fehler verursacht.

Die korrekte Syntax lautet:

position nearEntities [typeName, radius]

und in deinem Code ist die Position nicht vorhanden.

taker9999

Habe ich gemacht. So ist der Aktuelle Code

Code

params [
    ["_ki", ObjNull, [ObjNull]]
];

_dist = 5;

_pos = getPos _ki;

diag_log ["Ki ist bei %1", _pos];

if (({ isPlayer _x && {alive _x} } count (_pos nearEntities ["Man", _dist])) > 0) then {  
    diag_log "Spieler"; 
} else { 
    diag_log "Kein Spieler"; 
};

Alles anzeigen

B4v4r!4n_Str!k3r

Dein diag_log ist falsch. diag_log ["Ki ist bei %1", _pos]; muss diag_log format ["Ki ist bei %1", _pos]; heißen.

Zitat von taker9999

[] spawn {
for "_i" from 0 to 1 step 0 do {
uisleep 10; [this]call DPG_fnc_npcstop
};

Funktioniert auch nicht.

Wenn dann so:

Code

[this] spawn { params ["_ki",objNull,[objNull]]; 
for "_i" from 0 to 1 step 0 do { 
uisleep 10; [_ki]call DPG_fnc_npcstop ;
};

Besser ist jedoch den Aufruf in der init nur 1x durchzuführen:

[this] spawn DPG_fnc_npcstop;

Und dann die Funktion so abändern:

Code

params [
    ["_ki", objNull, [objNull]]
];
_dist = 5;
while {true} do {
    uiSleep 3;
    if (!alive _ki) exitWith {};
    _pos = getPos _ki;
    diag_log format ["Ki ist bei %1", _pos];
    if (({ isPlayer _x && {alive _x} } count (_pos nearEntities ["Man", _dist])) > 0) then { 
        diag_log "Spieler"; 
    } else { 
        diag_log "Kein Spieler"; 
    }; 
};

Alles anzeigen

blackfisch for "_i" from 0 to 1 step 0 do { anstatt von while {true} do { hat bei mir auch immer den Fehler Error Ungültige Zahl in Ausdruck geworfen. Kannst du mir erklären wieso? Ich komm nicht drauf was falsch ist.

blackfisch

Code

params [
 ["_ki", objNull, [objNull]]
];
private _dist = 5;
for "_i" from 0 to 1 step 0 do {
 uiSleep 3;
 if (!alive _ki) exitWith {};
 private _pos = getPos _ki;
 diag_log format ["Ki ist bei %1", _pos];
 if (({ isPlayer _x } count (_pos nearEntities ["Man", _dist])) > 0) then { 
 diag_log "Spieler"; 
 } else { 
 diag_log "Kein Spieler"; 
 }; 
};

Alles anzeigen

so... noch ne kleine Optimierung: alive Abfrage raus bei der nearEntities, da der Befehl nur "lebende" (nicht zerstörte) Entities zurück gibt

zu deiner Frage B4v4r!4n_Str!k3r kein Plan. ich nutz das ausschließlich und hatte nie Probleme

B4v4r!4n_Str!k3r

Zitat von blackfisch

zu deiner Frage B4v4r!4n_Str!k3rkein Plan. ich nutz das ausschließlich und hatte nie Probleme

Komisch, vielleicht bin ich auch noch nicht ganz wach und habe etwas übersehen

BlueType

Zitat von B4v4r!4n_Str!k3r

Komisch, vielleicht bin ich auch noch nicht ganz wach und habe etwas übersehen

Weil das true auch (true) geschrieben wird und nicht mit den Klammern

B4v4r!4n_Str!k3r

Zitat von Bluetype

Weil das true auch (true) geschrieben wird und nicht mit den Klammern

Du hast da etwas falsch verstanden: while {true} do { hat funktioniert, aber for "_i" from 0 to 1 step 0 do { nicht.

while (true) do { mit runden Klammern gibt es meines Wissens in ArmA nach gar nicht.

taker9999

Super hat alles geklappt wie es soll. Das endgültige Script sieht so aus:

Code: NPC Init

[this, getmarkerpos "npc_town_1", 40, 7, "MOVE", "CARELESS", "BLUE", "LIMITED", "LINE", "this call CBA_fnc_searchNearby", [3,6,9]] call CBA_fnc_taskPatrol; this call DPG_fnc_randomloudout; [this] spawn DPG_fnc_npcstop;

Diese 2 Datei erstellen und in den Funktions eintragen.

Wichtig! Achtet darauf das ihr auch den Richtigen tag verwendet. Bei mir ist er DPG. Im Life Framework ist es life. Achtet darauf und ändert es zu eurem Tag.

Code: fn_npcstop.sqf

params [
 ["_ki", objNull, [objNull]]
];

private _dist = 5;

for "_i" from 0 to 1 step 0 do {
     uiSleep 3;

     if (!alive _ki) exitWith {};

     private _pos = getPos _ki;


     if (({ isPlayer _x } count (_pos nearEntities ["Man", _dist])) > 0) then { 

        _ki disableAI "MOVE";
    } else { 
         _ki enableAI  "MOVE";
     }; 
};

Alles anzeigen

Code: fn_randomloudout

private ["_ki"];
_ki = [_this,0,objNull,[objNull]] call BIS_fnc_param;

removeAllItems _ki;
Removeuniform _ki;
Removeheadgear _ki;
Removevest _ki;
removeBackpack  _ki;
removeAllWeapons  _ki;
removeGoggles   _ki;
//Hut
_hatarray = ["H_Bandanna_blu","H_Bandanna_sand","H_Bandanna_gry","H_Bandanna_cbr","H_Bandanna_sgg","H_Bandanna_khk","H_Cap_oli","H_Cap_grn","TRYK_H_Bandana_H","TRYK_H_Bandana_wig","TRYK_H_Bandana_wig_g","rds_worker_cap3","rds_worker_cap2","rds_worker_cap1","rds_worker_cap4","TRYK_H_headsetcap_Glasses","TRYK_H_headsetcap_blk_Glasses","TRYK_H_headsetcap_od_Glasses","TRYK_R_CAP_BLK","TRYK_R_CAP_TAN","TRYK_R_CAP_OD_US","TRYK_r_cap_blk_Glasses","TRYK_r_cap_od_Glasses","TRYK_r_cap_tan_Glasses","TRYK_UA_CAP","TRYK_UA_CAP_GR","TRYK_UA_CAP_tan","TRYK_UA_CAP_U","TRYK_UA_CAP2R","TRYK_UA_CAP_GR2R","TRYK_UA_CAP_tan2R","TRYK_UA_CAP_U2R","TRYK_UA_CAP2","TRYK_UA_CAP_GR2","TRYK_UA_CAP_tan2","TRYK_UA_CAP_U2","TRYK_H_woolhat","TRYK_H_woolhat_br","TRYK_H_woolhat_cu","TRYK_H_woolhat_CW","TRYK_H_woolhat_tan","TRYK_H_woolhat_WH"];

_randomhat = _hatarray call BIS_fnc_selectRandom;

_ki addHeadgear _randomhat;

//Uniform
_uniarray = ["U_I_C_Soldier_Bandit_4_F","U_I_C_Soldier_Bandit_5_F","U_I_C_Soldier_Bandit_1_F","U_I_C_Soldier_Bandit_3_F","U_I_C_Soldier_Bandit_2_F","EF_HM_B1","EF_HM_BL1","EF_HM_OD1","EF_HM_SG1","EF_HM_PP1","EF_HM_B2","EF_HM_BL2","EF_HM_OD2","EF_HM_SG2","EF_HM_PP2","EF_HMARMY_1","EF_HMARMY_2","EF_MKJKT","EF_M_jkt2_3","EF_M_jkt2_22","EF_M_jkt2_32","EF_M_jkt1_3","EF_M_jkt32_2","EF_M_jkt2_4","EF_M_jkt3","EF_M_jkt32","rds_uniform_Profiteer1","rds_uniform_Profiteer2","rds_uniform_Profiteer3","rds_uniform_Profiteer4","rds_uniform_schoolteacher","TRYK_U_B_BLK_T_BG_BK","TRYK_U_B_RED_T_BG_BR","TRYK_U_B_BLK_T_BG_WH","TRYK_U_B_BLK_T_BK","TRYK_U_B_RED_T_BR","TRYK_U_B_BLK_T_WH","TRYK_U_B_Denim_T_BG_BK","TRYK_U_B_Denim_T_BG_WH","TRYK_U_B_Denim_T_BK","TRYK_U_B_Denim_T_WH"];

_randomuni = _uniarray call BIS_fnc_selectRandom;

_ki adduniform  _randomuni;

//Veste
_vestarray = ["V_LegStrapBag_olive_F","V_LegStrapBag_black_F","V_Safety_yellow_F","V_Safety_orange_F","V_Safety_blue_F"];

_randomvest = _vestarray call BIS_fnc_selectRandom;

_ki addvest   _randomvest;

//Googel
_gogarray = ["EF_MSG_T","EF_MSG_BK","EF_MSG_BL","EF_MSG_BW","EF_MSG_C","EF_MSG_G","EF_MSG_O","EF_MSG_P","EF_MSG_R","EF_MSG_V","EF_MSG_W","EF_MSG_Y","EF_SC_C1","EF_SC_CY1","EF_SC_MG1","EF_SC_P1","EF_SC_TTB1","EF_SC_TTBR1","EF_SC_TTBRK1","EF_SC_PP1","EF_SC_W1","G_Spectacles","G_Spectacles_Tinted"];

_randomgog = _gogarray call BIS_fnc_selectRandom;

_ki addGoggles   _randomgog;

Alles anzeigen

Damit laufen die NPC´s in einem umkreis von 40 Meter um den Marker "npc_town_1"

Hier noch ein paar links zur Erklärung von den einzelne Funktionen. das auch jeder, sofern er es möchte, das nachbauen kann.

https://cbateam.github.io/CBA_A3/docs/fi…Patrol-sqf.html

https://community.bistudio.com/wiki/disableAI

https://community.bistudio.com/wiki/enableAI

MFG

taker

und vielen vielen danke für die Hilfe. Da hatte ich wirklich ein Brett vor dem Kopf. B4v4r!4n_Str!k3r und blackfisch

BlueType

Zitat von B4v4r!4n_Str!k3r

Du hast da etwas falsch verstanden: while {true} do { hat funktioniert, aber for "_i" from 0 to 1 step 0 do { nicht.

while (true) do { mit runden Klammern gibt es meines Wissens in ArmA nach gar nicht.

Ehmmmm. Ich habs in meiner Hud und diese geht auch

blackfisch

Zitat von Bluetype

Ehmmmm. Ich habs in meiner Hud und diese geht auch

Wäre mir neu, weil while nen code will und mit runden klammern ist es keiner. Whatever,

#closed da erledigt

Benutzer online in diesem Thema