Suitcase ändern zu anderem Objekt? Alle VItems in ein Objekt?

Antimate

Hallöle!

Ich habe mir überlegt die Standard Suitcases zu entfernen und nur ein Objekt zu haben wo alles drin liegt.

Die Datei mit dem Aufruf für die Datei habe ich bereits gefunden nur stehe ich jetzt vor der Frage...

Wie fange ich damit am besten an?

Ich bin recht neu was die sache angeht und wollte mich mal da an etwas probieren.

Vielleicht erklärt sich ja einer von euch bereit mir soweit es geht eine Hilfestellung zu geben sodass ich dieses dann omo durchführen kann?

Ich wäre sehr dankbar darüber!

Und würde mich freuen von einem zu hören!

Mit freundlichen Grüßen!

moeck

Meinst Du, wenn wer stirbt? Dass die Sachen dann alle in einer Kiste landen?

Julian

Bitte sehr

Hier

Arma Services hat sowas ...

moeck

Ja kann man aber auch selber machen und sich die 20€ sparen

Julian

Zitat von moeck

Ja kann man aber auch selber machen und sich die 20€ sparen

Er hat geschrieben das er recht neu ist warum also das Rad neu erfinden ... man müsste nen Objekt erstellen das einfügen... spawnen dem Objekt eine addAction geben Dialog alles Dinge Darein... 20 Euro und Code angucken dann hat man wieder was gelernt...

Ist aber ja jedem selber überlassen..

moeck

so also ich habe jetzt mal geschaut und der folgende Script anfang ist dabei rausgekommen.

Code

#include "..\..\script_macros.hpp"
/*
    File: fn_dropItems.sqf
    Author: moeck

    Description:
    Called on death, player drops any 'virtual' items they may be carrying.
*/
private ["_obj","_unit","_item","_value"];
private _unit = _this select 0;
private _pos = _unit modelToWorld[0,3,0];
_pos = [(_pos select 0),(_pos select 1),0];
private _obj = "Land_PlasticCase_01_small_F" createVehicle _pos;
private _trunk =[];
private _weight = 0;
{
    if (_x isEqualType "") then {_item = _x;} else {_item = configName _x};
    _value = ITEM_VALUE(_item);
    _weight = _weight + (([_item] call life_fnc_itemWeight) * _value);
    _trunk pushBack [_item,_value];

} forEach (("true" configClasses (missionConfigFile >> "VirtualItems")) + ["life_cash"]);
_obj setVariable["Trunk",[_trunk,_weight],true];

Alles anzeigen

Es wird eine Kiste gespawnt und alle VItems und Geld rein gelegt. Klar jetzt müsste man noch schauen dass die Kiste per T oder addaction geöffnet wird und wenn man will kann man dann auch noch die I-Items des Spielers in die Kiste packen. Ich denke mal inkl. testen ist das vielleicht ein Aufwand von 2-3h und dafür will man 20€ ausgeben .

Achtung ich habe es noch nicht getestet

Gruß,

moeck

moeck

So damit es fast fertig ist hier mal noch ein kleines Update hinterher

Code

#include "..\..\script_macros.hpp"
/*
    File: fn_dropItems.sqf
    Author: moeck

    Description:
    Called on death, player drops any 'virtual' items and items. They are stored in a plastic case.
*/
private ["_obj","_unit","_item","_value"];
private _unit = _this select 0;
private _pos = _unit modelToWorld[0,3,0];
_pos = [(_pos select 0),(_pos select 1),0];
private _obj = "Land_PlasticCase_01_small_F" createVehicle _pos;
private _trunk =[];
private _weight = 0;
{
    if (_x isEqualType "") then {_item = _x;} else {_item = configName _x};
    _value = if (_item isEqualTo "life_cash") then {CASH} else {ITEM_VALUE(_item);};
    _iweight = if (_item isEqualTo "life_cash") then {0} else {(([_item] call life_fnc_itemWeight) * _value)};
    _weight = _weight +_iweight;
    _trunk pushBack [_item,_value];
} forEach (("true" configClasses (missionConfigFile >> "VirtualItems")) + ["life_cash"]);
_obj setVariable["Trunk",[_trunk,_weight],true];

if (!(uniform _unit isEqualTo "")) then {
    {_obj addItemCargoGlobal [_x, 1];} forEach (uniformItems player);
};
if (!(backpack player isEqualTo "")) then {
    {_obj addItemCargoGlobal [_x, 1];} forEach (backpackItems player);
};

if (!(vest player isEqualTo "")) then {
    {_obj addItemCargoGlobal [_x, 1];} forEach (vestItems player);
};
if (count (primaryWeaponItems player) > 0) then {
    {_obj addItemCargoGlobal [_x, 1];} forEach (primaryWeaponItems player);
};
if (count (handgunItems player) > 0) then {
    {_obj addItemCargoGlobal [_x, 1];} forEach (handGunItems player);
};
if !(primaryWeapon player isEqualTo "") then {_obj addItemCargoGlobal [(primaryWeapon player), 1]};
if !(handgunWeapon player isEqualTo "") then {_obj addItemCargoGlobal [(handgunWeapon player), 1]};

Alles anzeigen

so damit man an das T-Inventar kommt muss man die folgende Zeile im keyhandler um die gespawnte Kiste erweitern

Code

_list = ((ASLtoATL (getPosASL player)) nearEntities [["Box_IND_Grenades_F","B_supplyCrate_F","Land_PlasticCase_01_small_F"], 2.5]) select 0;

so nun werden auch die I-Items in die Box gelegt. Also ganz ehrlich das wäre mir keine 20€ wert . Vielleicht mag es ja mal wer testen . Würde mich über Rückmeldungen freuen .

Gruß,

moeck

Julian

moeck wie wäre es wenn du einfach nen Webshop aufmachst ?? ich meine es gibt bestimmt Leute die für dich supporter spielen wenn du auf Arbeit bist und dann leiten helfen

Alice Kingsleigh

Da ich grade eh am Server sitz teste ich das doch direkt mal aus

Alice Kingsleigh

Ergebnis: Die Kiste steht, daneben werden auch keine Items mehr grdoped, allerdings kann mit mit T nicht drauf zugreifen. Logs sagen alles in Ordnung. Habe wie du sagtest die fn_dropItems.sqf durch deine ersetzt und in der fn_keyHandler.sqf im case 20, also im T Key, nach der ersten else eingesetzt. Sieht also so aus:

Code

case 20: {
        if (!_alt && {!_ctrlKey} && {!dialog} && {!life_action_inUse} && {!(player getVariable ["playerSurrender",false])} && {!(player getVariable ["restrained",false])} && {!life_isknocked} && {!life_istazed}) then {
            if (!(isNull objectParent player) && alive vehicle player) then {
                if ((vehicle player) in life_vehicles) then {
                    [vehicle player] spawn life_fnc_openInventory;
                };
            } else {
                private "_list";
                _list = ((ASLtoATL (getPosASL player)) nearEntities [["Box_IND_Grenades_F","B_supplyCrate_F","Land_PlasticCase_01_small_F"], 2.5]) select 0;
                if (!(isNil "_list")) then {
                    _house = nearestObject [(ASLtoATL (getPosASL _list)), "House"];
                    if (_house getVariable ["locked", false]) then {
                        hint localize "STR_House_ContainerDeny";
                    } else {
                        [_list] spawn life_fnc_openInventory;
                    };
                } else {
                    _list = ["landVehicle","Air","Ship"];
                    if (KINDOF_ARRAY(cursorObject,_list) && {player distance cursorObject < 7} && {isNull objectParent player} && {alive cursorObject} && {!life_action_inUse}) then {
                        if (cursorObject in life_vehicles || {locked cursorObject isEqualTo 0}) then {
                            [cursorObject] spawn life_fnc_openInventory;
                        };
                    };
                };
            };
        };

Alles anzeigen

moeck

ist im I-Inventar was drin?

Alice Kingsleigh

Nope

moeck

ja ich sehe gerade da muss noch was anderes geändert werden. Das schaue ich mir später mal an, erstmal pennen

Alice Kingsleigh

Wünsche dir eine gute Nacht. Wenn du es geändert hast teste ich gerne direkt wenn ich es morgen sehe und gebe Rückmeldung.

moeck

so es hat mir doch keine Ruhe gelassen. Einfach mal zum debuggen der Kram mit logausgaben

Code

#include "..\..\script_macros.hpp"
/*
 File: fn_dropItems.sqf
 Author: moeck

 Description:
 Called on death, player drops any 'virtual' items and items. They are stored in a plastic case.
*/
private ["_obj","_unit","_item","_value"];
private _unit = _this select 0;
private _pos = _unit modelToWorld[0,3,0];
_pos = [(_pos select 0),(_pos select 1),0];
private _obj = "Land_PlasticCase_01_small_F" createVehicle _pos;
clearWeaponCargoGlobal _obj;
clearItemCargoGlobal _obj;
clearMagazineCargoGlobal _obj;
clearBackpackCargoGlobal _obj;
private _trunk =[];
private _weight = 0;

{
     if (_x isEqualType "") then {_item = _x;} else {_item = configName _x};
     _value = if (_item isEqualTo "life_cash") then {CASH} else {ITEM_VALUE(_item);};
     _iweight = if (_item isEqualTo "life_cash") then {0} else {(([_item] call life_fnc_itemWeight) * _value)};
     _weight = _weight +_iweight;
     _trunk pushBack [_item,_value];
} forEach (("true" configClasses (missionConfigFile >> "VirtualItems")) + ["life_cash"]);
diag_log str(_trunk);
_obj setVariable["Trunk",[_trunk,_weight],true];

if (!(uniform _unit isEqualTo "")) then {
    {_obj addItemCargoGlobal [_x, 1];diag_log _x;} forEach (uniformItems player);
};
if (!(backpack player isEqualTo "")) then {
    {_obj addItemCargoGlobal [_x, 1];diag_log _x;} forEach (backpackItems player);
};

if (!(vest player isEqualTo "")) then {
    {_obj addItemCargoGlobal [_x, 1];diag_log _x;} forEach (vestItems player);
};
if (count (primaryWeaponItems player) > 0) then {
    {_obj addItemCargoGlobal [_x, 1];diag_log _x;} forEach (primaryWeaponItems player);
};
if (count (handgunItems player) > 0) then {
    {_obj addItemCargoGlobal [_x, 1];diag_log _x;} forEach (handGunItems player);
};
if !(primaryWeapon player isEqualTo "") then {_obj addItemCargoGlobal [(primaryWeapon player), 1];diag_log (primaryWeapon player);};
if !(handgunWeapon player isEqualTo "") then {_obj addItemCargoGlobal [(handgunWeapon player), 1];diag_log (handgunWeapon player);};

Alles anzeigen

moeck

Julian ich habe das hier eher sportlich gesehenund wollte nur zeigen, dass man nicht immer sinnlos Geld ausgeben muss. Da der ganze Arma Kram nicht mehr als ein Hobby ist, muss ich damit kein Geld verdienen . Ich habe bereits einen recht gut bezahlten Job

Julian

Zitat von moeck

Julian ich habe das hier eher sportlich gesehenund wollte nur zeigen, dass man nicht immer sinnlos Geld ausgeben muss. Da der ganze Arma Kram nicht mehr als ein Hobby ist, muss ich damit kein Geld verdienen . Ich habe bereits einen recht gut bezahlten Job

hehe na dann

moeck

ok ich bin ein Idiot , vielleicht sollte man statt player _unit verwenden

Code

#include "..\..\script_macros.hpp"
/*
 File: fn_dropItems.sqf
 Author: moeck

 Description:
 Called on death, Player drops any 'virtual' items and items. They are stored in a plastic case.
*/
private ["_obj","_unit","_item","_value"];
private _unit = _this select 0;
private _pos = _unit modelToWorld[0,3,0];
_pos = [(_pos select 0),(_pos select 1),0];
private _obj = "Land_PlasticCase_01_small_F" createVehicle _pos;
clearWeaponCargoGlobal _obj;
clearItemCargoGlobal _obj;
clearMagazineCargoGlobal _obj;
clearBackpackCargoGlobal _obj;
private _trunk =[];
private _weight = 0;

{
     if (_x isEqualType "") then {_item = _x;} else {_item = configName _x};
     _value = if (_item isEqualTo "life_cash") then {CASH} else {ITEM_VALUE(_item);};
     _iweight = if (_item isEqualTo "life_cash") then {0} else {(([_item] call life_fnc_itemWeight) * _value)};
     _weight = _weight +_iweight;
     _trunk pushBack [_item,_value];
} forEach (("true" configClasses (missionConfigFile >> "VirtualItems")) + ["life_cash"]);
diag_log str(_trunk);
_obj setVariable["Trunk",[_trunk,_weight],true];

if (!(uniform _unit isEqualTo "")) then {
    {_obj addItemCargoGlobal [_x, 1];diag_log _x;} forEach (uniformItems _unit);
};
if (!(backpack _unit isEqualTo "")) then {
    {_obj addItemCargoGlobal [_x, 1];diag_log _x;} forEach (backpackItems _unit);
};

if (!(vest _unit isEqualTo "")) then {
    {_obj addItemCargoGlobal [_x, 1];diag_log _x;} forEach (vestItems _unit);
};
if (count (primaryWeaponItems _unit) > 0) then {
    {_obj addItemCargoGlobal [_x, 1];diag_log _x;} forEach (primaryWeaponItems _unit);
};
if (count (handgunItems _unit) > 0) then {
    {_obj addItemCargoGlobal [_x, 1];diag_log _x;} forEach (handGunItems _unit);
};
if !(primaryWeapon _unit isEqualTo "") then {_obj addItemCargoGlobal [(primaryWeapon _unit), 1];diag_log (primaryWeapon _unit);};
if !(handgunWeapon _unit isEqualTo "") then {_obj addItemCargoGlobal [(handgunWeapon _unit), 1];diag_log (handgunWeapon _unit);};

Alles anzeigen

Alice Kingsleigh

Was mir jetzt beim zweiten Test erst auffiel ist, dass die vItems nicht mehr grdropt werden. Bleiben komplett im Inventar. Auch nach deiner Änderung. Geld dropt, ist aber ebenso nirgends wieder zu finden. An der Kiste ist nur das I-Inventar aufrufbar. Hier werden aber nur Waffen und Magazine gespeichert. Habe mir extra Brille, Weste etc. alles mal testweise geholt gehabt.

moeck

Alice Kingsleigh kannst Du mir mal bitte das Clientlog zur verfügung stellen? dass du die Items noch hast ist mir klar, da sie noch nicht gelöscht werden

Benutzer online in diesem Thema