House Dupe Problem

Marius1773

Zitat von Julian

Wo genau ? in der Datei ?

Zitat von Königsegg

Ok es ist in der pInteraction.hpp drinnen hab nun bei ButtonOne das eingefügt onButtonClick = "closeDialog 0;";

Julian

Ach so ... Ja war nur weil GaNja es ohne geschrieben hat aber in der pinteraction ist es nicht so gut .... deswegen einfach die fn_housemenu.sqf nehmen

Koenigsegg

Zitat von Julian

closeDialog 0; sonst klappt es nicht

Einfach in die die fn_housemenu.sqf

Versuch die mal und teste mal

Werde ich nun Testen

nachtrag: geht leider immer noch nicht kann weiterhin das haus mehrmals verkaufen da der dialog ca 30 mal offen ist

nachtrag2: habe mal nach nem video gesucht wo genau das beschreibt was bei uns aktuell ist bzw gezeigt wird wie der bug geht

Externer Inhalt youtu.be

Inhalte von externen Seiten werden ohne deine Zustimmung nicht automatisch geladen und angezeigt.

Durch die Aktivierung der externen Inhalte erklärst du dich damit einverstanden, dass personenbezogene Daten an Drittplattformen übermittelt werden. Mehr Informationen dazu haben wir in unserer Datenschutzerklärung zur Verfügung gestellt.

Marius1773

Hier die fertigen Dateien, wo man nicht mehr mit Autoclicker irgendeinen Bullshit machen kann:

Code: fn_housemenu.sqf

#include "..\..\script_macros.hpp"
/*
    File: fn_houseMenu.sqf
    Author: Bryan "Tonic" Boardwine
    Description:
    Building interaction menu
*/
#define Btn1 37450
#define Btn2 37451
#define Btn3 37452
#define Btn4 37453
#define Btn5 37454
#define Btn6 37455
#define Btn7 37456
#define Btn8 37457
#define Title 37401

private ["_display","_curTarget","_Btn1","_Btn2","_Btn3","_Btn4","_Btn5","_Btn6","_Btn7","_Btn8"];
disableSerialization;
_curTarget = param [0,objNull,[objNull]];
if (isNull _curTarget) exitWith {}; //Bad target
_houseCfg = [(typeOf _curTarget)] call life_fnc_houseConfig;
if (count _houseCfg isEqualTo 0 && playerSide isEqualTo civilian) exitWith {};

if (!dialog) then {
    createDialog "pInteraction_Menu";
};

_Btn1 = CONTROL(37400,Btn1);
_Btn2 = CONTROL(37400,Btn2);
_Btn3 = CONTROL(37400,Btn3);
_Btn4 = CONTROL(37400,Btn4);
_Btn5 = CONTROL(37400,Btn5);
_Btn6 = CONTROL(37400,Btn6);
_Btn7 = CONTROL(37400,Btn7);
_Btn8 = CONTROL(37400,Btn8);
{_x ctrlShow false;} forEach [_Btn1,_Btn2,_Btn3,_Btn4,_Btn5,_Btn6,_Btn7,_Btn8];

life_pInact_curTarget = _curTarget;

if (_curTarget in life_hideoutBuildings) exitWith {
    closeDialog 0;
    hint localize "STR_House_Hideout";
};

if (_curTarget isKindOf "House_F" && playerSide isEqualTo west) exitWith {

    private _vaultHouse = [[["Altis", "Land_Research_house_V1_F"], ["Tanoa", "Land_Medevac_house_V1_F"]]] call TON_fnc_terrainSort;
    private _altisArray = [16019.5,16952.9,0];
    private _tanoaArray = [11074.2,11501.5,0.00137329];
    private _pos = [[["Altis", _altisArray], ["Tanoa", _tanoaArray]]] call TON_fnc_terrainSort;

    if ((nearestObject [_pos,"Land_Dome_Big_F"]) isEqualTo _curTarget || (nearestObject [_pos,_vaultHouse]) isEqualTo _curTarget) then {

        _Btn1 ctrlSetText localize "STR_pInAct_Repair";
        _Btn1 buttonSetAction "[life_pInact_curTarget] spawn life_fnc_repairDoor; closeDialog 0;";
        _Btn1 ctrlShow true;

        _Btn2 ctrlSetText localize "STR_pInAct_CloseOpen";
        _Btn2 buttonSetAction "[life_pInact_curTarget] call life_fnc_doorAnimate; closeDialog 0;";
        _Btn2 ctrlShow true;

    } else {
        if (!isNil {_curTarget getVariable "house_owner"}) then {
            _Btn1 ctrlSetText localize "STR_House_Raid_Owner";
            _Btn1 buttonSetAction "[life_pInact_curTarget] call life_fnc_copHouseOwner;";
            _Btn1 ctrlShow true;

            _Btn2 ctrlSetText localize "STR_pInAct_BreakDown";
            _Btn2 buttonSetAction "[life_pInact_curTarget] spawn life_fnc_copBreakDoor; closeDialog 0;";
            _Btn2 ctrlShow true;

            _Btn3 ctrlSetText localize "STR_pInAct_SearchHouse";
            _Btn3 buttonSetAction "[life_pInact_curTarget] spawn life_fnc_raidHouse; closeDialog 0;";
            _Btn3 ctrlShow true;

            if (player distance _curTarget > 3.6) then {
                _Btn3 ctrlEnable false;
            };

            _Btn4 ctrlSetText localize "STR_pInAct_LockHouse";
            _Btn4 buttonSetAction "[life_pInact_curTarget] spawn life_fnc_lockupHouse; closeDialog 0;";
            _Btn4 ctrlShow true;
        } else {
            closeDialog 0;
        };
    };
};

if (!(_curTarget in life_vehicles) || isNil {_curTarget getVariable "house_owner"}) then {
    private _isHouse = (isClass (missionConfigFile >> "Housing" >> worldName >> typeOf _curTarget));
    private _buildingPurchaseString = [
        "STR_pInAct_BuyGarage",
        "STR_pInAct_BuyHouse"
    ] select _isHouse;
    
    _Btn1 ctrlSetText localize _buildingPurchaseString;
    _Btn1 buttonSetAction "[life_pInact_curTarget] spawn life_fnc_buyHouse; closeDialog 0";
    _Btn1 ctrlShow true;

    if (!isNil {_curTarget getVariable "house_owner"}) then {
        _Btn1 ctrlEnable false;
    };

    if (_isHouse) then {
        if (getNumber (missionConfigFile >> "Housing" >> worldName >> (typeOf _curTarget) >> "canGarage") isEqualTo 1) then {
            _Btn2 ctrlSetText localize "STR_pInAct_GarageExt";
            _Btn2 buttonSetAction 'hint format [localize "STR_pInAct_GarageExtNOTF",[LIFE_SETTINGS(getNumber,"houseGarage_buyPrice")] call life_fnc_numberText];';
            _Btn2 ctrlShow true;
        };
    };

} else {
    if (isClass (missionConfigFile >> "Garages" >> worldName >> (typeOf _curTarget))) then {
        _Btn1 ctrlSetText localize "STR_pInAct_SellGarage";
        _Btn1 buttonSetAction "[life_pInact_curTarget] spawn life_fnc_sellHouse; closeDialog 0;";
        _Btn1 ctrlShow true;

        if !(((_curTarget getVariable "house_owner") select 0) isEqualTo getPlayerUID player) then {
            _Btn1 ctrlEnable false;
        };

        _Btn2 ctrlSetText localize "STR_pInAct_AccessGarage";
        _Btn2 buttonSetAction "[life_pInact_curTarget,""Car""] spawn life_fnc_vehicleGarage; closeDialog 0;";
        _Btn2 ctrlShow true;

        _Btn3 ctrlSetText localize "STR_pInAct_StoreVeh";
        _Btn3 buttonSetAction "[life_pInact_curTarget,player] spawn life_fnc_storeVehicle; closeDialog 0;";
        _Btn3 ctrlShow true;
    } else {
        _Btn1 ctrlSetText localize "STR_pInAct_SellHouse";
        _Btn1 buttonSetAction "[life_pInact_curTarget] spawn life_fnc_sellHouse; closeDialog 0;";
        _Btn1 ctrlShow true;

        if (((_curTarget getVariable "house_owner") select 0) != (getPlayerUID player)) then {
            _Btn1 ctrlEnable false;
        };

        if (_curTarget getVariable ["locked",false]) then {
            _Btn2 ctrlSetText localize "STR_pInAct_UnlockStorage";
        } else {
            _Btn2 ctrlSetText localize "STR_pInAct_LockStorage";
        };
        _Btn2 buttonSetAction "[life_pInact_curTarget] call life_fnc_lockHouse; closeDialog 0;";
        _Btn2 ctrlShow true;

        if (isNull (_curTarget getVariable ["lightSource",objNull])) then {
            _Btn3 ctrlSetText localize "STR_pInAct_LightsOn";
        } else {
            _Btn3 ctrlSetText localize "STR_pInAct_LightsOff";
        };
        _Btn3 buttonSetAction "[life_pInact_curTarget] call life_fnc_lightHouseAction; closeDialog 0;";
        _Btn3 ctrlShow true;

        if (getNumber (missionConfigFile >> "Housing" >> worldName >> (typeOf _curTarget) >> "canGarage") isEqualTo 1 && {!(_curTarget getVariable ["blacklistedGarage",false])}) then {
            if (_curTarget getVariable ["garageBought",false]) then {
                _Btn4 ctrlSetText localize "STR_pInAct_SellGarage";
                _Btn4 buttonSetAction "[life_pInact_curTarget] spawn life_fnc_sellHouseGarage; closeDialog 0;";
                _Btn4 ctrlShow true;

                if (((_curTarget getVariable "house_owner") select 0) != (getPlayerUID player)) then {
                    _Btn4 ctrlEnable false;
                };

                _Btn5 ctrlSetText localize "STR_pInAct_AccessGarage";
                _Btn5 buttonSetAction "[life_pInact_curTarget,""Car""] spawn life_fnc_vehicleGarage; closeDialog 0;";
                _Btn5 ctrlShow true;

                _Btn6 ctrlSetText localize "STR_pInAct_StoreVeh";
                _Btn6 buttonSetAction "[life_pInact_curTarget,player] spawn life_fnc_storeVehicle; closeDialog 0;";
                _Btn6 ctrlShow true;
            } else {
                _Btn5 ctrlSetText localize "STR_pInAct_BuyGarage";
                _Btn5 buttonSetAction "[life_pInact_curTarget] spawn life_fnc_buyHouseGarage; closeDialog 0;";
            };

            _Btn5 ctrlShow true;

        };

    };
};

Alles anzeigen

Code: fn_sellhouse.sqf

#include "..\..\script_macros.hpp"
/*
    File: fn_sellHouse.sqf
    Author: Bryan "Tonic" Boardwine
    Modified : NiiRoZz
    Description:
    Sells the house and delete all container near house.
*/
private ["_house","_uid","_action","_houseCfg"];

if (dialog) then {closeDialog 0};

_house = param [0,objNull,[objNull]];
_uid = getPlayerUID player;

if (isNull _house) exitWith {};
if (!(_house isKindOf "House_F")) exitWith {};
if (isNil {_house getVariable "house_owner"}) exitWith {hint localize "STR_House_noOwner";};
closeDialog 0;

_houseCfg = [(typeOf _house)] call life_fnc_houseConfig;
if (count _houseCfg isEqualTo 0) exitWith {};

_action = [
    format [localize "STR_House_SellHouseMSG",
    (round((_houseCfg select 0)/2)) call life_fnc_numberText,
    (_houseCfg select 1)],localize "STR_pInAct_SellHouse",localize "STR_Global_Sell",localize "STR_Global_Cancel"
] call BIS_fnc_guiMessage;

if (_action) then {
    _house setVariable ["house_sold",true,true];

    if (life_HC_isActive) then {
        [_house] remoteExecCall ["HC_fnc_sellHouse",HC_Life];
    } else {
        [_house] remoteExecCall ["TON_fnc_sellHouse",RSERV];
    };

    _house setVariable ["locked",false,true];
    deleteMarkerLocal format ["house_%1",_house getVariable "uid"];
    _house setVariable ["uid",nil,true];

    BANK = BANK + (round((_houseCfg select 0)/2));
    [1] call SOCK_fnc_updatePartial;
    _index = life_vehicles find _house;

    if (LIFE_SETTINGS(getNumber,"player_advancedLog") isEqualTo 1) then {
        if (LIFE_SETTINGS(getNumber,"battlEye_friendlyLogging") isEqualTo 1) then {
            advanced_log = format [localize "STR_DL_AL_soldHouse_BEF",(round((_houseCfg select 0)/2)),[BANK] call life_fnc_numberText];
        } else {
            advanced_log = format [localize "STR_DL_AL_soldHouse",profileName,(getPlayerUID player),(round((_houseCfg select 0)/2)),[BANK] call life_fnc_numberText];
            };
        publicVariableServer "advanced_log";
    };

    if !(_index isEqualTo -1) then {
        life_vehicles deleteAt _index;
    };

    _index = [str(getPosATL _house),life_houses] call TON_fnc_index;
    if !(_index isEqualTo -1) then {
        life_houses deleteAt _index;
    };
    _numOfDoors = FETCH_CONFIG2(getNumber,"CfgVehicles",(typeOf _house), "numberOfDoors");
    for "_i" from 1 to _numOfDoors do {
        _house setVariable [format ["bis_disabled_Door_%1",_i],0,true];
    };
    _containers = _house getVariable ["containers",[]];
    if (count _containers > 0) then {
        {
            _x setVariable ["Trunk",nil,true];

            if (life_HC_isActive) then {
                [_x] remoteExecCall ["HC_fnc_sellHouseContainer",HC_Life];
            } else {
                [_x] remoteExecCall ["TON_fnc_sellHouseContainer",RSERV];
            };

        } forEach _containers;
    };
    _house setVariable ["containers",nil,true];
};

Alles anzeigen

Code: fn_sellhousegarage.sqf

#include "..\..\script_macros.hpp"
/*
    File: fn_sellHouseGarage.sqf
    Author: BoGuu
    Description:
    Sell functionality for house garages.
*/

if (dialog) then {closeDialog 0};

private _house = param [0,objNull,[objNull]];
private _uid = getPlayerUID player;

if (isNull _house) exitWith {};
if !(_house getVariable ["garageBought",false]) exitWith {hint localize "STR_Garage_NotOwned";};
if ((_house getVariable "house_owner") select 0 != getPlayerUID player) exitWith {hint localize "STR_Garage_NotOwner";};
closeDialog 0;

private _sellPrice = LIFE_SETTINGS(getNumber,"houseGarage_sellPrice");

_action = [
    format [localize "STR_House_SellGarageMSG",
    [_sellPrice] call life_fnc_numberText],
    localize "STR_House_GarageSell",
    localize "STR_Global_Sell",
    localize "STR_Global_Cancel"
] call BIS_fnc_guiMessage;

if (_action) then {

    if (life_HC_isActive) then {
        [_uid,_house,1] remoteExec ["HC_fnc_houseGarage",HC_Life];
    } else {
        [_uid,_house,1] remoteExec ["TON_fnc_houseGarage",RSERV];
    };

    BANK = BANK + _sellPrice;
    [1] call SOCK_fnc_updatePartial;

    _house setVariable ["garageBought",false,true];

};

Alles anzeigen

Koenigsegg

Habe das nun eingefügt aber leider hat dies auch nicht geklappt kann nach wie vor den dialog mehrmals öffnen via speedclicker und dann ganz oft auf verkaufen drücken hab mal davon ne gif gemacht.

Spoiler anzeigen

Julian

dann such doch mal nach dem verkaufen und schreib dahinter mal nen closeDialog 0;

Koenigsegg

Zitat von Julian

dann such doch mal nach dem verkaufen und schreib dahinter mal nen closeDialog 0;

das verkaufen ist in der houseMenu.sqf und dort ist bereits ein closeDialog hinter sprich _Btn1 buttonSetAction "[life_pInact_curTarget] spawn life_fnc_sellHouse; closeDialog 0;";

weiß momentan auch nicht mehr weiter

Marius1773

Naja wie soll ich sagen das von mir kam von dem offiziellen Altis life github als fix dazu.. Hmm.

Yasar-S

Zitat von Risk

if(Player getVariable ["isBuying",true]) exitWhit(hint "habe bitte etwas geduld" closeDialog 0;);

Player setVariable["isBuying",true];

am Ende jeder Datei

Sleep 5;

Player setVariable["isBuying",false];

sollte so gehen wenn ich nicht ganz blöd bin.

Alles anzeigen

Nein du bist nicht Blöd . So habe ich das auch.

Meine Verzweigung

Code: fn_sellHouse.sqf

if(player getVariable ["playerQ",false]) exitWith {};
player setVariable ["playerQ",true];

//GANZ AM ENDE
player setVariable ["playerQ",nil];

Mit besten Grüßen

Yasar-S

Koenigsegg

Zitat von Marius1773

Naja wie soll ich sagen das von mir kam von dem offiziellen Altis life github als fix dazu.. Hmm.

Hatten das vorher auch schon probiert ging aber leider nicht..^^ werde das von Risk probieren habe das irgendwie überlesen xD

nachtrag: habe das von Risk probiert aber nun kann ich nicht mehr das Haus verkaufen, weiß aber auch nicht wo genau in der fn_SellHouse.sqf der obere abschnitt hin soll

Yasar-S

Der obere Abschnitt sollte über den Aufruf der Function "BIS_fnc_guiMessage".

Koenigsegg

Zitat von Yasar-S

Der obere Abschnitt sollte über den Aufruf der Function "BIS_fnc_guiMessage".

Das habe ich bereits so eingetragen aber der dupe geht nacht wie vor...

Code

if(player getVariable ["isSelling",true]) exitWith (hint "habe bitte etwas geduld" closeDialog 0;);
player setVariable["isSelling",true];

_action = [
    format [localize "STR_House_SellHouseMSG",
    (round((_houseCfg select 0)/2)) call life_fnc_numberText,
    (_houseCfg select 1)],localize "STR_pInAct_SellHouse",localize "STR_Global_Sell",localize "STR_Global_Cancel"
] call BIS_fnc_guiMessage;

Yasar-S

Koenigsegg du hast einen Fehler gemacht !

Code

if(player getVariable ["isSelling",true]) exitWith (hint "habe bitte etwas geduld" closeDialog 0;);

Das sollte so sein

Code

if(player getVariable ["isSelling",true]) exitWith {hint "habe bitte etwas geduld"; closeDialog 0;};

Versuch es mal mit

Code

//DEIN TEIL ERSETZTEN
// Die Verzweigung hat sich geändert

closeDialog 0;
if(player getVariable ["isSelling",false]) exitWith { hint "Ein bisschen geduld bitte..."; };
player setVariable["isSelling",true];

_action = [
 format [localize "STR_House_SellHouseMSG",
 (round((_houseCfg select 0)/2)) call life_fnc_numberText,
 (_houseCfg select 1)],localize "STR_pInAct_SellHouse",localize "STR_Global_Sell",localize "STR_Global_Cancel"
] call BIS_fnc_guiMessage;


//GANZ AM ENDE EINE NEUE ZEILE MIT
player setVariable ["isSelling",nil];

Alles anzeigen

Ich hoffe das hilft ein bisel

Mit freundlichen Grüßen

Yasar-S

Koenigsegg

Zitat von Yasar-S

Koenigsegg du hast einen Fehler gemacht !

Code

if(player getVariable ["isSelling",true]) exitWith (hint "habe bitte etwas geduld" closeDialog 0;);

Das sollte so sein

Code

if(player getVariable ["isSelling",true]) exitWith {hint "habe bitte etwas geduld"; closeDialog 0;};

Versuch es mal mit

Code

//DEIN TEIL ERSETZTEN
// Die Verzweigung hat sich geändert

closeDialog 0;
if(player getVariable ["isSelling",false]) exitWith { hint "Ein bisschen geduld bitte..."; };
player setVariable["isSelling",true];

_action = [
 format [localize "STR_House_SellHouseMSG",
 (round((_houseCfg select 0)/2)) call life_fnc_numberText,
 (_houseCfg select 1)],localize "STR_pInAct_SellHouse",localize "STR_Global_Sell",localize "STR_Global_Cancel"
] call BIS_fnc_guiMessage;


//GANZ AM ENDE EINE NEUE ZEILE MIT
player setVariable ["isSelling",nil];

Alles anzeigen

Ich hoffe das hilft ein bisel

Mit freundlichen Grüßen

Yasar-S

Alles anzeigen

Hey,

Tausend dank es ist nun nicht mehr möglich den dialog mehrmals zu öffnen egal wie oft ich den clicker laufen lasse es kommt nur noch 1 dialog sprich dupen ist nicht mehr möglich

Mit Freundlichen Grüßen,

Koenigsegg

Yasar-S

Freut mich zu hören das es geklappt hat

Benutzer online in diesem Thema