Vereinfachung fn_clearVehicleAmmo.sqf

#include "..\..\script_macros.hpp"
/*
 File: fn_clearVehicleAmmo.sqf
 Author: Bryan "Tonic" Boardwine
 Description:
 Clears the vehicle of ammo types that we don't want.
 Syntax: _vehicle removeMagazinesTurret [magazineName, turretPath]
 Documentation: https://community.bistudio.com/wiki/removeMagazinesTurret
*/
params [["_vehicle",objNull,[objNull]]];
if (isNull _vehicle) exitWith {};
/* funcGetTurretsWeapons: https://community.bistudio.com/wiki/weaponsTurret */
funcGetTurretsWeapons = { 
     private _result = [];
     private _findRecurse = { 
         private _root = (_this select 0); 
         private _path = +(_this select 1); 
         for "_i" from 0 to count _root -1 do { 
             private _class = _root select _i; 
             if (isClass _class) then { 
                 private _currentPath = _path + [_i]; 
                 { 
                     _result set [count _result, [_x, _currentPath]]; 
                 } foreach getArray (_class >> "weapons"); 
                 _class = _class >> "turrets"; 
                 if (isClass _class) then { 
                     [_class, _currentPath] call _findRecurse; 
                 }; 
             }; 
         }; 
     }; 
     private _class = ( 
         configFile >> "CfgVehicles" >> ( 
             switch (typeName _this) do { 
                 case "STRING" : {_this}; 
                 case "OBJECT" : {typeOf _this}; 
                 default {nil} 
             } 
         ) >> "turrets" 
     ); 
     [_class, []] call _findRecurse; 
     _result; 
 };
{
 if !(_x in ["SportCarHorn","MiniCarHorn","CarHorn","CarHorn","PoliceHorn","PoliceHorn","TruckHorn3","AmbulanceHorn","TruckHorn2"]) then {_vehicle removeWeapon _x};
} forEach weapons _vehicle;
{
    _vehicle removeWeaponTurret _x;
} forEach (_vehicle call funcGetTurretsWeapons);
clearWeaponCargoGlobal _vehicle;
clearMagazineCargoGlobal _vehicle;
clearItemCargoGlobal _vehicle;
clearBackpackCargoGlobal _vehicle;