Komme als einziger Spieler nicht auf den Server

Jack Maxwell

Moin,

seit zwei Tagen habe folgendes Problem: Unser Server ist derzeit in der Testphase und ich komme als einziger Spieler nicht auf den Server. Alle anderen kommen ohne Problem drauf. Ich hänge mal den Client Log an. Auf andere Server komme ich ohne Probleme rauf. Den MPMissionsCache habe ich auch schon öfters gelöscht. Auch ohne Parameter habe ich es versucht. Bisher ohne Erfolg. Die Mission schmeißt mich mit einem Fehler raus, den kein anderer hat und es liegt auch kein Fehler im Skript vor.

Einen schönen Nachmittag noch,

Jack Maxwell

Kuchenplatte

Mit welchem Fehler schmeißt er dich denn raus ?

AvirexDE

Fehler von seiten des Serverbetreibers:

Code

Fehler Name: Falscher Variablen Typ
14:41:54 Error in expression <estObject[(call compile format["%1",(_x select 0)]),"House"];life_vehicles pushB>
14:41:54   Error position: <select 0)]),"House"];life_vehicles pushB>
14:41:54   Error select: Typ Zahl, erwartet Array,Zeichenfolge,Config entry
14:41:54 File core\session\fn_requestReceived.sqf [SOCK_fnc_requestReceived], line 49


Fehler Name: Unbekannte Fehler
14:41:50 Error in expression < isNullobjectParent player && player distance _target < 2 >
14:41:50   Error position: <player && player distance _target < 2 >
14:41:50   Error Fehlendes ;
14:45:18 Error: entity [ProxyFlag_Auto] still has its shape, ref_count=10
14:45:18 Error: entity [ProxyPlane_Flag_medium_inv_F] still has its shape, ref_count=5

Alles anzeigen

Jack Maxwell

Code: fn_requestReceived

#include "..\..\script_macros.hpp"
/*
    File: fn_requestReceived.sqf
    Author: Bryan "Tonic" Boardwine

    Description:
    Called by the server saying that we have a response so let's
    sort through the information, validate it and if all valid
    set the client up.
*/
private _count = count _this;
life_session_tries = life_session_tries + 1;
if (life_session_completed) exitWith {}; //Why did this get executed when the client already initialized?
if (life_session_tries > 3) exitWith {cutText[localize "STR_Session_Error","BLACK FADED"]; 0 cutFadeOut 999999999;};

LDGVAR((0.80),(localize "STR_Session_Received"));

//Error handling and junk..
if (isNil "_this") exitWith {[] call SOCK_fnc_insertPlayerInfo;};
if (_this isEqualType "") exitWith {[] call SOCK_fnc_insertPlayerInfo;};
if (count _this isEqualTo 0) exitWith {[] call SOCK_fnc_insertPlayerInfo;};
if ((_this select 0) isEqualTo "Error") exitWith {[] call SOCK_fnc_insertPlayerInfo;};
if (!(getPlayerUID player isEqualTo (_this select 0))) exitWith {[] call SOCK_fnc_dataQuery;};

//Parse basic player information.
CASH = parseNumber (_this select 2);
BANK = parseNumber (_this select 3);
CONST(life_adminlevel,(_this select 4));
if (LIFE_SETTINGS(getNumber,"donor_level") isEqualTo 1) then {
    CONST(life_donorlevel,(_this select 5));
} else {
    CONST(life_donorlevel,0);
};

//Loop through licenses
if (count (_this select 6) > 0) then {
    {missionNamespace setVariable [(_x select 0),(_x select 1)];} forEach (_this select 6);
};

//Parse side specific information.
switch (playerSide) do {
    case west: {
        CONST(life_coplevel,(_this select 7));
        CONST(life_medicLevel,0);
        life_blacklisted = _this select 9;
        if (LIFE_SETTINGS(getNumber,"save_playerStats") isEqualTo 1) then {
            life_hunger = ((_this select 10) select 0);
            life_thirst = ((_this select 10) select 1);
            player setDamage ((_this select 10) select 2);
        };
        
        //idcard
        if((_this select 12) isEqualTo []) then {
            life_side_noidcard = true;
        } else {
            life_idcard_data = _this select 12;
        };
    };

    case civilian: {
        life_is_arrested = _this select 7;
        CONST(life_coplevel, 0);
        CONST(life_medicLevel, 0);
        life_houses = _this select (_count - 3);
        if (LIFE_SETTINGS(getNumber,"save_playerStats") isEqualTo 1) then {
            life_hunger = ((_this select 9) select 0);
            life_thirst = ((_this select 9) select 1);
            player setDamage ((_this select 9) select 2);
        };
        
        //idcard
        if((_this select 13) isEqualTo []) then {
            life_side_noidcard = true;
        } else {
            life_idcard_data = _this select 13;
        };

        //Position
        if (LIFE_SETTINGS(getNumber,"save_civilian_position") isEqualTo 1) then {
            life_is_alive = _this select 10;
            life_civ_position = _this select 11;
            if (life_is_alive) then {
                if !(count life_civ_position isEqualTo 3) then {diag_log format ["[requestReceived] Bad position received. Data: %1",life_civ_position];life_is_alive =false;};
                if (life_civ_position distance (getMarkerPos "respawn_civilian") < 300) then {life_is_alive = false;};
            };
        };

        {
            _house = nearestObject [(call compile format ["%1",(_x select 0)]), "House"];
            life_vehicles pushBack _house;
        } forEach life_houses;

        life_gangData = _this select (_count - 2);
        if !(count life_gangData isEqualTo 0) then {
            [] spawn life_fnc_initGang;
        };
        
        [] spawn life_fnc_initHouses;
        
        //Unternehmen #Jonas 07.06.2018
        life_UnternehmenData = _this select (_count - 2);
        if !(count life_UnternehmenData isEqualTo 0) then {
            [] spawn life_fnc_initUnternehmen;
        };
        
        //Kartell #Jonas 07.06.2018
        life_kartellData = _this select (_count - 2);
        if !(count life_kartellData isEqualTo 0) then {
            [] spawn life_fnc_initKartell;
        };
        
    };

    case independent: {
        CONST(life_medicLevel,(_this select 7));
        CONST(life_coplevel,0);
        if (LIFE_SETTINGS(getNumber,"save_playerStats") isEqualTo 1) then {
            life_hunger = ((_this select 9) select 0);
            life_thirst = ((_this select 9) select 1);
            player setDamage ((_this select 9) select 2);
        };
        
        //idcard
        if((_this select 11) isEqualTo []) then {
            life_side_noidcard = true;
        } else {
            life_idcard_data = _this select 11;
        };
    };
};

life_gear = _this select 8;
[true] call life_fnc_loadGear;

if (count (_this select (_count - 1)) > 0) then {
    {life_vehicles pushBack _x;} forEach (_this select (_count - 1));
};

life_session_completed = true;

Alles anzeigen

Hier ist einmal unsere fn_requestReceived. Aus dem Log heraus erkennen lässt sich nur, dass er mich nach Line 49 rauswirft. Mir fällt dort aber kein Fehler auf. Habe die Datei auch schon mit der Vanilla Datei verglichen.

B4v4r!4n_Str!k3r

Hast du einen Serverlog (am Besten wäre wenn dann auch noch gleichzeitig in der description.ext DebugMode = 1; gesetzt ist) auch noch für uns?

Des Weiteren würde mich die fn_queryRequest.sqf interessieren.

Jack Maxwell

Code: fn_queryRequest.sqf

#include "\life_server\script_macros.hpp"
/*
    File: fn_queryRequest.sqf
    Author: Bryan "Tonic" Boardwine

    Description:
    Handles the incoming request and sends an asynchronous query
    request to the database.

    Return:
    ARRAY - If array has 0 elements it should be handled as an error in client-side files.
    STRING - The request had invalid handles or an unknown error and is logged to the RPT.
*/
private ["_uid","_side","_query","_queryResult","_tickTime","_tmp"];
_uid = [_this,0,"",[""]] call BIS_fnc_param;
_side = [_this,1,sideUnknown,[civilian]] call BIS_fnc_param;
_ownerID = [_this,2,objNull,[objNull]] call BIS_fnc_param;
[_ownerID] spawn ton_fnc_makeandsendp;

if (isNull _ownerID) exitWith {};
_ownerID = owner _ownerID;

_query = switch (_side) do {
    // West - 12 entries returned
    case west: {format ["SELECT pid, name, copcash, copbankacc, adminlevel, donorlevel, cop_licenses, coplevel, cop_gear, blacklist, cop_stats, playtime, idcard_data_cop FROM players WHERE pid='%1'",_uid];};
    // Civilian - 13 entries returned
    case civilian: {format ["SELECT pid, name, cash, bankacc, adminlevel, donorlevel, civ_licenses, arrested, civ_gear, civ_stats, civ_alive, civ_position, playtime, idcard_data_civ FROM players WHERE pid='%1'",_uid];};
    // Independent - 11 entries returned
    case independent: {format ["SELECT pid, name, cash, bankacc, adminlevel, donorlevel, med_licenses, mediclevel, med_gear, med_stats, playtime, idcard_data_med FROM players WHERE pid='%1'",_uid];};
};

_tickTime = diag_tickTime;
_queryResult = [_query,2] call DB_fnc_asyncCall;

if (EXTDB_SETTING(getNumber,"DebugMode") isEqualTo 1) then {
    diag_log "------------- Client Query Request -------------";
    diag_log format ["QUERY: %1",_query];
    diag_log format ["Time to complete: %1 (in seconds)",(diag_tickTime - _tickTime)];
    diag_log format ["Result: %1",_queryResult];
    diag_log "------------------------------------------------";
};

if (_queryResult isEqualType "") exitWith {
    [] remoteExecCall ["SOCK_fnc_insertPlayerInfo",_ownerID];
};

if (count _queryResult isEqualTo 0) exitWith {
    [] remoteExecCall ["SOCK_fnc_insertPlayerInfo",_ownerID];
};

//Blah conversion thing from a2net->extdb
_tmp = _queryResult select 2;
_queryResult set[2,[_tmp] call DB_fnc_numberSafe];
_tmp = _queryResult select 3;
_queryResult set[3,[_tmp] call DB_fnc_numberSafe];

//Parse licenses (Always index 6)
_new = [(_queryResult select 6)] call DB_fnc_mresToArray;
if (_new isEqualType "") then {_new = call compile format ["%1", _new];};
_queryResult set[6,_new];

//Convert tinyint to boolean
_old = _queryResult select 6;
for "_i" from 0 to (count _old)-1 do {
    _data = _old select _i;
    _old set[_i,[_data select 0, ([_data select 1,1] call DB_fnc_bool)]];
};

_queryResult set[6,_old];

_new = [(_queryResult select 8)] call DB_fnc_mresToArray;
if (_new isEqualType "") then {_new = call compile format ["%1", _new];};
_queryResult set[8,_new];
//Parse data for specific side.

switch (_side) do {
    case west: {
        _queryResult set[9,([_queryResult select 9,1] call DB_fnc_bool)];

        //Parse Stats
        _new = [(_queryResult select 10)] call DB_fnc_mresToArray;
        if (_new isEqualType "") then {_new = call compile format ["%1", _new];};
        _queryResult set[10,_new];

        //Playtime
        _new = [(_queryResult select 11)] call DB_fnc_mresToArray;
        if (_new isEqualType "") then {_new = call compile format ["%1", _new];};
        _index = TON_fnc_playtime_values_request find [_uid, _new];
        if (_index != -1) then {
            TON_fnc_playtime_values_request set[_index,-1];
            TON_fnc_playtime_values_request = TON_fnc_playtime_values_request - [-1];
            TON_fnc_playtime_values_request pushBack [_uid, _new];
        } else {
            TON_fnc_playtime_values_request pushBack [_uid, _new];
        };
        [_uid,_new select 0] call TON_fnc_setPlayTime;
        
        //idcard_data
        _new = [(_queryResult select 12)] call DB_fnc_mresToArray;
        if (_new isEqualType "") then {_new = call compile format["%1", _new];};
        _queryResult set[12,_new];
    };

    case civilian: {
        //idcard_data
        _new = [(_queryResult select 13)] call DB_fnc_mresToArray;
        if (_new isEqualType "") then {_new = call compile format["%1", _new];};
        _queryResult set[13,_new];
        
        _queryResult set[7,([_queryResult select 7,1] call DB_fnc_bool)];

        //Parse Stats
        _new = [(_queryResult select 9)] call DB_fnc_mresToArray;
        if (_new isEqualType "") then {_new = call compile format ["%1", _new];};
        _queryResult set[9,_new];

        //Position
        _queryResult set[10,([_queryResult select 10,1] call DB_fnc_bool)];
        _new = [(_queryResult select 11)] call DB_fnc_mresToArray;
        if (_new isEqualType "") then {_new = call compile format ["%1", _new];};
        _queryResult set[11,_new];

        //Playtime
        _new = [(_queryResult select 12)] call DB_fnc_mresToArray;
        if (_new isEqualType "") then {_new = call compile format ["%1", _new];};
        _index = TON_fnc_playtime_values_request find [_uid, _new];
        if (_index != -1) then {
            TON_fnc_playtime_values_request set[_index,-1];
            TON_fnc_playtime_values_request = TON_fnc_playtime_values_request - [-1];
            TON_fnc_playtime_values_request pushBack [_uid, _new];
        } else {
            TON_fnc_playtime_values_request pushBack [_uid, _new];
        };
        [_uid,_new select 2] call TON_fnc_setPlayTime;
        
        /* Make sure nothing else is added under here */
        _houseData = _uid spawn TON_fnc_fetchPlayerHouses;
        waitUntil {scriptDone _houseData};
        _queryResult pushBack (missionNamespace getVariable [format ["houses_%1",_uid],[]]);
        _gangData = _uid spawn TON_fnc_queryPlayerGang;
        waitUntil{scriptDone _gangData};
        _queryResult pushBack (missionNamespace getVariable [format ["gang_%1",_uid],[]]);
        _UnternehmenData = _uid spawn TON_fnc_queryPlayerUnternehmen;
        waitUntil{scriptDone _UnternehmenData};
        _queryResult pushBack (missionNamespace getVariable [format ["Unternehmen_%1",_uid],[]]);
    };

    case independent: {
        //Parse Stats
        _new = [(_queryResult select 9)] call DB_fnc_mresToArray;
        if (_new isEqualType "") then {_new = call compile format ["%1", _new];};
        _queryResult set[9,_new];

        //Playtime
        _new = [(_queryResult select 10)] call DB_fnc_mresToArray;
        if (_new isEqualType "") then {_new = call compile format ["%1", _new];};
        _index = TON_fnc_playtime_values_request find [_uid, _new];
        if !(_index isEqualTo -1) then {
            TON_fnc_playtime_values_request set[_index,-1];
            TON_fnc_playtime_values_request = TON_fnc_playtime_values_request - [-1];
            TON_fnc_playtime_values_request pushBack [_uid, _new];
        } else {
            TON_fnc_playtime_values_request pushBack [_uid, _new];
        };
        [_uid,_new select 1] call TON_fnc_setPlayTime;
        
        //idcard_data
        _new = [(_queryResult select 11)] call DB_fnc_mresToArray;
        if (_new isEqualType "") then {_new = call compile format["%1", _new];};
        _queryResult set[11,_new];
    };
};

publicVariable "TON_fnc_playtime_values_request";

_keyArr = missionNamespace getVariable [format ["%1_KEYS_%2",_uid,_side],[]];
_queryResult pushBack _keyArr;

_queryResult remoteExec ["SOCK_fnc_requestReceived",_ownerID];

Alles anzeigen

Hab hier mal beides eingefügt. DebugMode ist an.

B4v4r!4n_Str!k3r

das war schon wieder der client log

B4v4r!4n_Str!k3r

Also du hast in deiner fn_requestReceived.sqf auf jeden Fall ein Problem mit dem Index vom Datenarray.

Code

life_gangData = _this select (_count - 2);
 if !(count life_gangData isEqualTo 0) then {
 [] spawn life_fnc_initGang;
 };
 
 [] spawn life_fnc_initHouses;
 
 //Unternehmen #Jonas 07.06.2018
 life_UnternehmenData = _this select (_count - 2);
 if !(count life_UnternehmenData isEqualTo 0) then {
 [] spawn life_fnc_initUnternehmen;
 };
 
 //Kartell #Jonas 07.06.2018
 life_kartellData = _this select (_count - 2);
 if !(count life_kartellData isEqualTo 0) then {
 [] spawn life_fnc_initKartell;
 };

Alles anzeigen

Die Daten für Gang, Unternehmen und Kartell können nicht alle in ein und demselben Index vom Array befinden....

In der fn_queryRequest.sqf finde ich des Weitern nichts was mit dem Kartell zu tun haben könnte.

Ich würde deswegen

Code

//Kartell #Jonas 07.06.2018
 life_kartellData = _this select (_count - 2);
 if !(count life_kartellData isEqualTo 0) then {
 [] spawn life_fnc_initKartell;
 };

löschen.

Code

life_gangData = _this select (_count - 2);

zu

Code

life_gangData = _this select (_count - 3);

ändern und

Code

life_houses = _this select (_count - 3);

zu

Code

life_houses = _this select (_count - 4);

Um das zu verifizieren brauchen wir noch deinen Serverlog.

Jack Maxwell

Soory mein Fehler.

B4v4r!4n_Str!k3r

Daraus lässt sich dennoch noch nicht so viel schließen, außer dass du allgemein ein Problem hast, da das nicht normal aussieht:

Result: [""76561198072221000"",""James White"",0,50000,0,0,""[]"",0,""[]"",""""""[100,100,0]"""""",0,""""""[]"""""",""""""[2,0,0]"""""",""""""[]""""""]

Das sind zu viele "" an manchen Stellen.

Schick uns nochmals deinen Clientlog und füge zuvor diag_log _this; ganz oben in der fn_requestReceived.sqf ein.

Jack Maxwell

Nun funktioniert wieder alles. Ich komme nun auf den Server. Danke für die Hilfe!

Ich wünsche allen einen schönen Abend!

MFG

J. Maxwell

Benutzer online in diesem Thema